我有兩個表，其中包含帶有通過/失敗變數的名稱資料。我試圖計算有多少人最初失敗但后來通過了。
| 姓名 | 通過 |
|---|---|
| 麥克風 | 通過 |
| 約翰 | 失敗的 |
| 比利 | 失敗的 |
| 姓名 | 通過 |
|---|---|
| 麥克風 | 通過 |
| 約翰 | 通過 |
| 比利 | 失敗的 |
我最初是通過創建帶有 IF 陣列的第三個表來做到這一點的，該陣列列出了失敗的人的姓名。然后我計算了“TRUE”的數量。
對于名稱：
=IFERROR(IFS(Table13[Passed]="FAILED", Table13[Name]), "")
稍后通過：
=IF(XLOOKUP(VALUETOTEXT(A2),Table1[Name],Table1[Passed])="Passed",TRUE,FALSE)
| 姓名 | 最初通過 | 稍后通過 |
|---|---|---|
| #不適用 | #不適用 | #不適用 |
| 約翰 | 失敗的 | 真的 |
| 比利 | 失敗的 | 錯誤的 |
最后得到了計數
=COUNTIF(Table3[Passed Later], "=TRUE")
通過將前兩個公式組合到
=IF(XLOOKUP(IFS(Table13[Passed]="Failed", Table13[Name]),Table1[Name],Table1[Passed])="Passed",TRUE,FALSE)
現在我被困在組合 COUNTIF 函式上。如果可能的話，我不知道如何將這一切實作為一個功能。有什么建議嗎？我認為我的主要問題是稍后通過列的輸出不是數字，而是字串。
uj5u.com熱心網友回復：
不確定這是否是正確的答案，但它有效。
輸入后：
我認為我的主要問題是稍后通過列的輸出不是數字，而是字串。
我能夠弄清楚。我只需要在最后一個 if 陳述句中為“Passed”提供一個數字輸出，并為“Failed”提供一個字串。這是我的最終公式，至少是我得出的解決方案。
=COUNT(IF(XLOOKUP(IFS(Table13[Passed]<>1, Table13[Name]),Table1[Name],Table1[Passed])=1,1,""))
想我會留下來幫助別人。
uj5u.com熱心網友回復：
使用兩個過濾器并使用 IsNumber(Match()) 檢查是否在第二個中找到第一個過濾器
=LET(
fst,FILTER(Table13[Name],Table13[Passed]="Failed"),
scd,FILTER(Table1[Name],Table1[Passed]= "Passed"),
SUM(--ISNUMBER(MATCH(fst,scd,0))))
如果你想要失敗者的名字然后通過添加另一個過濾器：
=LET(
fst,FILTER(Table13[Name],Table13[Passed]="Failed"),
scd,FILTER(Table1[Name],Table1[Passed]= "Passed"),
FILTER(fst,ISNUMBER(MATCH(fst,scd,0))))
uj5u.com熱心網友回復：
以下作業是否可行：
中的公式G1：
=FILTER(A2:A5,COUNTIFS(A2:A5,A2:A5,B2:B5,"Failed")*COUNTIFS(D2:D5,A2:A5,E2:E5,"Passed"))
或者，如果你想要一個計數：
中的公式H1：
=SUM(COUNTIFS(A2:A5,FILTER(D2:D5,E2:E5="Passed"),B2:B5,"Failed"))
轉載請註明出處，本文鏈接：https://www.uj5u.com/houduan/530172.html
標籤：擅长excel公式