插入記錄時如何捕捉plsql中的空約束例外？

我想在將記錄插入表時檢查列的空約束。在那里，我試圖通過一個程序將一個空值插入到一個不能為空的列中。這是我的程式。

CREATE OR REPLACE PROCEDURE RecordInsert(s_id IN NUMBER, pid IN NUMBER, pr_id IN NUMBER, quantity NUMBER, rv DATE, exercise_num NUMBER)
IS
null_constraint  EXCEPTION;
PRAGMA EXCEPTION_INIT(null_constraint,-1451);
BEGIN
  INSERT INTO Supplier_Part_Project_Tab
  VALUES(s_id, pid, pr_id_, quantity, rv);
  dbms_output.put_line('The row successfully inserted');
  COMMIT;

EXCEPTION
  WHEN null_constraint THEN
    dbms_output.put_line('The column cannot be NULL');
  WHEN OTHERS THEN
      pkg_Error.prc_Exeception(exercise_num);
END;

這就是我執行程式的方式。

BEGIN
 RecordInsert( 1002, '', 2001, 80, (TO_DATE('2003/05/03 09:02:44', 'yyyy/mm/dd hh12:mi:ss AM')),8);
COMMIT;
END;

在上述程序中，我試圖將 pid 插入為空。在那里，我想觸發“null_constraint”例外。但它會觸發“其他”例外。希望 oracle 例外 -1451 對我的要求是正確的。但是為什么不火呢？

uj5u.com熱心網友回復：

樣品表：

SQL> CREATE TABLE test
  2  (
  3     id     NUMBER NOT NULL,
  4     name   VARCHAR2 (20) NOT NULL
  5  );

Table created.

沒有例外處理部分的程式（看看會發生什么）：

SQL> CREATE OR REPLACE PROCEDURE RecordInsert (par_id    IN NUMBER,
  2                                            par_name  IN VARCHAR2)
  3  IS
  4     null_constraint  EXCEPTION;
  5     PRAGMA EXCEPTION_INIT (null_constraint, -1451);
  6  BEGIN
  7     INSERT INTO test (id, name)
  8          VALUES (par_id, par_name);
  9
 10     DBMS_OUTPUT.put_line ('The row successfully inserted');
 11  /*
 12  EXCEPTION
 13     WHEN null_constraint
 14     THEN
 15        DBMS_OUTPUT.put_line ('The column cannot be NULL');
 16     WHEN OTHERS
 17     THEN
 18        DBMS_OUTPUT.put_line ('Others');
 19  */
 20  END;
 21  /

Procedure created.

測驗：

SQL> exec recordinsert(1, 'Littlefoot');
The row successfully inserted

PL/SQL procedure successfully completed.

SQL> exec recordinsert(2, null);
BEGIN recordinsert(2, null); END;

*
ERROR at line 1:
ORA-01400: cannot insert NULL into ("SCOTT"."TEST"."NAME")
ORA-06512: at "SCOTT.RECORDINSERT", line 7
ORA-06512: at line 1


SQL>

啊哈。ORA-01400（不是 1451）。讓我們修改程式，然后：

SQL> CREATE OR REPLACE PROCEDURE RecordInsert (par_id    IN NUMBER,
  2                                            par_name  IN VARCHAR2)
  3  IS
  4     null_constraint  EXCEPTION;
  5     PRAGMA EXCEPTION_INIT (null_constraint, -1400);
  6  BEGIN
  7     INSERT INTO test (id, name)
  8          VALUES (par_id, par_name);
  9
 10     DBMS_OUTPUT.put_line ('The row successfully inserted');
 11  EXCEPTION
 12     WHEN null_constraint
 13     THEN
 14        DBMS_OUTPUT.put_line ('The column cannot be NULL');
 15     WHEN OTHERS
 16     THEN
 17        DBMS_OUTPUT.put_line ('Others');
 18  END;
 19  /

Procedure created.

SQL> set serveroutput on
SQL>
SQL> exec recordinsert(2, null);
The column cannot be NULL                  --> here's your exception

PL/SQL procedure successfully completed.

SQL>

您使用的錯誤代碼是

ORA-01451: 要修改為 NULL 的列不能修改為 NULL

原因：該列可能已經允許 NULL 值，NOT NULL 約束是主鍵或檢查約束的一部分，或者 ALTER TABLE MODIFY 陳述句試圖不必要地更改列規范，從 NULL 到 NULL。

行動：如果主鍵或檢查約束正在執行 NOT NULL 約束，則洗掉該約束。

它與ALTER TABLE陳述句有關，而不是與嘗試將NULL值插入NOT NULL列的插入有關，例如

SQL> create table test (id number not null, name varchar2(20));

Table created.

SQL> desc test
 Name                                      Null?    Type
 ----------------------------------------- -------- ----------------------------
 ID                                        NOT NULL NUMBER
 NAME                                               VARCHAR2(20)

SQL> alter table test modify name null;
alter table test modify name null
                        *
ERROR at line 1:
ORA-01451: column to be modified to NULL cannot be modified to NULL


SQL>

標籤：

上一篇：OraclePLSQL轉義單引號

下一篇：ORA-01861:文字與char變數上的格式字串不匹配錯誤