保護模式記憶體管理機制

MIT6.828——Lab1 PartA

MIT6.828——Lab1 PartB

分段機制的問題

? 分段的主要問題，出現在記憶體不足或者記憶體碎片過多的情況下，對于一個程式而言，例如其代碼段長度就和其代碼的長度直接相關，各個段的大小是不固定的，不能拆分的，要裝入記憶體便一次性將一個整段都裝入，因此在記憶體緊張時，就會出現問題，可以想象到的解決方法有這樣一種：將段換出到磁盤上，從而空出一部分的物理記憶體空間，但是同樣的，如果段長度過長，記憶體過小，在頻繁的換入換出也無濟于事，

? 問題的本質在于，分段機制下產生的連續線性地址，被認為在物理記憶體上也是連續的，線性地址就是物理地址，但是我們可用的物理地址并不是連續的，因此就會產生沖突，所以解決這個問題的關鍵在于，是否可以：線性地址連續，對應的物理地址不連續？為了解除這種一一映射的關系，便可以通過地址映射，

? 即 線性地址（虛擬地址）——頁表——> 物理地址，

? 為了效率的問題，這種映射關系寫在頁表里，頁表在記憶體中，查表的作業由硬體完成，

分頁機制的思想：通過映射，可以使得連續的線性地址與任意的物理地址相關聯，邏輯上連續的線性地址對應的物理地址可以不連續，

分段機制的作用：將線性地址轉化為物理地址；用大小相等（4KB）的頁代替大小不等的段，

頁表結構

一級頁表

首先針對一級頁表而言，尋址程序可以由下圖表示

可以看到，分頁機制仍舊是基于分段基礎上的，將分段形成的線性地址，進行劃分，利用高20位作為在頁表內尋址的偏移量，尋址頁表項，其中頁表項的基址（物理地址）放在CR3暫存器中，再利用低12位，結合頁表項給出的基址，合成物理地址，送上地址總線，即可尋址物理記憶體單元，可以看到，因為劃分了低12位為頁內偏移，因此頁表的大小也就是4KB，這是一個常用的頁大小值，而高20位，則說明，頁表中含1M項頁表項，占記憶體位4MB，

二級頁表

? 在一級頁表的鋪墊下，便有了另一個問題，頁表的大小為4M，且必須提前建立好，每個行程都有自己的頁表，如果行程數很多，頁表的記憶體開銷便很可觀，因此是否可以動態的創建頁表項呢？解決這個問題的答案就是二級頁表，二級頁表的思想是，將1M頁平均放到1K個頁表中，每個頁表1K個頁表項，占據記憶體位4KB，剛好為一頁的大小，為了存盤這些頁表，引入了頁目錄，每個頁表的物理地址，都在頁目錄中以頁目錄項的形式存盤，因為最多1K頁表，因此頁目錄大小也為4KB，一頁的大小，

? 二級頁表下的尋址程序如下：

? 現在需要了解一下，頁表項和頁目錄項的詳細資訊了，這部分資訊，可以在Intel系統開發手冊上得到詳細說明，

這里直接截取部分說明了：

開啟分頁機制

開啟分頁機制，需要做三件事：

準備好頁表和頁目錄
將頁目錄的物理地址寫入CR3
暫存器CR0的PG位置1

編程實體

在之前的mit6.828實驗1中，已經看到了一個比較基本的實體，如何進入保護模式，并進行分頁操作，為了對于lab2有一個更好的理解，這里截取一部分《作業系統真象還原》的代碼進行解釋說明，這里可以和lab1部分結合來看

建立GDT進入保護模式

GDT_BASE:   dd    0x00000000 
			dd    0x00000000

CODE_DESC:  dd    0x0000FFFF 
			dd    DESC_CODE_HIGH4

DATA_STACK_DESC:dd    0x0000FFFF
				dd    DESC_DATA_HIGH4

VIDEO_DESC: dd    0x80000007
			dd    DESC_VIDEO_HIGH4  

GDT_SIZE    equ   $ - GDT_BASE
GDT_LIMIT   equ   GDT_SIZE -1

gdt_ptr  dw  GDT_LIMIT 
		 dd  GDT_BASE
		 
;-----------------  打開A20  ----------------
in al,0x92
or al,0000_0010B
out 0x92,al
;-----------------  加載GDT  ----------------
lgdt [gdt_ptr]
;-----------------  cr0第0位置1  ----------------
mov eax, cr0
or eax, 0x00000001
mov cr0, eax

jmp dword SELECTOR_CODE:p_mode_start	     ; 重繪流水線
[bits 32]
p_mode_start:
   mov ax, SELECTOR_DATA
   mov ds, ax
   mov es, ax
   mov ss, ax
   mov esp,LOADER_STACK_TOP
   mov ax, SELECTOR_VIDEO
   mov gs, ax

按約定，GDT的第一個段描述符為空，這里建立了三個段，都是按照段描述符的規格進行性質填充，對照相關位的含義既可以知道段的資訊，為了裝載GDT，使用命令lgdt即可，進入保護模式后，尋址就需要使用段選擇子，這在之前的lab1中也說到了，

開啟分頁

首先規劃記憶體的整體布局，可以先畫出下面這張圖

人為規定的，將頁目錄放在了物理地址0x100000處，將第一個頁表，放在了物理地址0x101000處，同時劃分行程的虛擬地址空間位高端1GB內核空間和低端3GB用戶控制元件，首先需要注意的是，在虛擬記憶體空間中，將高端1GB完全分給了內核，這對于每個行程都是一樣的，為了實作所有行程的內核共享，這部分空間固定占據了頁目錄項的第0xc00項至第1023項，對于頁目錄而言，第0項存盤了第0個頁表的位置，最后一項存盤了頁目錄自身在物理記憶體中的位置，

值得注意的是，頁表0和頁表c00都映射到了物理記憶體的低端1MB，這么做的原因是，在內核加載到記憶體空間之前，運行的一直是loader程式，它運行在低端1MB，為了保證之前段機制下的地址和現在分頁后的地址一致，內核的前1MB也需要映射到物理記憶體低端1MB空間，低端的1MB=256*4KB，因此占據了256頁，需要256個頁表項，

在這部分說明之后，下面便是具體的實作：

setup_page:
;先把頁目錄占用的空間逐位元組清0
   mov ecx, 4096
   mov esi, 0
.clear_page_dir:
   mov byte [PAGE_DIR_TABLE_POS + esi], 0
   inc esi
   loop .clear_page_dir

;開始創建頁目錄項(PDE)
.create_pde:				     ; 創建Page Directory Entry
   mov eax, PAGE_DIR_TABLE_POS
   add eax, 0x1000 			     ; 此時eax為第一個頁表的位置及屬性
   mov ebx, eax				     ; 此處為ebx賦值，是為.create_pte做準備，ebx為基址，

;   下面將頁目錄項0和0xc00都存為第一個頁表的地址，
;   一個頁表可表示4MB記憶體,這樣0xc03fffff以下的地址和0x003fffff以下的地址都指向相同的頁表，
;   這是為將地址映射為內核地址做準備
   or eax, PG_US_U | PG_RW_W | PG_P	         ; 頁目錄項的屬性RW和P位為1,US為1,表示用戶屬性,所有特權級別都可以訪問.
   mov [PAGE_DIR_TABLE_POS + 0x0], eax       ; 第1個目錄項,在頁目錄表中的第1個目錄項寫入第一個頁表的位置(0x101000)及屬性
   mov [PAGE_DIR_TABLE_POS + 0xc00], eax     ; 一個頁表項占用4位元組,0xc00表示第768個頁表占用的目錄項,0xc00以上的目錄項用于內核空間,
					     				     ; 也就是頁表的0xc0000000~0xffffffff共計1G屬于內核,0x0~0xbfffffff共計3G屬于用戶行程.
   sub eax, 0x1000
   mov [PAGE_DIR_TABLE_POS + 4092], eax	     ; 使最后一個目錄項指向頁目錄表自己的地址

;下面創建頁表項(PTE)
   mov ecx, 256				                 ; 1M低端記憶體 / 每頁大小4k = 256
   mov esi, 0
   mov edx, PG_US_U | PG_RW_W | PG_P	     ; 屬性為7,US=1,RW=1,P=1
.create_pte:				                 ; 創建Page Table Entry
   mov [ebx+esi*4],edx			             ; 此時的ebx已經在上面通過eax賦值為0x101000,也就是第一個頁表的地址 
   add edx,4096
   inc esi
   loop .create_pte

;創建內核其它頁表的PDE
   mov eax, PAGE_DIR_TABLE_POS
   add eax, 0x2000 		     ; 此時eax為第二個頁表的位置
   or eax, PG_US_U | PG_RW_W | PG_P  ; 頁目錄項的屬性RW和P位為1,US為0
   mov ebx, PAGE_DIR_TABLE_POS
   mov ecx, 254			     ; 范圍為第769~1022的所有目錄項數量
   mov esi, 769
.create_kernel_pde:
   mov [ebx+esi*4], eax
   inc esi
   add eax, 0x1000
   loop .create_kernel_pde
   ret

在建立好了虛擬記憶體的布局之后，就可以正式開啟分頁機制

call setup_page

;要將描述符表地址及偏移量寫入記憶體gdt_ptr,一會用新地址重新加載
sgdt [gdt_ptr]	      ; 存盤到原來gdt所有的位置

;將gdt描述符中視頻段描述符中的段基址+0xc0000000
mov ebx, [gdt_ptr + 2]  
or dword [ebx + 0x18 + 4], 0xc0000000      ;視頻段是第3個段描述符,每個描述符是8位元組,故0x18，
;段描述符的高4位元組的最高位是段基址的31~24位

;將gdt的基址加上0xc0000000使其成為內核所在的高地址
add dword [gdt_ptr + 2], 0xc0000000

add esp, 0xc0000000        ; 將堆疊指標同樣映射到內核地址

; 把頁目錄地址賦給cr3
mov eax, PAGE_DIR_TABLE_POS
mov cr3, eax

; 打開cr0的pg位(第31位)
mov eax, cr0
or eax, 0x80000000
mov cr0, eax

;在開啟分頁后,用gdt新的地址重新加載
lgdt [gdt_ptr]             ; 重新加載

轉載請註明出處，本文鏈接：https://www.uj5u.com/caozuo/322939.html

標籤：Linux

上一篇：nginx原始碼編譯安裝（詳解）

下一篇：nginx原始碼編譯安裝（詳解）

MIT6.828——Lab2記憶體管理準備知識