批處理檔案中嵌套if-else條件的問題

我不知道為什么嵌套 if-else 從"Memo File AND Other File Not Found"開始到"Memo File Not Found"時它不起作用。

任何人都可以幫助我嗎？

如果您能解決，不勝感激。謝謝！

原始代碼

@ECHO OFF
SET FOLDER="D:\temp\test"
SET TRANS="D:\temp\test\Trans\Trans.txt"
SET MEMO="D:\temp\test\Memo\Memo.txt"
SET OTHER="D:\temp\test\Other\Other.txt"

IF NOT EXIST %FOLDER% (
    ECHO Folder Not Found
) ELSE (
    IF NOT EXIST %MEMO% (
        IF NOT EXIST %TRANS% (
            IF NOT EXIST %OTHER% (
                ECHO All Files Not Found
            ) ELSE (
                IF NOT EXIST %MEMO% (
                    IF NOT EXIST %TRANS% (
                        ECHO Memo File AND Trans File Not Found
                    ) ELSE (
                        IF NOT EXIST %MEMO% (
                            IF NOT EXIST %OTHER% (
                                ECHO Memo File AND Other File Not Found
                            ) ELSE (
                                IF NOT EXIST %TRANS% (
                                    IF NOT EXIST %OTHER% (
                                        ECHO Trans File AND Other File Not Found
                                    ) ELSE (
                                        IF NOT EXIST %TRANS% (
                                            ECHO Trans File Not Found
                                        ) ELSE (
                                            IF NOT EXIST %MEMO% (
                                                ECHO Memo File Not Found
                                            )
                                        )
                                    )
                                )
                            )
                        )
                    )
                )
            )
        )
    )
)

uj5u.com熱心網友回復：

此示例是否輸出您嘗試檢索的資訊：

@ECHO OFF
SET "FOLDER=D:\temp\test"
SET "TRANS=%FOLDER%\Trans\Trans.txt"
SET "MEMO=%FOLDER%\Memo\Memo.txt"
SET "OTHER=%FOLDER%\Other\Other.txt"

IF NOT EXIST "%FOLDER%\*" (
    ECHO Folder Not Found
) ELSE (
    IF NOT EXIST "%MEMO%" (
        IF NOT EXIST "%TRANS%" (
            IF NOT EXIST "%OTHER%" (
                ECHO All Files Not Found
            ) ELSE (
                ECHO Memo File AND Trans File Not Found
            )
        ) ELSE (
            IF NOT EXIST "%OTHER%" (
                ECHO Memo File AND Other File Not Found
            ) ELSE (
                ECHO Memo File Not Found
            )
        )
    ) ELSE (
        IF NOT EXIST "%TRANS%" (
            IF NOT EXIST "%OTHER%" (
                ECHO Trans File AND Other File Not Found
            ) ELSE (
                ECHO Trans File Not Found
            )
        ) ELSE (
            IF NOT EXIST "%OTHER%" (
                ECHO Other File Not Found
            ) ELSE (
                ECHO All Files Found
            )
        )
    )
)
PAUSE

uj5u.com熱心網友回復：

這是我會這樣做的方式：

@ECHO OFF
SET FOLDER="D:\temp\test"
SET TRANS="D:\temp\test\Trans\Trans.txt"
SET MEMO="D:\temp\test\Memo\Memo.txt"
SET OTHER="D:\temp\test\Other\Other.txt"

IF NOT EXIST %FOLDER% (
    ECHO Folder Not Found
    GOTO :EOF
)

SET "NOTFOUND="
IF NOT EXIST %TRANS% SET "NOTFOUND=Trans"
IF NOT EXIST %MEMO% SET "NOTFOUND=Memo %NOTFOUND%"
IF NOT EXIST %OTHER% SET "NOTFOUND=Other %NOTFOUND%"

IF DEFINED NOTFOUND ECHO These files not found: %NOTFOUND%

標籤：视窗 if 语句 批处理文件 命令

上一篇：使批處理檔案在一定時間后停止運行？

下一篇：Windows批處理檔案要求管理員權限并在curl中下載檔案失敗