Perl的智能匹配可以用來驗證欄位串列嗎？

通常，對于可以傳遞給函式的每個有效選項，我都有一個哈希值%valid_opts = (a => 1, b => 2, ...)，然后我會迭代以找出是否傳遞了不受支持的選項。當發生拼寫錯誤并且我想知道為什么有些東西壞了時，這使我免于自己的痛苦：

sub f
{
   my %opts = @_;
   my %valid_opts = (a => 1, b => 1, c => 1);

   foreach (keys(%opts)) {
      croak "bad option $_" if !$valid_opts{$_};
   }

   # profit
}

最近我了解了~~智能匹配運算子，想知道它是否可以簡化作業：

我可以使用~~運算子檢查是否%opts只包含%valid_opts沒有回圈的鍵嗎？

我已經嘗試了一些組合，keys(%opts) ~~ @valid_opts但我認為它比較以確保它們完全匹配。如果這是可能的，那么你將如何設定它？

這應該是真的：

• @valid_opts = (qw/abc/)
• %opts = (a => 1, b => 2)

這應該是錯誤的：

• @valid_opts = (qw/abc/)
• %opts = (a => 1, b => 2, d => 4 )

冒著這個問題真的是XY 問題的風險，那么有沒有更好的方法來檢查函式頂部的有效選項？

uj5u.com熱心網友回復：

有些模塊可以做到這一點，而且功能更強大。但除此之外，您也可以非常輕松地創建一個函式來自己執行此操作。一個完整的例子。

在我的示例中，我將檔案命名為validation.pl 。

#!/usr/bin/env perl
use strict;
use warnings;
use v5.32;
use Carp qw(croak);

# Works Fine
helloA(
    Name     => "David",
    LastName => "Raab",
);

helloB(
    Name     => "David",
    LastName => "Raab",
);

# Throws: Keys [LasstName, Invalid] not supported by main::valid_arguments at ./validation.pl line 19.
helloA(
    Name      => "David",
    LasstName => "Raab",
);

# Would also throw exception.
helloB(
    Name      => "David",
    LasstName => "Raab",
);


# valid_arguments(["Name", "LastName"], @_);
sub valid_arguments {
    my ($valids, %orig) = @_;
    
    # Turns: ["A","B","C"] into {"A" => 1, "B" => 1, "C" => 1}
    my %valids = map { $_ => 1 } @$valids;
    
    # Check all passed arguments
    for my $key (keys %orig) {
        # if they are valid entry
        if ( exists $valids{$key} ) {
            # when true - do nothing
        }
        else {
            # when false - throw error
            local $Carp::CarpLevel = 2;
            my @caller = caller 0;
            croak (sprintf "Key [%s] not supported by %s", $key, $caller[3]);
        }
    }
    
    # returns hash in list context. hashref in scalar context.
    return wantarray ? %orig : \%orig;
}

sub helloA {
    my (%args) = valid_arguments(["Name", "LastName"], @_);
    printf "Hello %s %s\n", $args{Name}, $args{LastName};
}

sub helloB {
    my $args = valid_arguments(["Name", "LastName"], @_);
    printf "Hello %s %s\n", $args->{Name}, $args->{LastName};
}

通過caller()您可以從其他來源獲取您的函式被呼叫的資訊。Carp::croak()從另一個角度拋出例外。因此，您會收到一條錯誤訊息，用戶需要它來修復他的錯誤。

valid_arguments編輯：檢查所有引數的擴展。

# Examples: 
# my %args = valid_arguments(["Name", "LastName"], @_);
# my $args = valid_arguments(["Name", "LastName"], @_);
sub valid_arguments {
    my ($valids, %orig) = @_;
    
    # Turns: ["A","B","C"] into {"A" => 1, "B" => 1, "C" => 1}
    my %valids = map { $_ => 1 } @$valids;
    
    # Get a list of invalid arguments
    my @invalids;
    for my $key ( keys %orig ) {
        push @invalids, $key if not exists $valids{$key};
    }
    
    # Throw error if any invalid exist
    if ( @invalids > 0 ) {
        local $Carp::CarpLevel = 2;
        my $caller = (caller 0)[3];
        
        @invalids == 1 
            ? croak (sprintf "Key [%s] not supported by %s", $invalids[0], $caller)
            : croak (sprintf "Keys [%s] not supported by %s", join(", ", @invalids), $caller);
    }
    
    # return hash in list context. hashref in scalar context.
    return wantarray ? %orig : \%orig;
}

目前所有引數都是可選的。強制性的怎么辦？您也可以添加此功能，但我會使用已經開發和使用的模塊。

標籤：数组 perl 关联数组

上一篇：為perl配置包路徑的正確方法是什么？

下一篇：Perl：遍歷多行匹配