TObjectList<T>.IndexOf給出不正確的結果

我試圖理解為什么我使用的方式TObjectList<T>.IndexOf對我不起作用。

下面是一個小例子

program Project3;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  madExcept,
  madLinkDisAsm,
  madListHardware,
  madListProcesses,
  madListModules,
  System.Generics.Defaults,
  System.Generics.Collections,
  System.Contnrs,
  System.SysUtils;

type
  TRecordObject = class(TObject)
    ID: Integer;
    Price: Currency;
    Matched: Boolean;
  public
    constructor Create(aSort: Integer; aPrice, aSize: Currency; aID: string; aNewParam: Integer;
      aSecondPrice, aSecondSize: Currency; aMatched: boolean); reintroduce;
  end;

  TSortCriterion<T> = class(TObject)
    Ascending: Boolean;
    Comparer: IComparer<T>;
  end;

  TSortCriteriaComparer<T> = class(TComparer<T>)
  private
    SortCriteria: TObjectList<TSortCriterion<T>>;
  public
    constructor Create;
    destructor Destroy; override;
    function Compare(const Right, Left: T): Integer; override;
    procedure ClearCriteria; virtual;
    procedure AddCriterion(NewCriterion: TSortCriterion<T>); virtual;
  end;

  TIDComparer = class(TComparer<TRecordObject>)
  public
    function Compare(const Left, Right: TRecordObject): Integer; override;
  end;

  TMatchedComparer = class(TComparer<TRecordObject>)
  public
    function Compare(const Left, Right: TRecordObject): Integer; override;
  end;

procedure TSortCriteriaComparer<T>.AddCriterion(NewCriterion: TSortCriterion<T>);
begin
  SortCriteria.Add(NewCriterion);
end;

procedure TSortCriteriaComparer<T>.ClearCriteria;
begin
  SortCriteria.Clear;
end;

function TSortCriteriaComparer<T>.Compare(const Right, Left: T): Integer;
var
  Criterion: TSortCriterion<T>;
begin
  for Criterion in SortCriteria do
  begin
    Result := Criterion.Comparer.Compare(Right, Left);
    if not Criterion.Ascending then
      Result := -Result;
    if Result <> 0 then
      Exit;
  end;
end;

constructor TSortCriteriaComparer<T>.Create;
begin
  inherited;
  SortCriteria := TObjectList<TSortCriterion<T>>.Create(True);
end;

destructor TSortCriteriaComparer<T>.Destroy;
begin
  SortCriteria.Free;
  inherited;
end;



    
function TIDComparer.Compare(const Left, Right: TRecordObject): Integer;
begin
  if Left.ID > Right.ID then
    Result := 1
  else if Left.ID < Right.ID then
    result := -1
  else
    result := 0;
end;

constructor TRecordObject.Create(aSort: Integer; aPrice, aSize: Currency; aID: string;
  aNewParam: Integer; aSecondPrice, aSecondSize: currency; aMatched: boolean);
begin
  ID := aSort;
  Price := aPrice;
  Matched := aMatched;
end;

var
  MyComparer: TSortCriteriaComparer<TRecordObject>;
  Criterion: TSortCriterion<TRecordObject>;
  MyList: TObjectList<TRecordObject>;
  MyObject: TRecordObject;
  ReturnValue: Integer;
  Result: Boolean;

function TMatchedComparer.Compare(const Left, Right: TRecordObject): Integer;
begin
  if Left.Matched > Right.Matched then
    Result := 1
  else if Left.Matched < Right.Matched then
    result := -1
  else
    result := 0;
end;

var
  SearchObject: TRecordObject;

begin
  MyComparer := TSortCriteriaComparer<TRecordObject>.Create;
  try
    Criterion := TSortCriterion<TRecordObject>.Create;
    Criterion.Ascending := True;
    Criterion.Comparer := TIDComparer.Create;
    MyComparer.AddCriterion(Criterion);

    Criterion := TSortCriterion<TRecordObject>.Create;
    Criterion.Ascending := True;
    Criterion.Comparer := TMatchedComparer.Create;
    MyComparer.AddCriterion(Criterion);

    MyList := TObjectList<TRecordObject>.Create;

    MyObject := TRecordObject.Create(26, 1, 1, '', 1, 1, 1, False);
    MyList.Add(MyObject);

    MyObject := TRecordObject.Create(26, 1, 1, '', 1, 1, 1, True);
    MyList.Add(MyObject);

    MyObject := TRecordObject.Create(24, 1, 1, '', 1, 1, 1, True);
    MyList.Add(MyObject);

    MyObject := TRecordObject.Create(24, 1, 1, '', 1, 1, 1, True);
    MyList.Add(MyObject);

    MyObject := TRecordObject.Create(34, 1, 1, '', 1, 1, 1, False);
    MyList.Add(MyObject);

    MyList.Sort(MyComparer);

    SearchObject := TRecordObject.Create(26, 1, 1, '', 1, 1, 1, True);

    // Result=3 (correct)
    Result := MyList.BinarySearch(SearchObject, ReturnValue, MyComparer);

    Writeln(Result);
    Writeln('ReturnValue with BinarySearch='   IntToStr(ReturnValue));

    //Result=-1=not found (incorrect)
    ReturnValue := MyList.IndexOf(SearchObject);
    Writeln('ReturnValue with IndexOf='   IntToStr(ReturnValue));
    Readln;

  finally
    Criterion.Free;
    MyComparer.Free;
    MyList.Free;
  end;
end.

如果我使用，TObjectList<T>.BinarySearch我會得到正確的結果“3”，但如果我使用，TObjectList<T>.IndexOf我會得到 -1（未找到）。

SearchObject 在這里僅用于確保傳遞給 .BinarySearch 和 IndexOf 的兩個物件相同。

我嘗試在 .BinarySearch 之前執行 .IndexOf ，因為我認為在搜索之后必須重置某些內容，但這也不起作用。

我究竟做錯了什么？

編輯

我也替換了TObjectList<T>，TList<T>但同樣的錯誤仍然存??在。

uj5u.com熱心網友回復：

二分搜索呼叫通過您的自定義比較器，因此知道如何根據您在那里撰寫的規則來識別物件。但是您的呼叫IndexOf沒有通過您的比較器，并且由于您在創建集合時沒有提供，因此使用默認比較器。

默認比較器使用物件標識，并且由于您的搜索物件不在集合中，因此回傳 -1，這是您提出的問題的正確答案。

解決方案：將比較器傳遞給集合建構式。

MyList := TObjectList<TRecordObject>.Create(MyComparer);

標籤：德尔福 泛型

上一篇：如何從緩沖區加載jpeg影像？

下一篇：Include在使用DTO類的用例中產生null