目錄
一、前景回顧
二、規劃頁表
三、實作頁表
四、運行測驗
一、前景回顧
前面我們已經介紹了分頁機制的運行原理，那么如何開啟分頁機制呢，也簡單，分為如下三個步驟：
1、創建頁目錄表并初始化頁記憶體，
2、將頁目錄表地址賦值為CR3，
3、打開CR0暫存器的PG位，
可以看出頁表是分頁機制的核心，接下來我們將開始在我們的系統上實作一個二級頁表，
二、規劃頁表
設計頁表其實就是設計記憶體布局，不過在規劃記憶體布局之前，我們需要了解用戶行程與作業系統之間的關系，
在作業系統中，為了計算機安全，用戶行程始終是運行在低特權級的，用戶行程需要訪問硬體相關資源時，是需要向作業系統申請，然后通過系統呼叫的方式陷入作業系統，由作業系統去做并且將結果回傳給用戶行程，行程可以有多個，但是作業系統只有一個，所以作業系統必須“共享”給每一個行程，他們的關系如圖所示，
對于每一個行程來說，它不單單是運行程式這么簡單的事，它需要接受調度、阻塞、在需要陷入內核時還需要作業系統的幫助等等，因此，完整的一個行程是需要和作業系統配合才能完成正常的作業，也就是說每一個行程里面應該包含作業系統部分，Linux下的每一個行程，高1GB的空間就是留給作業系統的，低3GB的空間就是留給行程用戶空間自身的，在我們的系統中，也遵循這樣的安排，對于這高1GB的空間，我們并不是每創建一個新的行程，就將作業系統代碼給復制到這1GB的空間中，這樣顯得笨重而且隨著行程數的增加會占用更多的記憶體，實際上作業系統的代碼只有一份，我們每創建一個新的行程，就讓該行程的高1GB空間指向作業系統即可，
現在回過頭來看看我們的系統，這里提前透露一下，后面完善了內核之后，我們的整個作業系統的代碼也不到1MB，所以我們這里就假設最終作業系統的代碼只有1MB，也就是說整個作業系統代碼的存放區域從0x0到0xFFFFF，跟前面說的劃分1GB的空間來存放作業系統代碼差距特別大，很大一部分沒有用上，因為我們的作業系統會比較簡單，用不到這么多空間，不過記憶體劃分還是按照Linux下的格式來，便于學習，
所以頁目錄表的地址，我們就存放在物理地址0x100000處，為了讓頁表緊挨著頁目錄表，頁目錄表本身占用4KB，所以第一個頁表的物理地址是0x101000，還有其他的規劃我一并表現在它們的物理記憶體布局中，如圖所示，
這張圖將我們的整個頁表規劃表現得一覽無余，至于其中細節且讓我娓娓道來，
首先我們知道，頁表是用來給虛擬地址映射用的，虛擬地址的使用前提得是開啟了分頁機制，如果沒有開啟分頁機制，那么頁表就毫無用處，現在假設我們開啟了分頁機制，那么此時注意，我們使用的地址就不再是之前的線性地址了，而是虛擬地址，怎么說呢，以前我們要想讓CPU訪問一個地址，只需要將該地址拆解分別賦給CS和段內偏移就可以了，但是開啟分頁機制后，拆解出的這個地址就不能訪問到期望的地址了，因為在開啟分頁機制后，CPU拿到這個地址，會根據CR3暫存器中存盤的頁目錄表地址來進行尋址，最終得到的物理地址才是CPU真正去訪問的地址，具體步驟請參考上一回的內容，
所以現在如果我們想要訪問作業系統的代碼，也就是低端1MB的記憶體，該如何訪問呢？前面我們說過，Linux將用戶行程的高1GB作為作業系統的空間，所以我們可以知道，在用戶行程中，虛擬地址0xc0000000~0xffffffff便是映射到作業系統的1GB空間中去，而在我們的系統中，作業系統的代碼總共占據了1MB的記憶體，所以從0xc0000000~0xc00fffff便是映射到我們作業系統的1MB空間，0xc0000000虛擬地址對應的頁目錄項應該是第768個，這個算起來容易，0xc0000000的高10位是0x300，即十進制的768，該目錄項可以表示的記憶體空間是4MB，所以我們指定了一個頁表來管理這4MB的空間，因此我們在頁目錄表的第768頁目錄項中填入該頁表的物理地址0x101000，我們將目光轉入到0x101000地址處，此處頁表的第0到255頁表項指向的物理記憶體便是我們作業系統的1MB空間，
從頁目錄項的第769到1022的頁目錄項中，我們都只是指定了頁表地址，并沒有給實際的頁表初始化，因為我們的作業系統只占用了1MB空間，多余的也用不上，這里只是為了占個位置而已，
頁目錄項的第1023項可能會有人比較好奇，為什么該項指向的地址是頁目錄表本身地址，這里是為了能通過虛擬地址來訪問到頁目錄表本身，如果后面需要修改頁目錄表，我們通過0xfffff000~0xffffffff就能訪問到頁目錄表的第0到第1023項，感興趣的朋友可以自己試試，看這個虛擬地址最終是否能轉換成頁目錄表各項的物理地址，當然可能就會有人說，這樣的話作業系統實際上就并沒有占據1GB的記憶體空間了么，少掉了4MB的空間，事實上的確是這樣，不過其實問題也不大，是吧，
最后我們再來看看為什么頁目錄表的第0項的內容是0x101000，原因是我們在加載內核之前，程式中一直都是運行的loader，它本身的代碼都是在低端1MB之內的，必須保證之前段機制下的線性地址和分頁后的虛擬地址對應的物理地址一致，
三、實作頁表
前面說了這么多，接下來我們來實作我們的頁目錄表和頁表，在loader.S檔案中增加如下代碼：
1 %include "boot.inc"
2 section loader vstart=LOADER_BASE_ADDR
3 LOADER_STACK_TOP equ LOADER_BASE_ADDR
4 jmp loader_start
5
6 ;構建gdt及其內部描述符
7 GDT_BASE: dd 0x00000000
8 dd 0x00000000
9 CODE_DESC: dd 0x0000FFFF
10 dd DESC_CODE_HIGH4
11 DATA_STACK_DESC: dd 0x0000FFFF
12 dd DESC_DATA_HIGH4
13 VIDEO_DESC: dd 0x80000007
14 dd DESC_VIDEO_HIGH4
15
16 GDT_SIZE equ $-GDT_BASE
17 GDT_LIMIT equ GDT_SIZE-1
18 times 60 dq 0 ;此處預留60個描述符的空位
19
20 SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0
21 SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0
22 SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0
23
24 ;以下是gdt指標，前2個位元組是gdt界限，后4個位元組是gdt的起始地址
25 gdt_ptr dw GDT_LIMIT
26 dd GDT_BASE
27
28 ;---------------------進入保護模式------------
29 loader_start:
30 ;一、打開A20地址線
31 in al, 0x92
32 or al, 0000_0010B
33 out 0x92, al
34
35 ;二、加載GDT
36 lgdt [gdt_ptr]
37
38 ;三、cr0第0位(pe)置1
39 mov eax, cr0
40 or eax, 0x00000001
41 mov cr0, eax
42
43 jmp dword SELECTOR_CODE:p_mode_start ;重繪流水線
44
45 [bits 32]
46 p_mode_start:
47 mov ax, SELECTOR_DATA
48 mov ds, ax
49 mov es, ax
50 mov ss, ax
51 mov esp, LOADER_STACK_TOP
52 mov ax, SELECTOR_VIDEO
53 mov gs, ax
54
55 mov byte [gs:160], 'p'
56
57 ;------------------開啟分頁機制-----------------
58 ;一、創建頁目錄表并初始化頁記憶體位圖
59 call setup_page
60
61 ;將描述符表地址及偏移量寫入記憶體gdt_ptr，一會兒用新地址重新加載
62 sgdt [gdt_ptr]
63 ;將gdt描述符中視頻段描述符中的段基址+0xc0000000
64 mov ebx, [gdt_ptr + 2]
65 or dword [ebx + 0x18 + 4], 0xc0000000
66
67 ;將gdt的基址加上0xc0000000使其成為內核所在的高地址
68 add dword [gdt_ptr + 2], 0xc0000000
69
70 add esp, 0xc0000000 ;將堆疊指標同樣映射到內核地址
71
72 ;二、將頁目錄表地址賦值給cr3
73 mov eax, PAGE_DIR_TABLE_POS
74 mov cr3, eax
75
76 ;三、打開cr0的pg位
77 mov eax, cr0
78 or eax, 0x80000000
79 mov cr0, eax
80
81 ;在開啟分頁后，用gdt新的地址重新加載
82 lgdt [gdt_ptr]
83 mov byte [gs:160], 'H'
84 mov byte [gs:162], 'E'
85 mov byte [gs:164], 'L'
86 mov byte [gs:166], 'L'
87 mov byte [gs:168], 'O'
88 mov byte [gs:170], ' '
89 mov byte [gs:172], 'P'
90 mov byte [gs:174], 'A'
91 mov byte [gs:176], 'G'
92 mov byte [gs:178], 'E'
93
94 jmp $
95 ;---------------------------------------------
96
97 ;--------------函式宣告------------------------
98 ;setup_page：(功能)設定分頁------------
99 setup_page:
100 ;先把頁目錄占用的空間逐位元組清0
101 mov ecx, 4096
102 mov esi, 0
103 .clear_page_dir:
104 mov byte [PAGE_DIR_TABLE_POS + esi], 0
105 inc esi
106 loop .clear_page_dir
107
108 ;開始創建頁目錄項
109 .create_pde:
110 mov eax, PAGE_DIR_TABLE_POS
111 add eax, 0x1000 ;此時eax為第一個頁表的位置
112 mov ebx, eax
113
114 ;下面將頁目錄項0和0xc00都存為第一個頁表的地址，每個頁表表示4MB記憶體
115 ;頁目錄表的屬性RW和P位為1,US為1，表示用戶屬性，所有特權級別都可以訪問
116 or eax, PG_US_U | PG_RW_W | PG_P
117
118 ;在頁目錄表中的第1個目錄項中寫入第一個頁表的地址(0x101000)和屬性
119 mov [PAGE_DIR_TABLE_POS + 0x0], eax
120
121 mov [PAGE_DIR_TABLE_POS + 0xc00], eax
122
123 ;使最后一個目錄項指向頁目錄表自己的地址
124 sub eax, 0x1000
125 mov [PAGE_DIR_TABLE_POS + 4092], eax
126
127 ;下面創建頁表項(PTE)
128 mov ecx, 256 ;1M低端記憶體/每頁大小4K=256
129 mov esi, 0
130 mov edx, PG_US_U | PG_RW_W | PG_P
131 .create_pte: ;創建page table entry
132 mov [ebx + esi*4], edx
133 add edx, 4096
134 inc esi
135 loop .create_pte
136
137 ;創建內核其他頁表的PDE
138 mov eax, PAGE_DIR_TABLE_POS
139 add eax, 0x2000 ;此時eax為第二個頁表的位置
140 or eax, PG_US_U | PG_RW_W | PG_P
141 mov ebx, PAGE_DIR_TABLE_POS
142 mov ecx, 254 ;范圍為第769～1022的所有目錄項數量
143 mov esi, 769
144 .create_kernel_pde:
145 mov [ebx + esi*4], eax
146 inc esi
147 add eax, 0x1000
148 loop .create_kernel_pde
149 ret
loader.S
我還是將之前的代碼附上了，便于理解，新增的是開啟分頁機制以及函式宣告部分，
我們重點來看看setup_page函式，該函式的作用便是創建頁目錄表并初始化頁記憶體，PAGE_DIR_TABLE_POS在boot.inc檔案中定義為0x100000，也就是我們事先說的頁目錄表的存盤地址，
首先將以PAGE_DIR_TABLE_POS為起始地址的4096個位元組，也就是一頁物理頁大小的記憶體空間給清0，隨后再進行初始化，代碼中有很多注釋，這里就不再贅述，
四、運行測驗
這里就不再贅述，還是和前面一樣，通過nasm和dd命令將loader.S編譯寫入硬碟，運行boch得到如下畫面，在boch的控制臺輸入info tab命令查看生成的頁表，
左邊是虛擬地址，右邊是映射后的真實物理地址，對比我們前面設計的頁表沒有問題，說明我們的程式沒有問題，
本回到此結束了，接下來我們要開始向內核進軍，開始使用熟悉的C語言來撰寫程式了，欲知后事如何，請看下回分解，
轉載請註明出處，本文鏈接：https://www.uj5u.com/caozuo/492857.html
標籤：嵌入式