在STS4中自動添加構建的源檔案？

目前我被編譯后自動添加的源檔案所困擾。

QueryDSL IS WORKING（重繪 后自動添加。）。但是，MapStruct 不起作用。

QueryDSL 輸出是 src/main/generated/querydsl，每個專案。MapStruct 在他們的專案中是默認的（build/generated/sources/annotationProcessor/java/main）。

手動添加源檔案后，此代碼有效，但我想像 querydsl 一樣自動添加源。

這是我在 build.gradle 中的一部分。

// 根 build.gradle

buildscript {
    ext {
        springBootVersion = '2.7.2'
        dependencyManagementVersion = '1.0.12.RELEASE'
        mysqlVersion = '8.0.30'
        lombokVersion = '6.5.0.3'
        queryDslVersion = '4.4.0'
        queryDslPluginVersion = '1.0.10'
        mapStructVersion = '1.5.3.Final'
        lombokMapstructBindingVersion = "0.2.0"
    }
    repositories {
        mavenCentral()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}"
        classpath "io.spring.gradle:dependency-management-plugin:${dependencyManagementVersion}"
        classpath "io.freefair.gradle:lombok-plugin:${lombokVersion}"
        // for QueryDSL
        classpath "gradle.plugin.com.ewerk.gradle.plugins:querydsl-plugin:${queryDslPluginVersion}"
    }
}

subprojects {
    group = 'test.test'
    version '0.0.1-SNAPSHOT'

    apply plugin: 'java'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'io.freefair.lombok'
    apply plugin: 'com.ewerk.gradle.plugins.querydsl'
    
    sourceCompatibility = '11'

    repositories {
        mavenCentral()
    }

    dependencies {
      compile group: 'com.querydsl', name: 'querydsl-jpa'
      annotationProcessor group: 'com.querydsl', name: 'querydsl-apt'

        // for QueryDSL
        // implementation "com.querydsl:querydsl-core:${queryDslVersion}"
        // implementation "com.querydsl:querydsl-jpa:${queryDslVersion}"
        // annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}:jpa"
        annotationProcessor "jakarta.persistence:jakarta.persistence-api"
        annotationProcessor "jakarta.annotation:jakarta.annotation-api"
        
        annotationProcessor "org.mapstruct:mapstruct-processor:${mapStructVersion}"
        implementation "org.mapstruct:mapstruct:${mapStructVersion}"
        
        annotationProcessor "org.projectlombok:lombok-mapstruct-binding:${lombokMapstructBindingVersion}"
        
        testImplementation 'junit:junit:4.12'
    }
}

// for QueryDSL
task cleanGeneatedDir(type: Delete) {
    delete file('src/main/generated')
}

// 一個專案 build.gradle

dependencies {
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-web'
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-security'
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-validation'
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-data-jpa'
    implementation group: 'org.springdoc', name: 'springdoc-openapi-ui', version: '1.6.11'
    implementation 'com.querydsl:querydsl-jpa:4.4.0'
    
    testImplementation group: 'org.springframework.boot', name: 'spring-boot-starter-test'
}

def querydslDir = "src/main/generated/querydsl"

querydsl {
    library = "com.querydsl:querydsl-apt"
    jpa = true
    querydslSourcesDir = querydslDir
}
sourceSets {
    main.java.srcDir querydslDir
}
compileQuerydsl{
    options.annotationProcessorPath = configurations.querydsl
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
    querydsl.extendsFrom compileClasspath
}

uj5u.com熱心網友回復：

它由 gradle 中的 sourceSets > main > java > srcDirs 自動配置。

在代碼中，

sourceSets {
    main {
        java {
            srcDirs = ['src/main/java', 'build/generated/sources/annotationProcessor/java/main']
        }
    }
}

標籤：蚀弹簧工具套件sts

上一篇：安裝EclipseWindowsBuilder插件后Maven構建中的java.lang.NoClassDefFoundError

下一篇：EclipseWildWebDeveloper不會在Chrome遠程除錯的JavaScript斷點上停止