uj5u.com熱心網友回復：
uj5u.com熱心網友回復：
建個類就完成一半了，然后寫幾個判斷就全完成了，不會建議放棄，轉行。
uj5u.com熱心網友回復：
居然提了兩個。你可以說你想要做什么，然后在這個程序中遇到了什么問題，而不是拋出你的需求。
如果你依然一頭霧水！親，這邊建議您認真學習呢！
uj5u.com熱心網友回復：
public class zd{public int dj;
public int zk;
public zd(int DJ,int ZK){
dj=DJ*ZK;
zk=ZK;
}
大致是這么個意思，多看書
uj5u.com熱心網友回復：
uj5u.com熱心網友回復：
這個應該不難，我也小白，零C#基礎邊工邊學2個多月藍色提示里的我可能不曉得有沒有用到，但是這個代碼已經有頭緒了
uj5u.com熱心網友回復：
就像2樓說的創建一個類再加幾個判斷陳述句就做完了public class zd
{
double danjia=0;
int shuliang=0;
double zhekou=0;
bool cuxiao=falsel
int huiyuan=0;//0為普通，1為黃金，2為白金
pubic int Shuliang
{
get {return shuliang;}
set {shuliang=value;}
}
}
if(cuxiao==false)
{if (huiyuan==0)
{jine=(double)shuliang*danjia}
else if(huiyuan==1)
{jine=(double)shuliang*danjia*0.9}
}
else
{jine=(double)shuliang*danjia*0.6}
大概類似這樣子，我是從改程式使用控制元件開始學的，控制臺程式的輸入輸出就不太會寫的0.0
uj5u.com熱心網友回復：
這個設計為一個賬單類有問題，商品名稱題目都沒有出現，是否促銷是商店控制，也不應該由訂單控制，這書不是很好。商品類
商品編號，商品名稱、單價
會員類
會員編號，會員型別
購物車類
商品、數量
購物小票類
會員，購物集合，是否促銷，折扣、金額
雖然不符合題目要求，可能更符合實際吧，用vb.net寫了一個，一起探討探討。
Module MainModule
Sub Main()
'定義貨架
Dim Storage As New List(Of Product) From {
New Product With {.Id = "P001", .Name = "可樂", .Price = 2.5D},
New Product With {.Id = "P002", .Name = "大米", .Price = 50}}
'定義會員
Dim member As New Member With {.Id = "Vip001", .Name = "張三", .Type = Member.MemberType.Platinum}
'獲取今天是否促銷標記
Dim isDiscount As Boolean = False
'會員入店，生成訂單
Dim bill As New Bill(isDiscount, member, New List(Of Cart))
'購物
bill.Carts.Add(New Cart With {.Product = Storage(0), .Count = 2})
bill.Carts.Add(New Cart With {.Product = Storage(1), .Count = 1})
'結算
For Each i In bill.Carts
Console.WriteLine($"商品:{i.Product.Name} 數量:{i.Count}")
Next
Console.WriteLine($"會員:{bill.Member.Name} 折扣:{bill.Discount} 金額:{bill.Amount}")
Console.ReadKey()
End Sub
End Module
''' <summary>
''' 商品類
''' </summary>
Public Class Product
Public Property Id As String
Public Property Name As String
Public Property Price As Decimal
End Class
''' <summary>
''' 會員類
''' </summary>
Public Class Member
Public Property Id As String
Public Property Name As String
Public Property Type As MemberType = MemberType.Standard
Public ReadOnly Property Discount As Decimal
Get
Return Type / 10D
End Get
End Property
Public Enum MemberType
Standard = 10
Gold = 9
Platinum = 8
End Enum
End Class
''' <summary>
''' 購物車類
''' </summary>
Public Class Cart
Public Property Product As Product
Public Property Count As Integer
End Class
''' <summary>
''' 購物清單類
''' </summary>
Public Class Bill
Private isDiscount As Boolean
Public Sub New(isDiscount As Boolean, member As Member, carts As List(Of Cart))
Me.isDiscount = isDiscount
Me.Member = member
Me.Carts = carts
End Sub
Public Property Member As Member
Public ReadOnly Property Carts As New List(Of Cart)
Public ReadOnly Property Discount As Decimal
Get
If isDiscount Then
Return 0.6D
Else
Return Member.Discount
End If
End Get
End Property
Public ReadOnly Property Amount As Decimal
Get
Return Carts.Sum(Function(x) x.Product.Price * x.Count) * Discount
End Get
End Property
End Class
商品:可樂 數量:2
商品:大米 數量:1
會員:張三 折扣:0.8 金額:44.00
uj5u.com熱心網友回復：
/// <summary>
/// 現金收費類
/// </summary>
public class CashSuper
{
private double price;
private int quantity;
private double discount;
private double total;
private DateTime createDate;
private bool isPromotion;
private MemberType _VIP;
/// <summary>
/// 單價
/// </summary>
public double Price { get; set; }
/// <summary>
/// 數量
/// </summary>
public int Quantity { get; set; }
/// <summary>
/// 折扣
/// </summary>
public double Discount
{
get
{
if (IsPromotion)
{
return 0.6;
}
else
{
if (VIP == MemberType.Gold)
{
return 0.9;
}
else if (VIP == MemberType.Gold)
{
return 0.8;
}
else
{
return 1.0;
}
}
}
}
/// <summary>
/// 金額
/// </summary>
public double Total { get { return Price * Quantity * Discount; } }
/// <summary>
/// 日期
/// </summary>
public DateTime CreateDate { get; set; }
/// <summary>
/// 是否促銷
/// </summary>
public bool IsPromotion { get; set; }
/// <summary>
/// 會員型別
/// </summary>
public MemberType VIP { get; set; }
}
uj5u.com熱心網友回復：
加上日期，略作修改。
Module MainModule
'定義貨架
Dim storage As New List(Of Product) From {
New Product With {.Id = "P001", .Name = "可樂", .Price = 2.5D},
New Product With {.Id = "P002", .Name = "大米", .Price = 50}}
'定義會員庫
Dim members As New List(Of Member) From {
New Member With {.Id = "Vip001", .Name = "張三", .Type = Member.MemberType.Platinum},
New Member With {.Id = "Vip002", .Name = "李四", .Type = Member.MemberType.Gold}}
Sub Main()
'獲取今天是否促銷標記
Dim isDiscount As Boolean = False
'掃描會員卡，獲取會員
Dim vipMember = members.First(Function(x) x.Id = "Vip001")
'會員結算，生成訂單
Dim bill As New Bill(isDiscount, vipMember, New List(Of Cart))
'商品掃碼
bill.Carts.Add(New Cart With {.Product = storage.First(Function(x) x.Id = "P001"), .Count = 2})
bill.Carts.Add(New Cart With {.Product = storage.First(Function(x) x.Id = "P002"), .Count = 1})
'列印小票
For Each i In bill.Carts
Console.WriteLine($"商品:{i.Product.Name} 數量:{i.Count}")
Next
Console.WriteLine($"會員:{bill.Member.Name} 折扣:{bill.Discount} 金額:{bill.Amount}")
Console.WriteLine($"日期:{bill.Date}")
Console.ReadKey()
End Sub
End Module
''' <summary>
''' 商品類
''' </summary>
Public Class Product
Public Property Id As String
Public Property Name As String
Public Property Price As Decimal
End Class
''' <summary>
''' 會員類
''' </summary>
Public Class Member
Public Property Id As String
Public Property Name As String
Public Property Type As MemberType = MemberType.Standard
Public ReadOnly Property Discount As Decimal
Get
Return Type / 10D
End Get
End Property
Public Enum MemberType
Standard = 10
Gold = 9
Platinum = 8
End Enum
End Class
''' <summary>
''' 購物車類
''' </summary>
Public Class Cart
Public Property Product As Product
Public Property Count As Integer
End Class
''' <summary>
''' 購物清單類
''' </summary>
Public Class Bill
Private isDiscount As Boolean
Public Sub New(isDiscount As Boolean, member As Member, carts As List(Of Cart))
Me.isDiscount = isDiscount
Me.Member = member
Me.Carts = carts
End Sub
Public ReadOnly Property Member As Member
Public ReadOnly Property Carts As New List(Of Cart)
Public ReadOnly Property Discount As Decimal
Get
Return If(isDiscount, 0.6D, Member.Discount)
End Get
End Property
Public ReadOnly Property Amount As Decimal
Get
Return Carts.Sum(Function(x) x.Product.Price * x.Count) * Discount
End Get
End Property
Public ReadOnly Property [Date] As Date = Now
End Class
uj5u.com熱心網友回復：
學習了。。。。uj5u.com熱心網友回復：
很簡單，就是利用if…else和switch…case陳述句罷了uj5u.com熱心網友回復：
你們也太慣著伸手黨了吧uj5u.com熱心網友回復：
這就是創建類，按照要求寫一些成員和對應的方法……很難嗎？這個自己看看書就會了，如果真要走程式員的路，主要是靠自己研究，上班時其實很多時候都是需要自學的，沒有自學的能力，建議放棄……uj5u.com熱心網友回復：
創建個類，然后定義屬性，最后確定幾個關鍵要素即可。 例如 會員等級，折扣，原價，進位，實收價，等等。具體語法你可以參考樓上的 代碼。uj5u.com熱心網友回復：
可以的，最好再封裝下 屬性的 權限。設計好聯動。[/code]
轉載請註明出處，本文鏈接：https://www.uj5u.com/net/116298.html
標籤：C#
上一篇：小白求解決