Arduino固定翼航模SU-27的設計與制作

前言：

利用兩塊Arduino開發板來分別制作遙控裝置和接收裝置，兩者之間使用無線模塊進行通信，從而實作對航模包括拉高、拉低、左轉、右轉的姿態控制，

材料準備：

SU-27航模（慷訓）、Arduino開發板X2（這里使用的是UNO和MEGA2560）、HC-12無線通信模塊X2、A2212無刷電機（1400KV、8060槳葉）、無刷電調（30A）、動力鋰電池（3S、2200mAh、40C）、SG90舵機X2（9g）、JoyStick搖桿X2、杜邦線若干

硬體結構：

實物圖：

用木條加固了機翼

拿木頭做的遙控器外殼

程式設計：

發送端：

/*
send.ino
*/

#include <SoftwareSerial.h>//使用了軟串口庫

//三個引腳名稱宏定義
#define power_pin A0//獲取油門控制數值的引腳
#define fly_pin   A5//獲取拉高拉低數值的引腳
#define turn_pin  A2//獲取左右轉向數值的引腳

//實體化軟串口物件
SoftwareSerial mySerial(10, 11); // RX, TX

//初始值賦值
int last_power_val=510;
int last_fly_val=500;
int last_turn_val=510;

void setup() {  
  Serial.begin(9600);
  mySerial.begin(9600);
}

void loop() { 
  //讀取三個引腳的數值
  int power_val=analogRead(power_pin);
  int fly_val=analogRead(fly_pin);
  int turn_val=analogRead(turn_pin);
  //輸出數值便于監測
  Serial.println(power_val);
  Serial.println(fly_val);
  Serial.println(turn_val);

  //當前后兩次讀取的數值差值超過10就發送一次資料
  if(abs(power_val-last_power_val)>10){
    
    mySerial.print("pow"+(String)power_val);
    last_power_val=power_val;//保存本次讀取的數值
    delay(50);//避免串口資料同時發送導致讀取出錯
  }
  if(abs(fly_val-last_fly_val)>10){
    
    mySerial.print("fly"+(String)fly_val);
    last_fly_val=fly_val;
    delay(50);
  }
  if(abs(turn_val-last_turn_val)>10){
    
    mySerial.print("tur"+(String)turn_val);
    last_turn_val=turn_val;
    delay(50);
  } 
  
 //避免串口資料量過大導致接收出錯
 delay(500);
}

接收端：

#include <Servo.h>//使用舵機庫來控制電調和舵機

//電調和舵機引腳名稱定義
#define pow_servo_pin    9
#define left_servo_pin   11
#define right_servo_pin  12
//油門物件
Servo pow_servo; 
//左舵機物件
Servo left_servo;
//右舵機物件
Servo right_servo;

//輸出的數值初始化為0
int power_val=0;
int fly_val=0;
int turn_val=0;

void setup() {
  Serial.begin(9600);
  //mySerial.begin(9600);
  Serial3.begin(9600);
  pow_servo.attach(pow_servo_pin,1000,2000);//設定電調的PWM信號頻率
  left_servo.attach(left_servo_pin);
  right_servo.attach(right_servo_pin);
  delay(2000);
}

void loop() {
  //從緩沖區讀取收到的字串
   String str="";
   while(Serial3.available()){
    char ch=(char)Serial3.read();
    str+=ch;
    delay(2);
   }
   if(str.length()>0){
    //截取識別符號和有效資料
      String key=str.substring(0,3);
      String value=str.substring(3,str.length());
      //Serial.println(str);
      //獲取油門數值
      if(key=="pow"){
        power_val=getInt(value);
        power_val=map(power_val,0,1023,0,180);
        pow_servo.write(power_val);
        Serial.print("power:");
        Serial.println(power_val);
        
      }
      //獲取拉高拉低數值
      if(key=="fly"){
        fly_val=getInt(value);
        fly_val=map(fly_val,0,1023,0,160);
        fly_val=160-fly_val;  
        left_servo.write(fly_val);
        right_servo.write(fly_val);  
        Serial.print("fly:");
        Serial.println(fly_val);          
      }
      //獲取左右轉向數值
      if(key=="tur"){
        turn_val=getInt(value);
        if(turn_val>510){
          turn_right(turn_val);
        }
        if(turn_val<510){
          turn_left(turn_val);
        }
        
//        Serial.print("turn:");
//        Serial.println(turn_val);        
      }        
   }   
}
//左轉函式
void turn_left(int x){
  int x1=map(x,0,510,0,110);
  int x2=(int)(110+(510-x)*50/500);
  //int x2=(int)160-0.1*x;
  right_servo.write(x1);
  left_servo.write(x2);
  Serial.println("**************************");
  Serial.println("Turn left：");
  Serial.print("left_servo:");
  Serial.println(x2);
  Serial.print("right_servo:");
  Serial.println(x1);
  Serial.println("**************************");
}
//右轉函式
void turn_right(int x){
  int x1=map(x,510,1023,110,160);
  int x2=(int)(110-(x-510)*50/(1023-510));
  //int x2=(int)160-0.1*x;
  right_servo.write(x1);
  left_servo.write(x2);
  Serial.println("**************************");
  Serial.println("Turn right:");
  Serial.print("left_servo:");
  Serial.println(x2);
  Serial.print("right_servo:");
  Serial.println(x1);
  Serial.println("**************************");
}
//字串轉整數函式
int getInt(String str){
  int num=0;
  for(int i=0;i<str.length();i++){
    num*=10;
    num+=str[i]-'0';    
  }  
  return num;
}


//拉高：兩側機翼全部向上翻轉
//拉低：兩側機翼全部向下翻轉
//左轉：左側機翼下翻，右側機翼上翻
//右轉：左側機翼上翻，右側機翼下翻

//經過實測,在此航模上舵機的轉動
//角度在0—160的范圍內,即可實
//現機翼的上下完全翻轉

最后，經過多次的測驗、修改、試飛，它真的比較好的飛起來了！

這是一件很有意思、很讓人激動的事情！