各位好。我是小白。從來沒有用過delphi，但是有特別想做一個傻瓜式的資料庫查詢軟體。用了delphi， 現在學了一天，能夠執行查詢了。但是，我現在需要的是將這些查詢到資料匯出到 EXCEL表中，我是小白，完全不懂。所以希望能詳細點說，如果能夠圖文教程最好，謝謝大家。
這個我是已經做好的圖，能夠連接到資料庫，并且點擊查詢還能夠查詢到資料。
現在唯一的問題就是，想實作 點擊 匯出到EXCEL的功能實作，把查詢到資料直接匯出到EXCEL表中。請問，如何實作呢？
我是小白，完全沒有學過這個語言。
然后我在其他地方下載了一個uExportXls.pas 檔案。但是卻完全不知道怎么
用，在網上也找不到對應的視頻，教程，所以只有跑這里來問問大家了。再次感謝！！
{ 背景：今天要把DataSet匯入Excel，查詢以前的貼子，一部分用Ole，速度太慢，
一部分用ADO連接到Excel檔案，也很慢，一氣之下把DBGrigEh的匯出部分改了出來，
歡迎大家指教、改進。
功能：將資料集的資料匯入Excel;
用法：With ExportXls.Create(TDataSet(ADOQuery1)) do
Try
Save2File(SaveDialog1.FileName, True);
finally
Free;
end;
作者：Caidao (核心代碼來自Ehlib)
時間：2003-04-09
地點：汕頭
}
unit uExportXls;
interface
uses
DB, Classes;
var
CXlsBof: array[0..5] of Word = ($809, 8, 0, $10, 0, 0);
CXlsEof: array[0..1] of Word = ($0A, 00);
CXlsLabel: array[0..5] of Word = ($204, 0, 0, 0, 0, 0);
CXlsNumber: array[0..4] of Word = ($203, 14, 0, 0, 0);
CXlsRk: array[0..4] of Word = ($27E, 10, 0, 0, 0);
CXlsBlank: array[0..4] of Word = ($201, 6, 0, 0, $17);
type
TFldRec = record
Title: string;
Width: Integer;
end;
ExportXls = class(TObject)
private
FCol: word;
FRow: word;
FDataSet: TDataSet;
Stream: TStream;
FWillWriteHead: boolean;
FBookMark: TBookmark;
procedure IncColRow;
procedure WriteBlankCell;
procedure WriteFloatCell(const AValue: Double);
procedure WriteIntegerCell(const AValue: Integer);
procedure WriteStringCell(const AValue: string);
procedure WritePrefix;
procedure WriteSuffix;
procedure WriteTitle;
procedure WriteDataCell;
procedure Save2Stream(aStream: TStream);
public
procedure Save2File(FileName: string; WillWriteHead: Boolean);
constructor Create(aDataSet: TDataSet);
end;
function ExportToXLS(const FileName: string; DataSet: TDataSet): Boolean;
implementation
uses SysUtils;
function ExportToXLS(const FileName: string; DataSet: TDataSet): Boolean;
begin
Result := False;
with ExportXls.Create(DataSet) do try
Save2File(FileName, True);
Result := True;
finally
Free;
end;
end;
constructor ExportXls.Create(aDataSet: TDataSet);
begin
inherited Create;
FDataSet := aDataSet;
end;
procedure ExportXls.IncColRow;
begin
if FCol = FDataSet.FieldCount - 1 then begin
Inc(FRow);
FCol := 0;
end
else
Inc(FCol);
end;
procedure ExportXls.WriteBlankCell;
begin
CXlsBlank[2] := FRow;
CXlsBlank[3] := FCol;
Stream.WriteBuffer(CXlsBlank, SizeOf(CXlsBlank));
IncColRow;
end;
procedure ExportXls.WriteFloatCell(const AValue: Double);
begin
CXlsNumber[2] := FRow;
CXlsNumber[3] := FCol;
Stream.WriteBuffer(CXlsNumber, SizeOf(CXlsNumber));
Stream.WriteBuffer(AValue, 8);
IncColRow;
end;
procedure ExportXls.WriteIntegerCell(const AValue: Integer);
var
V: Integer;
begin
CXlsRk[2] := FRow;
CXlsRk[3] := FCol;
Stream.WriteBuffer(CXlsRk, SizeOf(CXlsRk));
V := (AValue shl 2) or 2;
Stream.WriteBuffer(V, 4);
IncColRow;
end;
procedure ExportXls.WriteStringCell(const AValue: string);
var
L: Word;
begin
L := Length(AValue);
CXlsLabel[1] := 8 + L;
CXlsLabel[2] := FRow;
CXlsLabel[3] := FCol;
CXlsLabel[5] := L;
Stream.WriteBuffer(CXlsLabel, SizeOf(CXlsLabel));
Stream.WriteBuffer(Pointer(AValue)^, L);
IncColRow;
end;
procedure ExportXls.WritePrefix;
begin
Stream.WriteBuffer(CXlsBof, SizeOf(CXlsBof));
end;
procedure ExportXls.WriteSuffix;
begin
Stream.WriteBuffer(CXlsEof, SizeOf(CXlsEof));
end;
procedure ExportXls.WriteTitle;
var
n: word;
begin
for n := 0 to FDataSet.FieldCount - 1 do
WriteStringCell(FDataSet.Fields[n].DisplayLabel); //顯示標簽名
end;
procedure ExportXls.WriteDataCell;
var
Idx: word;
begin
WritePrefix;
if FWillWriteHead then WriteTitle;
FDataSet.DisableControls;
FBookMark := FDataSet.GetBookmark;
FDataSet.First;
while not FDataSet.Eof do begin
for Idx := 0 to FDataSet.FieldCount - 1 do begin
if FDataSet.Fields[Idx].IsNull then
WriteBlankCell
else begin
case FDataSet.Fields[Idx].DataType of
ftSmallint, ftInteger, ftWord, ftAutoInc, ftBytes:
WriteIntegerCell(FDataSet.Fields[Idx].AsInteger);
ftFloat, ftCurrency, ftBCD:
WriteFloatCell(FDataSet.Fields[Idx].AsFloat);
else
if Assigned(FDataSet.Fields[Idx].OnGetText) then
WriteStringCell(FDataSet.Fields[Idx].Text)
else
WriteStringCell(FDataSet.Fields[Idx].AsString);
end;
end;
end;
FDataSet.Next;
end;
WriteSuffix;
if FDataSet.BookmarkValid(FBookMark) then FDataSet.GotoBookmark(FBookMark);
FDataSet.EnableControls;
end;
procedure ExportXls.Save2Stream(aStream: TStream);
begin
FCol := 0;
FRow := 0;
Stream := aStream;
WriteDataCell;
end;
procedure ExportXls.Save2File(FileName: string; WillWriteHead: Boolean);
var
aFileStream: TFileStream;
begin
FWillWriteHead := WillWriteHead;
if FileExists(FileName) then DeleteFile(FileName);
aFileStream := TFileStream.Create(FileName, fmCreate);
try
Save2Stream(aFileStream);
finally
aFileStream.Free;
end;
end;
end.
uj5u.com熱心網友回復：
用第三方控制元件dbgrideh，cxgrid等表格，支持匯出到xls，效率要比自己寫的高很多。
uj5u.com熱心網友回復：
參考：http://blog.csdn.net/zang141588761/article/details/52275948
uj5u.com熱心網友回復：
簡單的代碼
procedure ExpXLS(DataSet: TDataSet; const AFilePath: string);
var
ExcApp: OleVariant;
i,l: integer;
begin
ExcApp := CreateOleObject('Excel.Application');
ExcApp.Visible := True;
ExcApp.WorkBooks.Add;
DataSet.First;
l := 1;
DataSet.First;
while not DataSet.EOF do
begin
for i := 0 to DataSet.Fields.Count - 1 do
ExcApp.WorkBooks[1].Sheets[1].Cells[l,i + 1] :=
DataSet.Fields[i].DisplayText;
DataSet.Next;
l := l + 1;
end;
ExcApp.WorkBooks[1].SaveAs(AFilePath);
end;
參考這里：
http://blog.csdn.net/avan_lau/article/details/24470345
uj5u.com熱心網友回復：
用第三方控制元件XLSReadWriteII4,配合dbgrideh，寫個方法一勞永逸。
procedure XLS_DBGridEh_EXCEL(Sender:TComponent;DBGrid:TDBGridEh;Title,FileName:string;
PageType,ShowZero,DoSum:integer;NoSum,NoCol:String;
percent:integer); // 通過XLS 生成Excel表
//Sender 主表單
//DBGrid DBGridEh
//Title 標題
//FileName 生成檔案名
//Pagetype 頁面樣式（0縱向，1橫向）
//ShowZero 顯示 0 （0不顯示，1顯示）
//DoSum 底欄統計匯總（0不，1可）
//NoSum 強制非匯總的列 格式：AAAA,BBBB,CCCC
//NoCol 強制非顯示的列 同上
//percent 顯示百分比
DBGrid
EXCEL
uj5u.com熱心網友回復：
#4 回答的不是很詳細啊，像我這樣的小白是不會懂的uj5u.com熱心網友回復：
用DBGridEh，下面這一句話就可以實作SaveDBGridEHTOExportFile(TdbgridehEXportasxls,dbgrideh1,'c:\查詢結果.xls',true);
轉載請註明出處，本文鏈接：https://www.uj5u.com/houduan/50786.html
標籤：數據庫相關