Gradle下載舊的編譯依賴項-有解無憂

我正在使用spring-boot和gradle。我想使用最新的 selenium 版本，但是包括驅動程式在內的一半編譯依賴項是 3.14 版本。我嘗試使快取無效，./gradlew clean build, ./gradlew build --refresh-dependencies，但它沒有幫助。我的舊專案具有相同的依賴項（但沒有 spring-boot），我這個問題不存在。

import org.gradle.api.tasks.testing.logging.TestExceptionFormat

plugins {
    id 'org.springframework.boot' version '2.6.7'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
}

group = 'xxx.xxxxxx'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    // https://mvnrepository.com/artifact/org.seleniumhq.selenium/selenium-java
    implementation 'org.seleniumhq.selenium:selenium-java:4.1.4'
    // https://mvnrepository.com/artifact/org.testng/testng
    testImplementation 'org.testng:testng:7.5'
    // https://mvnrepository.com/artifact/io.rest-assured/rest-assured
    testImplementation 'io.rest-assured:rest-assured:4.5.1'
    // https://mvnrepository.com/artifact/io.github.bonigarcia/webdrivermanager
    implementation 'io.github.bonigarcia:webdrivermanager:5.1.1'
    // https://mvnrepository.com/artifact/com.github.javafaker/javafaker
    implementation 'com.github.javafaker:javafaker:1.0.2'
    // https://mvnrepository.com/artifact/org.assertj/assertj-core
    testImplementation 'org.assertj:assertj-core:3.22.0'

}

test {
    useTestNG()

    testLogging {
        exceptionFormat(TestExceptionFormat.FULL)
    }

    systemProperties(System.getProperties())
}

Gradle 下載舊的編譯依賴項

uj5u.com熱心網友回復：

Spring Boot 管理 Selenium 的版本，因此在您的情況下，您只指定了的版本selenium-java，所有其他版本都由 Spring Boot 管理。要正確更新所有 Selenium 依賴項，您必須覆寫 Selenium 版本的屬性：

ext['selenium.version'] = '4.1.4'

并從 selenium-java 條目中洗掉版本：

implementation 'org.seleniumhq.selenium:selenium-java'

您可以在檔案中找到 Spring Boot 管理的庫的所有可用屬性：https ://docs.spring.io/spring-boot/docs/2.6.7/reference/htmlsingle/#appendix.dependency-versions.properties

轉載請註明出處，本文鏈接：https://www.uj5u.com/qukuanlian/468927.html

標籤：爪哇弹簧靴毕业典礼依赖关系依赖管理

上一篇：如何根據查詢結果從表中洗掉

下一篇：Matlab未定義的變數或函式“out”