30天自制作業系統-merk11的第三天
制作真正的IPL
先上參考代碼haribote-ipl
目的：讀入10個柱面
; haribote-ipl
; TAB=4
CYLS EQU 10 ; 宣告CYLS=10
ORG 0x7c00 ; 指明程式裝載地址
; 標準FAT12格式軟盤專用的代碼 Stand FAT12 format floppy code
JMP entry
DB 0x90
DB "HARIBOTE" ; 啟動扇區名稱（8位元組）
DW 512 ; 每個扇區（sector）大小（必須512位元組）
DB 1 ; 簇（cluster）大小（必須為1個扇區）
DW 1 ; FAT起始位置（一般為第一個扇區）
DB 2 ; FAT個數（必須為2）
DW 224 ; 根目錄大小（一般為224項）
DW 2880 ; 該磁盤大小（必須為2880扇區1440*1024/512）
DB 0xf0 ; 磁盤型別（必須為0xf0）
DW 9 ; FAT的長度（必須9扇區）
DW 18 ; 一個磁道（track）有幾個扇區（必須為18）
DW 2 ; 磁頭數（必須為2）
DD 0 ; 不使用磁區，必須是0
DD 2880 ; 重寫一次磁盤大小
DB 0,0,0x29 ; 意義不明（固定）
DD 0xffffffff ; （可能是）卷標號碼
DB "HARIBOTEOS " ; 磁盤的名稱（必須為11位元組，不足填空格）
DB "FAT12 " ; 磁盤格式名稱（必須8位元組，不足填空格）
RESB 18 ; 先空出18位元組
; 程式主體
entry:
MOV AX,0 ; 初始化暫存器
MOV SS,AX
MOV SP,0x7c00
MOV DS,AX
; 讀取磁盤
MOV AX,0x0820
MOV ES,AX
MOV CH,0 ; 柱面0
MOV DH,0 ; 磁頭0
MOV CL,2 ; 扇區2
readloop:
MOV SI,0 ; 記錄失敗次數暫存器
retry:
MOV AH,0x02 ; AH=0x02 : 讀入磁盤
MOV AL,1 ; 1個扇區
MOV BX,0
MOV DL,0x00 ; A驅動器
INT 0x13 ; 呼叫磁盤BIOS
JNC next ; 沒出錯則跳轉到next
ADD SI,1 ; 往SI加1
CMP SI,5 ; 比較SI與5
JAE error ; SI >= 5 跳轉到error
MOV AH,0x00
MOV DL,0x00 ; A驅動器
INT 0x13 ; 重置驅動器
JMP retry
next:
MOV AX,ES ; 把記憶體地址后移0x200（512/16十六進制轉換）
ADD AX,0x0020
MOV ES,AX ; ADD ES,0x020因為沒有ADD ES，只能通過AX進行
ADD CL,1 ; 往CL里面加1
CMP CL,18 ; 比較CL與18
JBE readloop ; CL <= 18 跳轉到readloop
MOV CL,1
ADD DH,1
CMP DH,2
JB readloop ; DH < 2 跳轉到readloop
MOV DH,0
ADD CH,1
CMP CH,CYLS
JB readloop ; CH < CYLS 跳轉到readloop
; 讀取完畢，跳轉到haribote.sys執行！
MOV [0x0ff0],CH ; IPLがどこまで読んだのかをメモ
JMP 0xc200
error:
MOV SI,msg
putloop:
MOV AL,[SI]
ADD SI,1 ; 給SI加1
CMP AL,0
JE fin
MOV AH,0x0e ; 顯示一個文字
MOV BX,15 ; 指定字符顏色
INT 0x10 ; 呼叫顯卡BIOS
JMP putloop
fin:
HLT ; 讓CPU停止，等待指令
JMP fin ; 無限回圈
msg:
DB 0x0a, 0x0a ; 換行兩次
DB "load error"
DB 0x0a ; 換行
DB 0
RESB 0x7dfe-$ ; 填寫0x00直到0x001fe
DB 0x55, 0xaa
;轉載請注明出處：https://www.cnblogs.com/merk11/p/15512260.html
切換畫面模式&進入32位模式
; haribote-os boot asm
; TAB=4
BOTPAK EQU 0x00280000 ; 加載bootpack
DSKCAC EQU 0x00100000 ; 磁盤快取的位置
DSKCAC0 EQU 0x00008000 ; 磁盤快取的位置（實模式）
; BOOT_INFO相關
CYLS EQU 0x0ff0 ; 引導扇區設定
LEDS EQU 0x0ff1
VMODE EQU 0x0ff2 ; 關于顏色的資訊
SCRNX EQU 0x0ff4 ; 解析度X
SCRNY EQU 0x0ff6 ; 解析度Y
VRAM EQU 0x0ff8 ; 影像緩沖區的起始地址
ORG 0xc200 ; 這個的程式要被裝載的記憶體地址
; 畫面モードを設定
MOV AL,0x13 ; VGA顯卡，320x200x8bit
MOV AH,0x00
INT 0x10
MOV BYTE [VMODE],8 ; 螢屏的模式（參考C語言的參考）
MOV WORD [SCRNX],320
MOV WORD [SCRNY],200
MOV DWORD [VRAM],0x000a0000
; 通過BIOS獲取指示燈狀態
MOV AH,0x02
INT 0x16 ; keyboard BIOS
MOV [LEDS],AL
; 防止PIC接受所有中斷
; AT兼容機的規范、PIC初始化
; 然后之前在CLI不做任何事就掛起
; PIC在同意后初始化
MOV AL,0xff
OUT 0x21,AL
NOP ; 不斷執行OUT指令
OUT 0xa1,AL
CLI ; 進一步中斷CPU
; 讓CPU支持1M以上記憶體、設定A20GATE
CALL waitkbdout
MOV AL,0xd1
OUT 0x64,AL
CALL waitkbdout
MOV AL,0xdf ; enable A20
OUT 0x60,AL
CALL waitkbdout
; 保護模式轉換
[INSTRSET "i486p"] ; 說明使用486指令
LGDT [GDTR0] ; 設定臨時GDT
MOV EAX,CR0
AND EAX,0x7fffffff ; 使用bit31（禁用分頁）
OR EAX,0x00000001 ; bit0到1轉換（保護模式過渡）
MOV CR0,EAX
JMP pipelineflush
pipelineflush:
MOV AX,1*8 ; 寫32bit的段
MOV DS,AX
MOV ES,AX
MOV FS,AX
MOV GS,AX
MOV SS,AX
; bootpack傳遞
MOV ESI,bootpack ; 源
MOV EDI,BOTPAK ; 目標
MOV ECX,512*1024/4
CALL memcpy
; 傳輸磁盤資料
; 從引導區開始
MOV ESI,0x7c00 ; 源
MOV EDI,DSKCAC ; 目標
MOV ECX,512/4
CALL memcpy
; 剩余的全部
MOV ESI,DSKCAC0+512 ; 源
MOV EDI,DSKCAC+512 ; 目標
MOV ECX,0
MOV CL,BYTE [CYLS]
IMUL ECX,512*18*2/4 ; 除以4得到位元組數
SUB ECX,512/4 ; IPL偏移量
CALL memcpy
; 由于還需要asmhead才能完成
; 完成其余的bootpack任務
; bootpack啟動
MOV EBX,BOTPAK
MOV ECX,[EBX+16]
ADD ECX,3 ; ECX += 3;
SHR ECX,2 ; ECX /= 4;
JZ skip ; 傳輸完成
MOV ESI,[EBX+20] ; 源
ADD ESI,EBX
MOV EDI,[EBX+12] ; 目標
CALL memcpy
skip:
MOV ESP,[EBX+12] ; 堆疊的初始化
JMP DWORD 2*8:0x0000001b
waitkbdout:
IN AL,0x64
AND AL,0x02
JNZ waitkbdout ; AND結果不為0跳轉到waitkbdout
RET
memcpy:
MOV EAX,[ESI]
ADD ESI,4
MOV [EDI],EAX
ADD EDI,4
SUB ECX,1
JNZ memcpy ; 運算結果不為0跳轉到memcpy
RET
; memcpy地址前綴大小
ALIGNB 16
GDT0:
RESB 8 ; 初始值
DW 0xffff,0x0000,0x9200,0x00cf ; 寫32bit位段暫存器
DW 0xffff,0x0000,0x9a28,0x0047 ; 可執行的檔案的32bit暫存器（bootpack用）
DW 0
GDTR0:
DW 8*3-1
DD GDT0
ALIGNB 16
bootpack:
;轉載請注明出處：https://www.cnblogs.com/merk11/p/15512260.html
實作HLT
; naskfunc
; TAB=4
[FORMAT "WCOFF"] ; 制作目標檔案的模式
[BITS 32] ; 制作32位模式用的機器語言
; 制作目標檔案的資訊
[FILE "naskfunc.nas"] ; 源檔案名資訊
GLOBAL _io_hlt ; 程式中包含的函式名
; 以下是實際的函式
[SECTION .text] ; 目標檔案中寫了這些后再寫程式
_io_hlt: ; void io_hlt(void);
HLT
RET
;轉載請注明出處：https://www.cnblogs.com/merk11/p/15512260.html
C語言
/* 告訴C編譯器，有一個函式在別的檔案里 */
void io_hlt(void);
/* 是函式宣告卻不用{}，而用;，這表示的意思是：
函式在別的檔案中，你自己找一下 */
void HariMain(void)
{
fin:
io_hlt(); /* 執行naskfunc.nas中的_io_hlt函式 */
goto fin;
}
;轉載請注明出處：https://www.cnblogs.com/merk11/p/15512260.html
匯編語言學習
EQU:相當于c語言中的#define
JC:是“jump if carry”的縮寫，意思 是如果進位標志（carry flag）是1的話，就跳轉，
JB:是“jump if below”的縮寫，翻譯過 來就是：“如果小于的話，就跳轉，”
在BIOS中：
AH=0x02;（讀盤） AH=0x03;（寫盤）
AH=0x04;（校驗） AH=0x0c;（尋道）
AL=處理物件的扇區數;（只能同時處理連續的扇區）
CH=柱面號 &0xff;
CL=扇區號（0-5位）|（柱面號&0x300）>>2;
DH=磁頭號;
DL=驅動器號；
ES:BX=緩沖地址；(校驗及尋道時不使用)
回傳值： (這邊的回傳值配合了JC的使用)
FLACS.CF == 0：沒有錯誤，AH==0
FLAGS.CF == 1：有錯誤，錯誤號碼存入AH內（與重置（reset）功能一樣）
設定顯卡模式：
AH=0x00;
AL=模式：（省略了一些不重要的畫面模式）
0x03：16色字符模式，80 × 25
0x12：VGA 圖形模式，640 × 480 × 4位彩色模式，獨特的4面存盤模式
0x13：VGA 圖形模式，320 × 200 × 8位彩色模式，調色板模式
0x6a：擴展VGA 圖形模式，800 × 600 × 4位彩色模式，獨特的4面存盤模式 （有的顯卡不支持這個模式）
回傳值：無
計算機組成學習
軟盤
沿半徑方向分割成18個扇區
按同心圓方式分割成80個柱面
由于磁盤正反兩面都能記錄資料，所以有兩個磁頭
一般向一個空軟盤保存檔案時
(1) 檔案名會寫在0x002600以后的地方；
(2) 檔案的內容會寫在0x004200以后的地方，
編譯原理學習
自己的理解：
.c檔案首先gcc編譯器的處理下，生成.gas檔案，
.gas檔案接著生成.obj目標檔案
.obj目標檔案在通過link后生成.bim檔案
.bim雖然是二進制映像檔案但是缺少一下必要的檔案頭和壓縮
所以還需加工成.hrb真正的完整的機器語言檔案
筆者對編譯程序解釋見原著：
首先，使用cc1.exe從bootpack.c生成bootpack.gas，
第二步，使用gas2nask.exe從bootpack.gas生成bootpack.nas，
第三步，使用nask.exe從bootpack.nas生成bootpack.obj，
第四步，使用obi2bim.exe從bootpack.obj生成bootpack.bim，
最后，使用bim2hrb.exe從bootpack.bim生成bootpack.hrb，
這樣就做成了機器語言，再使用copy指令將asmhead.bin與bootpack.hrb單純結合到起來， 就成了haribote.sys，
轉載請註明出處，本文鏈接：https://www.uj5u.com/caozuo/354403.html
標籤：其他