（編輯）根據@michael.hor257k 的建議，我還包括了輸入 XML 的詳細形式。
我有一個無法控制的輸入 XML，需要在 XSLT 中對其進行轉換。請注意，與SO上的許多“相關答案”不同，在這種情況下，“深度”級別并不是每個專案的屬性，而是需要從路徑中計算出來。
這是我的問題的 XSLT 小提琴：http: //xsltransform.net/6rexjhn/3
這是輸入的簡化形式（緊湊形式）：
<?xml version="1.0" encoding="UTF-8"?>
<data>
<settings>
<field style="attribute" level="one.quality" target="one.quality">high</field>
<field style="attribute" level="one.weight" target="one.weight">10 kg</field>
<field style="element" level="one_two" target="two">A</field>
<field style="attribute" level="one_three.color" target="three.color">black</field>
<field style="element" level="one_three_four" target="four" >B</field>
<field style="attribute" level="one_three_four.length" target="four.length">12 cm</field>
<field style="attribute" level="one_three_four.width" target="four.width"> 7 cm</field>
<field style="element" level="one_three_five" target="five" >C</field>
<field style="attribute" level="one_six.size" target="six.size" >large</field>
<field style="element" level="one_six_seven_eight" target="eight">D</field>
<field style="element" level="one_nine" target="nine">E</field>
</settings>
</data>
這是詳細的形式：
<?xml version="1.0" encoding="UTF-8"?>
<data>
<settings>
<field style="element" level="one" target="one"></field>
<field style="attribute" level="one.quality" target="one.quality">high</field>
<field style="attribute" level="one.weight" target="one.weight">10 kg</field>
<field style="element" level="one_two" target="two">A</field>
<field style="element" level="one_three" target="three"></field>
<field style="attribute" level="one_three.color" target="three.color">black</field>
<field style="element" level="one_three_four" target="four" >B</field>
<field style="attribute" level="one_three_four.length" target="four.length">12 cm</field>
<field style="attribute" level="one_three_four.width" target="four.width"> 7 cm</field>
<field style="element" level="one_three_five" target="five" >C</field>
<field style="element" level="one_six" target="six" ></field>
<field style="attribute" level="one_six.size" target="six.size" >large</field>
<field style="element" level="one_six_seven" target="seven" ></field>
<field style="element" level="one_six_seven_eight" target="eight">D</field>
<field style="element" level="one_nine" target="nine">E</field>
</settings>
</data>
展平是這樣的：（1）下劃線代表目標的子元素，（2）句點代表屬性，（3）最大深度未知但應該是合理的，（4）有子元素的元素有只有子元素，沒有獨立值。這就是我想要得到的：
<?xml version="1.0" encoding="UTF-8"?>
<template xmlns="http://www.example.org/standards/template/1"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:ac="http://www.example.org/Standards/abc/1"
xsi:schemaLocation="http://www.example.org/standards/template.xsd"
Version="2022-01">
<one quality="high" weight="10 kg">
<two>A</two>
<three color="black">
<four length="12 cm" width="7 cm">B</four>
<five>C<five>
</three>
<six size="large">
<seven>
<eight>D</eight>
<seven>
</six>
<nine>E</nine>
</one>
</template>
基于這個也沒有深度屬性的 SO 答案，這是我嘗試過的（使用 XSLT 1.0）。很多資料丟失了，我不知道如何處理屬性。
<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" doctype-public="XSLT-compat" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:key name="siblings" match="*[not(self::field)]" use="generate-id(preceding-sibling::field[1])" />
<xsl:key name="nextlevel" match="field" use="generate-id(preceding-sibling::field[@level][starts-with(current(), concat(., '_'))][1])" />
<xsl:template match="/">
<template xmlns="http://www.example.org/standards/template/1"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:ac="http://www.example.org/Standards/abc/1"
xsi:schemaLocation="http://www.example.org/standards/template.xsd"
Version="2022-01">
<one quality="{//field[@target='one.quality']}" weight="{//field[@target='one.weight']}">
<xsl:apply-templates select="//field[@level='one']" />
</one>
</template>
</xsl:template>
<!-- Fetch elements -->
<xsl:template match="//field[@style='element']">
<xsl:element name="{@target}">
<xsl:apply-templates select="key('siblings', generate-id())" />
<xsl:apply-templates select="key('nextlevel', generate-id())" />
</xsl:element>
</xsl:template>
<!-- identity copy transform -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
</xsl:transform>
這就是我使用上面的 XSLT 得到的：
<?xml version="1.0" encoding="UTF-8"?>
<template xmlns="http://www.example.org/standards/template/1"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:ac="http://www.example.org/Standards/abc/1"
xsi:schemaLocation="http://www.example.org/standards/template.xsd"
Version="2022-01">
<one quality="high" weight="10 kg"/>
</template>
uj5u.com熱心網友回復：
在我看來，鑒于您的“冗長”輸入，您可以使用以下方法輕松實作預期結果：
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns="http://www.example.org/standards/template/1" >
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:key name="elem" match="field[@style='element']" use="substring-before(@level, @target)" />
<xsl:key name="attr" match="field[@style='attribute']" use="substring-before(@level, '.')" />
<xsl:template match="/">
<template xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.example.org/standards/template.xsd" xmlns:ac="http://www.example.org/Standards/abc/1" Version="2022-01">
<xsl:apply-templates select="key('elem', '')" />
</template>
</xsl:template>
<xsl:template match="field[@style='element']">
<xsl:element name="{@target}">
<xsl:apply-templates select="key('attr', @level)" />
<xsl:value-of select="." />
<xsl:apply-templates select="key('elem', concat(@level, '_'))" />
</xsl:element>
</xsl:template>
<xsl:template match="field[@style='attribute']">
<xsl:attribute name="{substring-after(@target, '.')}">
<xsl:value-of select="." />
</xsl:attribute>
</xsl:template>
</xsl:stylesheet>
請注意，沒有任何節點名稱的硬編碼，并且層次結構深度是無限的。
轉載請註明出處，本文鏈接：https://www.uj5u.com/houduan/474968.html