ProductName | display | final value
Lewis No
Lewis No
Lewis No
Sood No
Henny Yes
Henny No
Henny No
1.在 excel 中尋找一個公式，如果產品的顯示值為 yes 且產品名稱相同，則最終值應為 yes，其他應為變體。2.否則，如果該產品對于所有具有相同名稱的產品都沒有顯示值，那么它應該不會顯示。
最終輸出應該是
ProductName | display | final value
Lewis No. Not display
Lewis No. Not display
Lewis No. Not display
Sood No. Not display
Henny Yes. Yes
Henny No. Variant
Henny No. Variant
嘗試使用 if 和 count if 但無法找到未顯示的邏輯
uj5u.com熱心網友回復：
試試下面的公式-
=LET(x,CONCAT(UNIQUE(FILTER($B$2:$B2,$A$2:$A2=A2))),IF(x="No","Not Display",IF(x="Yes","Yes","Variant")))
uj5u.com熱心網友回復：
在 Office 365 中，您可以使用以下內容來溢位結果：
=LET(range,A1:B8,
r,ROWS(range),
name,TAKE(range,1-r,1),
display,TAKE(range,1-r,-1),
DROP(REDUCE(0, SEQUENCE(r-1,),
LAMBDA(x, y,
VSTACK(x,
IF(
ISNUMBER(XMATCH(INDEX(name,y)&"Yes",name&display)),
IF(INDEX(display,y)="Yes",
"Yes",
"Variant"),
"No display")))),
1))
在較舊的 Excel 中使用：
=IF(COUNTIFS($A$2:$A$8,A2,$B$2:$B$8,"Yes"),IF(B2="Yes","Yes","Variant"),"Not display")
它檢查名稱的組合并檢查Yes范圍內的任何位置。如果為 FALSE，則結果為Not display；如果為 TRUE，它會檢查 B 列中的值是否為Yes，而不是結果Yes。否則會導致Variant.
轉載請註明出處，本文鏈接：https://www.uj5u.com/qukuanlian/536338.html
標籤：擅长excel公式
上一篇：使用陣列和回圈洗掉字符實體