我有兩個 Goole Sheet 查詢，它們都按要求作業，我剩下的挑戰是結合兩者的結果并按日期排序。我的兩個查詢是：
=UNIQUE(FILTER({'My Data'!B13:B, 'My Data'!F13:F, 'My Data'!N13:N, 'My Data'!L13:L, 'My Data'!L13:L * 24 * 'My Data A'!K2 },
'My Data'!O13:O = "Y",
'My Data'!Q13:Q =G2,
MONTH('My Data'!B13:B) =E2,
YEAR('My Data'!B13:B) =C2
))
和
=UNIQUE(FILTER({'My Data 2'!A4:A, 'My Data 2'!E4:E, 'My Data 2'!D4:D, 'My Data 2'!F4:F,'My Data 2'!F4:F * 24 * 'My Data 2'!G4:G},
'My Data 2'!C4:C =G2,
MONTH('My Data 2'!A4:A) =E2,
YEAR('My Data 2'!A4:A) =C2
))
除了創建一個帶有兩個查詢的額外作業表然后查詢該作業表之外，我看不到其他方法可以滿足我的要求，但是這些仍然不能滿足我的需求！
有沒有辦法在作業表中做到這一點？
uj5u.com熱心網友回復：
嘗試：
=SORT({UNIQUE(FILTER({'My Data'!B13:B, 'My Data'!F13:F, 'My Data'!N13:N, 'My Data'!L13:L, 'My Data'!L13:L * 24 * 'My Data 2'!K2 },
'My Data'!O13:O = "Y",
'My Data'!Q13:Q =G2,
MONTH('My Data'!B13:B) =E2,
YEAR('My Data'!B13:B) =C2
));
UNIQUE(FILTER({'My Data 2'!A4:A, 'My Data 2'!E4:E, 'My Data 2'!D4:D, 'My Data 2'!F4:F,'My Data 2'!F4:F * 24 * 'My Data 2'!G4:G},
'My Data 2'!C4:C =G2,
MONTH('My Data 2'!A4:A) =E2,
YEAR('My Data 2'!A4:A) =C2
))})
更新：
=SORT({UNIQUE(FILTER({'My Data'!B13:B, 'My Data'!F13:F, 'My Data'!N13:N,
'My Data'!L13:L, 'My Data'!L13:L * 24 * Totals!K2 }, 'My Data'!O13:O = "Y",
'My Data'!Q13:Q =G3, MONTH('My Data'!B13:B) =E3, YEAR('My Data'!B13:B) =C3));
UNIQUE(FILTER({'Non Log'!A4:A, 'Non Log'!E4:E, 'Non Log'!D4:D, 'Non Log'!F4:F,
'Non Log'!F4:F * 24 * 'Non Log'!G4:G}, 'Non Log'!C4:C =G3,
MONTH('Non Log'!A4:A) =E3, YEAR('Non Log'!A4:A) =C3))}, 1, 0)
轉載請註明出處，本文鏈接：https://www.uj5u.com/houduan/524633.html
上一篇：Google表格中的復選框