最簡潔的Erlang基礎-有解無憂

0x00 說在前面

Erlang讀音/???rl??/，第一次見到的時候總感覺怎么讀都讀不對，后來在維基上看到Erlang標注了音標，才能準確的讀出來，而且也沒那么怪異，因為作業才有機會接觸這門語言，也因此只有三天的時間可以看《Erlang程式設計》這本書，學習這門語言的時候帶著一個作業目標：把一個Erlang日志收集分析統計的代碼轉換成Python的，而Erlang的風格是盡量不寫注釋，盡量在寫函式名和變數名的時候表達清楚代碼的含義，這樣一來學習Erlang就成了必要的，很慶幸，領導給了三天時間學習，三天時間基本也足夠了，除了這一片基礎語法的入門篇之外，后續還有一篇或者兩篇并發編程和分布式編程的，畢竟這個才是Erlang擅長的領域，話不多說，show me your article

0x01 配置開發環境

依賴工具：

Erlang版本：18.3
IDE：IDEA

下載鏈接：

Erlang：https://www.erlang.org/downloads 選擇otp18.3即可，
IDEA：https://www.jetbrains.com/idea/download 選擇社區版即可，

IDEA配置Erlang插件：

IDEA官方檔案-使用IDEA開發Erlang

0x02 基礎知識

注釋

% 百分比符號標明注釋的開始，
%% 兩個符號通常用于注釋函式，
%%% 三個符號通常用于注釋模塊，

變數

所有的變數都必須以大寫字母開頭，變數只可一次賦值，賦值之后不可在變， f()函式釋放shell系結變數，

浮點數

浮點數必須含有小數點且小數點后必須有一位10進制數
用/來除兩個整數時相除結果會自動轉換成浮點數
div取整，rem取余

三種標點符號

整個函式的定義結束時用一個句號“.”
函式引數，資料構建，順序陳述句之間，用逗號“,”分隔
函式定義、case、if、try..catch、receive運算式中的模式匹配時，用分號“;”分界

恒等

恒等測驗符號 =:=以及不等測驗符號 =/=

塊運算式

當程式中某處的語法要求只能使用單個運算式但是邏輯上又需要在此使用多個運算式時，就可以使用begin...end快運算式

begin
  Expr1,
  ...
  ExprN
end

0x03 內置資料結構

元組及模式匹配（解構）

_ 代表丟棄的變數，和python相同
匹配時模式匹配符=左右兩邊的元組的結構必須相同，

1> Point = {point, 20, 43}.
{point,20,43}
2> {point, x, y} = Point.
** exception error: no match of right hand side value {point,20,43}
3> {point, X, Y} = Point.
{point,20,43}
4> X.
20
5> Y.
43
6> Person = {person, {name, {first, joe}, {last, armstrong}}, {footsize, 42}}.
{person,{name,{first,joe},{last,armstrong}},{footsize,42}}
7> {_, {_, {_, Who}, {_, _}}, {_, Size}} = Person.
{person,{name,{first,joe},{last,armstrong}},{footsize,42}}
8> Who.
joe
9> Size.
42

串列

串列元素可以是不同的型別，
串列頭：串列的第一個元素
串列尾：串列除第一個元素剩下的部分
豎線符號|
- 將串列的頭和尾分割開來
- [E1, E2, E4, ... , |L]：使用|向串列L的起始處加入多個元素構造成新的串列
串列鏈接運算子 ++ （中綴添加運算子）

串列操作演示代碼

1> L = [1+7, hello, 2-2, {cost, apple, 30-20}, 3]. 
[8,hello,0,{cost,apple,10},3]
2> L1 = [123, {oranges, 4} | L].
[123,{oranges,4},8,hello,0,{cost,apple,10},3]
3> [E1 | L2] = L1.
[123,{oranges,4},8,hello,0,{cost,apple,10},3]
4> E1.
123
5> L2.
[{oranges,4},8,hello,0,{cost,apple,10},3]
6> [E2, E3 | L3] = L2.
[{oranges,4},8,hello,0,{cost,apple,10},3]
7> E3.
8

串列運算式

形式：[F(X) || X <- L]

1> L = [1, 2, 3, 4, 5].
[1,2,3,4,5]
2> [2 * X || X <- L].
[2,4,6,8,10]
3> [X || {a, X} <- [{a, 1}, {b, 2}, {c, 3}, {a, 4}, hello, "wow"]].
[1,4]

字串

Erlang的字串是一個整數串列，整數串列的內容由每一個字符對應的ascii碼構成

1> I = $s.
115
2> [I-32, $u, $r, $p, $r, $i, $s, $e].
"Surprise"
3> $r.                                
114
4> [I-32, $u, $r, $p, 114, $i, $s, $e].
"Surprise"

映射組(Map)

映射組是一個由多個Key-Vaule結構組成的符合資料型別，類似于Python的字典，具體使用如下

1> M1 = #{"name" => "alicdn", "percentage" => 80}.
#{"name" => "alicdn","percentage" => 80}
2> maps:get("name", M1).
"alicdn"
3> M2 = maps:update("percentage", 50, M1).
#{"name" => "alicdn","percentage" => 50}
4> map_size(M1).
2
5> #{"name" := X, "percentage" := Y} = M2.
#{"name" => "alicdn","percentage" => 50}
6> X.
"alicdn"
7> Y.
50

構造映射組和模式匹配時的符號不一樣，=>和:=的區別，常見的put方法參見erlang maps庫的使用，

0x04 模塊

一個模塊存放于一個.erl檔案中（模塊名和檔案名相同）
編譯模塊的命令：c(模塊名)，編譯成功之后就會加載到當前shell中
呼叫模塊中的函式：模塊名:函式名(引數)
匯入模塊中的函式：-import(lists, [map/2, sum/1]).
匯出模塊中的函式：
- 匯出指定函式-export([start/0, area/2]).
- 匯出全部函式-compile(export_all).，避免在開發階段經常會向export中添加函式或者洗掉函式

-module(learn_test).
-author("ChenLiang").

%% API
-export([area/1]).


area({rectangle, Width, Height}) -> Width * Height;
area({circle, R}) -> 3.14159 * R * R;
area({square, X}) -> X * X.

編譯模塊，呼叫函式

1> c(learn_test).
{ok,learn_test}
2> learn_test:area({circle, 2.0}).
12.56636
3>

0x05 函式

基本函式

同名同目（引數數量，arity）的才是同一個函式，因此函式名相同，目不相同的函式是完全不同的兩個函式，同名不同目的函式通常作為輔助函式，

函式不會顯示地回傳值，函式中最后一條陳述句的執行結果將作為函式的回傳值，
同一個函式中，并列的邏輯分支之間，用分號 “;” 分界；順序陳述句之間，用逗號 “,” 分隔，

示例代碼：計算串列元素的和

-module(learn_test).
-author("ChenLiang").

%% API
-export([sum/1]).

sum(L) -> sum(L, 0).

sum([], N) -> N;
sum([H|T], N) -> sum(T, H + N).

匿名函式

erlang中的匿名函式就是fun，fun也可以有若干個不同的字句，

1> Z = fun(X) -> 2*X end.
#Fun<erl_eval.6.50752066>
2> Double = Z.
#Fun<erl_eval.6.50752066>
3> Double(4).
8
4> TempConvert = fun({c, C}) -> {f, 32 + C * 9 / 5};
5> ({f, F}) -> {c, (F - 32) * 5 / 9}                
6> end.                                             
#Fun<erl_eval.6.50752066>
7> TempConvert({c, 100}).                           
{f,212.0}
8> TempConvert({f, 212}).
{c,100.0}

高階函式

回傳fun或者接受fun作為引數的函式都稱為高階函式，

以fun為引數的函式

常見的是lists模塊中的map(Fun, List1) -> List2，filter(Pred, List1) -> List2函式，

lists模塊的具體使用參見：https://www.erlang.org/doc/man/lists.html

1> Even = fun(X) -> X rem 2 =:= 0 end.
#Fun<erl_eval.6.50752066>
2> lists:map(Even, [1, 2, 3, 4, 5, 6]).
[false,true,false,true,false,true]
3> lists:filter(Even, [1, 2, 3, 4, 5, 6]).
[2,4,6]

回傳fun的函式

一般在回傳的函式內部封裝了一些變數和邏輯，通常情況下不寫回傳fun的函式，

1> Mult = fun(Times) -> (fun(X) -> X * Times end ) end.
#Fun<erl_eval.6.50752066>
2> Triple = Mult(3).
#Fun<erl_eval.6.50752066>
3> Triple(4).
12

0x06 斷言

強化模式匹配的功能，給模式匹配增加一些變數測驗和比較的能力

max(X, Y) when X > Y -> X;
max(_, Y) -> Y.

0x07 記錄

記錄是Erlang中基于元組的key-value資料定義，使用示例如下：

-module(learn_test).
-author("ChenLiang").

%% API
-export([record_test1/0, record_test2/0]).

-record(person, {name, age=18, hobby=["erlang"]}).    %% record定義可以存放于hrl和erl中

record_test1() ->
  Person = #person{name="hahaha"},    %% 為record中欄位賦值
  Person#person.hobby.    %%  通過.運算子訪問record中欄位

record_test2() ->
  Person = #person{},
  #person{name = Name} = Person,    %% 通過模式匹配獲取record欄位
  Name. %% 輸出undefined

0x08 .hrl頭檔案

某些檔案的擴展名為 .hrl，這些.hrl是在 .erl 檔案中會用到的頭檔案，使用方法如下：

-include("File_Name").

例如：

-include("mess_interface.hrl").

.hrl 檔案中可以包含任何合法的 Erlang 代碼，但是通常里面只包含一些記錄和宏的定義，

0x09 case / if 運算式

case 運算式

case陳述句語法

case Experssion of
  Pattern1 [when Guard1] -> Expr_seq1;
  Pattern2 [when Guard2] -> Expr_seq2;
  ...
end

將Expression的結果和各個Pattern逐個匹配，匹配成功，則計算運算式序列的值，并回傳，全部匹配不到，則直接報錯，

case陳述句使用示例:

-module(learn_test).
-author("ChenLiang").

%% API
-export([filter/2]).


filter(P, [H|T]) ->
  case P(H) of
    true -> [H|filter(P, T)];
    false -> filter(P, T)
  end
;
filter(_, []) -> [].

在erl shell中運行結果如下：

1> c(learn_test).
{ok,learn_test}
2> learn_test:filter(fun(X) -> X rem 2 =:= 0 end, [1, 2, 3, 4, 5]).
[2,4]

if 運算式

if陳述句使用示例

-module(learn_test).
-author("ChenLiang").

%% API
-export([bigger/2]).


bigger(X, Y) ->
  if
    X > Y -> X;
    X < Y -> Y;
    true -> -1
  end.

如果沒有匹配的斷言，則會拋出例外，因此最后一個斷言通常是true斷言，

0x10 例外

Erlang中一切都是運算式，都有回傳值，因此例外捕獲陳述句也有回傳值，

捕獲所有的例外_:_

-module(learn_test).
-author("ChenLiang").

%% API
-export([catch_exc1/0,catch_exc2/0]).


exception() ->
  exit({system, "123123"}).

catch_exc1() ->
  try
      exception()
  catch
      _:_  -> 111
  end.

catch_exc2() ->
  try
    exception()
  catch
    _  -> 222
  end.

erl shell輸出結果

1> learn_test:catch_exc1().
111
2> learn_test:catch_exc2().
** exception exit: {system,"123123"}
     in function  learn_test:exception/0 (learn_test.erl, line 17)
     in call from learn_test:catch_exc2/0 (learn_test.erl, line 28)

多種錯誤的檢測可以使用try catch風格，

參考stackoverflow-How do I elegantly check many conditions in Erlang?

記得幫我點贊哦！

精心整理了計算機各個方向的從入門、進階、實戰的視頻課程和電子書，按照目錄合理分類，總能找到你需要的學習資料，還在等什么？快去關注下載吧！！！

resource-introduce

念念不忘，必有回響，小伙伴們幫我點個贊吧，非常感謝，

我是職場亮哥，YY高級軟體工程師、四年作業經驗，拒絕咸魚爭當龍頭的斜杠程式員，

聽我說，進步多，程式人生一把梭

如果有幸能幫到你，請幫我點個【贊】，給個關注，如果能順帶評論給個鼓勵，將不勝感激，

職場亮哥文章串列：更多文章

wechat-platform-guide-attention

本人所有文章、回答都與著作權保護平臺有合作，著作權歸職場亮哥所有，未經授權，轉載必究！

轉載請註明出處，本文鏈接：https://www.uj5u.com/houduan/224150.html

標籤：其他

上一篇：寶塔上TP5開啟404頁面后，沒有反應

下一篇：Java泛型中<?> 和 <? extends Object>的異同分析