我正在嘗試重命名更改擴展名的檔案并洗掉檔案名的最后兩個字符（不包括擴展名），這可以通過 Windows 命令提示符實作嗎？
例如：
INF_CAN1_Knees_Top_T209_1.OUT
INF_CAN1_Knees_Outside_T196_2.OUT
應改名為：
INF_CAN1_Knees_Top_T209.txt
INF_CAN1_Knees_Outside_T196.txt
更改擴展名很容易：
rename *.OUT *.txt works.
我認為這rename *_?.OUT *.txt會起作用，但它不會，它會改變擴展名，但_1or_2仍然存在。這讓我感到驚訝，因為在輸入和輸出中似乎*有不同的值。
是否有可能做到這一點，為什么我嘗試過它不起作用？
uj5u.com熱心網友回復：
此檔案重命名任務可以使用以下批處理檔案：
@echo off
setlocal EnableExtensions DisableDelayedExpansion
if exist "*!*_?.out" goto ExtendedVersion
setlocal EnableDelayedExpansion
for /F "eol=| delims=" %%I in ('dir *_?.out /A-D-L /B 2^>nul ^| %SystemRoot%\System32\findstr.exe /E /I /R "_[0123456789]\.out"') do (
set "FileNameOut=%%~nI"
set "FileNameNew=!FileNameOut:~0,-2!.txt"
if not exist "!FileNameNew!" ren "!FileNameOut!%%~xI" "!FileNameNew!"
)
endlocal
goto EndBatch
:ExtendedVersion
echo INFO: Extended version required because of an OUT file with exclamation marks.
for /F "eol=| delims=" %%I in ('dir *_?.out /A-D-L /B 2^>nul ^| %SystemRoot%\System32\findstr.exe /E /I /R "_[0123456789]\.out"') do (
set "FileNameOut=%%~nI"
setlocal EnableDelayedExpansion
set "FileNameNew=!FileNameOut:~0,-2!.txt"
if not exist "!FileNameNew!" ren "!FileNameOut!%%~xI" "!FileNameNew!"
endlocal
)
:EndBatch
endlocal
首先使用前兩個命令列定義所需的執行環境。
第三個命令列中的IF條件快速檢查檔案名中是否有任何包含一個或多個感嘆號的 OUT 檔案。如果此條件為真，則需要處理回圈的擴展版本。
標準版本首先啟用所需的延遲擴展。然后使用一個FOR回圈，它在后臺運行，Windows 安裝到C:\Windows：
C:\Windows\System32\cmd.exe /c dir *_?.out /A-D-L /B 2>nul | C:\Windows\System32\findstr.exe /E /I /R "_[0123456789]\.out"
搜索的內部命令DIRcmd.exe
cmd.exe在由開始處理批處理檔案的行程定義的當前目錄中- 由于選項而僅用于檔案名
/A-D-L（屬性不是目錄而不是鏈接） *_?.out匹配長或短 8.3 名稱中不區分大小寫的通配符模式- 并以裸格式輸出，因為選項
/B只是帶有檔案擴展名的檔案名，但沒有檔案路徑。
處理DIR上的STDERR（標準錯誤）的錯誤訊息輸出未找到任何符合條件的檔案系統條目，通過將此錯誤訊息重定向到設備NUL來抑制。
閱讀有關使用命令重定向運算子2>nul的 Microsoft 檔案，了解和的說明|。當 Windows 命令解釋器在執行命令FOR之前使用在后臺啟動的單獨命令列程執行嵌入式命令列時處理此命令列時，重定向運算子>和|必須^在FOR命令列上使用脫字符進行轉義以被解釋為文字字符。
DIR的輸出被重定向到FINDSTR的STDIN（標準輸入），它使用正則運算式搜索不區分大小寫的以下劃線結尾的行（= 長檔案名）、范圍內的數字和檔案擴展名。FINDSTR用作過濾器。它過濾掉檔案名僅以下劃線或下劃線和與數字不同的字符結尾的所有檔案。0-9.out*.out
請注意，這?意味著任何字符零或一次！
FOR分別cmd.exe處理批處理檔案捕獲寫入后臺啟動的標準輸出流的所有輸出，并在完成執行命令DIRcmd.exe后自行關閉后逐行處理。cmd.exe
FOR with 選項/F在這里用于在真正執行檔案重命名之前獲取*_?.out加載到記憶體中的檔案的檔案名串列，cmd.exe否則可能會發生，特別是在 FAT 驅動器（FAT32，exFAT）上，某些 OUT 檔案被多次處理（在無法重命名）。
FOR使用選項/F總是忽略空行，這在這里沒有問題，因為使用了選項的DIR不會輸出空行。
FOR接下來將使用水平制表符和普通空格作為字串分隔符將行拆分為子字串，如果第一個制表符/空格分隔的字串以分號開頭，則將查看下一個，在這種情況下，它還將忽略整行以進行進一步處理，否則將在運行FORI主體中的命令之前，僅將第一個制表符/空格分隔的字串分配給指定的回圈變數。
不需要默認的行拆分行為，因為 OUT 檔案名可以包含一個或多個空格。該選項的使用delims=定義了一個空的分隔符串列，它關閉了行拆分行為。
;OUT 檔案名以（分號）開頭是非常不尋常的，但仍有可能。FOR不應忽略這樣的檔案名。該選項eol=|將豎線定義為檔案名不能包含的行尾字符。Microsoft 在有關命名檔案、路徑和命名空間的檔案中列出了 Windows 檔案系統的檔案名中不允許出現的字符。
不帶檔案擴展名的當前檔案名.out首先分配給環境變數FileNameOut。
接下來，使用字串替換從環境變數的字串值中獲取不帶最后兩個字符與分配給環境變數FileNameOut的檔案擴展名的檔案名。.txtFileNameNew
如果還沒有 TXT 檔案，則接下來執行命令REN將*_?.out檔案重命名為*.txt，并洗掉檔案擴展名前的最后兩個字符。
回圈后的命令ENDLOCAL在啟用延遲擴展之前恢復先前的環境，命令GOTO指示 Windows 命令處理器繼續處理批處理檔案，其標簽下方的命令列EndBatch包含一個ENDLOCAL以在啟動批處理檔案時恢復環境加工。
擴展版與標準版幾乎相同。*_?.out不同之處在于將沒有檔案擴展名的當前檔案的檔案名分配給環境變數時，不啟用延遲變數擴展FileNameOut。這避免了將檔案名中的感嘆號解釋為延遲擴展變數參考的開始/結束，從而導致在將檔案名字串分配給環境變數之前對其進行操作，因為已經啟用延遲擴展會發生這種情況。
*_?.out擴展版本啟用回圈內的下一個延遲變數擴展，與標準版本相同，并在處理下一個檔案之前最終恢復先前的環境。
擴展版本的速度較慢，因為環境變數串列復制以及每次執行SETLOCAL在后臺進行的其他操作，如本答案中詳細說明的那樣。需要回圈中的命令ENDLOCAL以避免在處理大量 OUT 檔案時發生堆疊溢位。
用戶對RENAME命令如何使用通配符模式的期望通常是錯誤的。如果第一個引數字串包含通配符模式字符*和?，則通配符模式僅用于查找與通配符模式匹配的檔案系統條目。重命名時不考慮第一個通配符模式字串。對于重命名，只有第二個引數字串很重要。如果第二個引數字串是通配符模式，則此模式將應用于當前檔案/檔案夾名稱，以識別要保留哪些字符以及要更改哪些字符，這與之前用于查找要重命名的檔案的通配符模式無關。檔案夾只能使用不包含的第一個引數字串重命名*或的第一個引數字串重命名?，即要重命名的檔案夾的名稱必須按原樣指定。
另請參閱：Windows RENAME 命令如何解釋通配符？
也可以使用以下批處理檔案代碼來重命名所有 *.out 檔案并僅洗掉最后兩個檔案名中的最后兩個字符，但檔案擴展名中留下的檔案名中的一個字符是下劃線。
@echo off
setlocal EnableExtensions DisableDelayedExpansion
if exist "*!*.out" goto ExtendedVersion
setlocal EnableDelayedExpansion
for /F "eol=| delims=" %%I in ('dir *.out /A-D-L /B 2^>nul') do (
set "FileNameOut=%%~nI"
if "!FileNameOut:~-2,1!" == "_" (set "FileNameNew=!FileNameOut:~0,-2!.txt") else set "FileNameNew=!FileNameOut!.txt"
if not exist "!FileNameNew!" ren "!FileNameOut!%%~xI" "!FileNameNew!"
)
endlocal
goto EndBatch
:ExtendedVersion
echo INFO: Extended version required because of an OUT file with exclamation marks.
for /F "eol=| delims=" %%I in ('dir *.out /A-D-L /B 2^>nul') do (
set "FileNameOut=%%~nI"
setlocal EnableDelayedExpansion
if "!FileNameOut:~-2,1!" == "_" (set "FileNameNew=!FileNameOut:~0,-2!.txt") else set "FileNameNew=!FileNameOut!.txt"
if not exist "!FileNameNew!" ren "!FileNameOut!%%~xI" "!FileNameNew!"
endlocal
)
:EndBatch
endlocal
該批處理檔案重命名
INF_CAN1_Knees_Top_T209_1.OUT
INF_CAN1_Something Other & 100% free!.OUT
至
INF_CAN1_Knees_Top_T209.txt
INF_CAN1_Something Other & 100% free!.txt
要了解所使用的命令及其作業原理，請打開命令提示符視窗，在那里執行以下命令，并完整而仔細地閱讀每個命令顯示的幫助頁面。
echo /?endlocal /?findstr /?for /?goto /?if /?ren /?set /?setlocal /?
轉載請註明出處，本文鏈接：https://www.uj5u.com/qukuanlian/524786.html
標籤：视窗命令
上一篇：將資料從一個表拆分到另一個表