批處理IF陳述句塊語法

我有以下代碼（批量）來測驗不起作用的較大代碼的一部分：

@echo off
set /a slotted55=8
set /a place=55
set /a key3=8
set /a key1=0
set /a key2=0
set /a key4=0
set /a key5=0
set /a key6=0
set /a strike=0
 if %place%==55 (
    if %key1%==%slotted55% (
        set key1=V
        set slotted55=V
        goto 5x5one
    ) else (
        if %key2%==%slotted55% (
            set key2=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key3%==%slotted55% (
            set key3=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key4%==%slotted55% (
            set key4=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key5%==%slotted55% (
            set key5=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key6%==%slotted55% (
            set key6=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        set /a strike=%strike%  1
        if %strike%==3 goto gameover
        set %slotted55%=X
        goto 5x5one
    )
 )
:gameover
echo gameover
pause
exit
:5x5one
echo good
pause

出于某種原因，它不斷崩潰。我查看了多個其他問題，但似乎沒有一個適合這種情況。所有變數似乎都是正確的，并且沒有丟失運算元，但它不像批處理那樣給你一個錯誤資訊。誰能幫我？

uj5u.com熱心網友回復：

正如我在評論中所述，您不需要任何else陳述句，而且由于您的開頭if陳述句沒有else，您應該從使用相反的比較開始，因此不要將所有內容都嵌套在一組括號中。

@Echo Off
SetLocal EnableExtensions
Set "place=55"
Set /A "key3=slotted55=8"
Set /A "key1=key2=key4=key5=key6=strike=0"

If "%place%" NEq "55" GoTo gameover

If "%key1%" == "%slotted55%" (
    Set "key1=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key2%" == "%slotted55%" (
    Set "key2=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key3%" == "%slotted55%" (
    Set "key3=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key4%" == "%slotted55%" (
    Set "key4=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key5%" == "%slotted55%" (
    Set "key5=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key6%" == "%slotted55%" (
    Set "key6=V"
    Set "slotted55=V"
    GoTo 5x5one
)
Set /A strike  = 1
If %strike% Equ 3 GoTo gameover
Set "slotted55=X"
GoTo 5x5one

:gameover
Echo gameover
Pause
Exit /B

:5x5one
Echo good
Pause

uj5u.com熱心網友回復：

由于您放置)s 的位置，您的所有else陳述句都在相互查看，而不是if您撰寫的其他陳述句。現在，你的邏輯看起來像這樣：

if "%x%"=="5" (
    echo X is 5
) else (
    echo X is not 5
) else (
    echo X is somehow neither 5 nor is it not 5
)

如果您將 yourelse與 next結合起來if，您的邏輯將再次有意義。

set /a strike=0
if %place%==55 (
    if %key1%==%slotted55% (
        set key1=V
        set slotted55=V
        goto 5x5one
    ) else if %key2%==%slotted55% (
        set key2=V
        set slotted55=V
        goto 5x5one
    ) else if %key3%==%slotted55% (
        set key3=V
        set slotted55=V
        goto 5x5one
    ) else if %key4%==%slotted55% (
        set key4=V
        set slotted55=V
        goto 5x5one
    ) else if %key5%==%slotted55% (
        set key5=V
        set slotted55=V
        goto 5x5one
    ) else if %key6%==%slotted55% (
        set key6=V
        set slotted55=V
        goto 5x5one
    ) else (
        set /a strike=%strike%  1
        if %strike%==3 goto gameover
        set %slotted55%=X
        goto 5x5one
    )
)

uj5u.com熱心網友回復：

您正在此處使用遞增數字，您可以只使用 for 回圈并在for回圈內使用單個 if 陳述句：

@echo off
setlocal enabledelayedexpansion

set /a slotted55=8, place=55, key3=8, key1=0, key2=0, key4=0, key5=0, key6=0, strike=0
if %place% neq %slotted55% goto :gameover
for /L %%i in (1,1,6) do (
       if !key%%i! equ %slotted55% (
            set "key%%i=V"
            set "slotted55=V"
            goto :5x5one
    ) 
)
:gameover
set /a strike =1
if %strike% equ 3 (
    echo gameover
    pause
    exit
)
set "slotted55=X"

:5x5one
echo good
pause

就目前而言，這里似乎缺少一些東西，strike=3除非您必須goto回傳回圈，否則您將永遠無法到達。因此，如果沒有所有else陳述句，此代碼將像您一樣作業。

標籤：if 语句 批处理文件 句法

上一篇：批量洗掉排除特定檔案夾下的檔案（或具有特定模式/通配符的檔案名，例如Test123.csv、Test623.csv、Test854.csv）

下一篇：批處理：在字串中查找帶引號的子字串