我在 XML 元素中有以下字串：
<foodAndBeverageNutrient__>ENER-|APPROXIMATELY||120|E14 ENER-|APPROXIMATELY||501|KJO PRO-|APPROXIMATELY||6.6|GRM CHOAVL|APPROXIMATELY||6.9|GRM SUGAR-|APPROXIMATELY||1.2|GRM FAT|APPROXIMATELY||7.1|GRM FASAT|APPROXIMATELY||1.3|GRM FAMSCIS|APPROXIMATELY||3.8|GRM FAPUCIS|APPROXIMATELY||2.0|GRM FIBTG|APPROXIMATELY||1.2|GRM SALTEQ|APPROXIMATELY||0.5|GRM</foodAndBeverageNutrient__>
將以下 xsl 與 tokenize 一起使用，我可以拆分
<xsl:template name="foodAndBeverageNutrient_detail">
<xsl:for-each select="tokenize(., '\ \ ')">
<xsl:variable name="foodAndBeverageNutrient" select="tokenize(., '\|')"/>
<nutrientDetail>
<nutrientTypeCode>
<xsl:value-of select="$foodAndBeverageNutrient[1]"/>
</nutrientTypeCode>
<xsl:if test="$foodAndBeverageNutrient[3] !=''">
<dailyValueIntakePercent>
<xsl:value-of select="$foodAndBeverageNutrient[3]"/>
</dailyValueIntakePercent>
</xsl:if>
<measurementPrecisionCode>
<xsl:value-of select="$foodAndBeverageNutrient[2]"/>
</measurementPrecisionCode>
<quantityContained measurementUnitCode="{$foodAndBeverageNutrient[5]}">
<xsl:value-of select="$foodAndBeverageNutrient[4]"/>
</quantityContained>
</nutrientDetail>
</xsl:for-each>
</xsl:template>
給我以下結果：
<foodAndBeverageNutrientInformation>
<preparationState>UNPREPARED</preparationState>
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="ENER-"/>
<quantityContained>
<measurementValue unitOfMeasure="E14">
<value>29</value>
</measurementValue>
</quantityContained>
</foodAndBeverageNutrient>
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="ENER-"/>
<quantityContained>
<measurementValue unitOfMeasure="KJO">
<value>69</value>
</measurementValue>
</quantityContained>
</foodAndBeverageNutrient>
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="PRO-"/>
<quantityContained>
<measurementValue unitOfMeasure="GR">
<value>1.4</value>
</measurementValue>
</quantityContained>
</foodAndBeverageNutrient>
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="CHOAVL"/>
<quantityContained>
<measurementValue unitOfMeasure="GR">
<value>3.8</value>
</measurementValue>
</quantityContained>
</foodAndBeverageNutrient>
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="SUGAR-"/>
<quantityContained>
<measurementValue unitOfMeasure="GR">
<value>3.4</value>
</measurementValue>
</quantityContained>
</foodAndBeverageNutrient>
但是我需要按營養型別代碼分組，所以結果是每個營養型別代碼都會重復包含的數量，就像這樣；
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="ENER-"/>
<quantityContained>
<measurementValue unitOfMeasure="E14">
<value>29</value>
</measurementValue>
</quantityContained>
<quantityContained>
<measurementValue unitOfMeasure="KJO">
<value>122</value>
</measurementValue>
</quantityContained>
</foodAndBeverageNutrient>
我曾嘗試對 <xsl:for-each-group 進行分組，但看起來我在 xsl 中的級別錯誤，所以我仍然得到“舊”結果。有沒有辦法與標記化變數分組以重復數量部分？
uj5u.com熱心網友回復：
將資料分組為陣列序列的 XSLT 3 示例是
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="3.0"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="#all"
expand-text="yes">
<xsl:template match="foodAndBeverageNutrient__">
<xsl:for-each-group select="tokenize(., '\ \ ') ! array { tokenize(., '\|') }" group-by="?1">
<foodAndBeverageNutrient>
<measurementPrecision>APPROXIMATELY</measurementPrecision>
<nutrientTypeCode iNFOODSCodeValue="{current-grouping-key()}"/>
<xsl:apply-templates select="current-group()"/>
</foodAndBeverageNutrient>
</xsl:for-each-group>
</xsl:template>
<xsl:template match=".[. instance of array(*)]">
<quantityContained measurementUnitCode="{?5}">
<value>{?4}</value>
</quantityContained>
</xsl:template>
<xsl:mode on-no-match="shallow-copy"/>
<xsl:output indent="yes" method="xml"/>
</xsl:stylesheet>
我不太確定我是否選擇了正確的資料，但您會更好地知道您擁有的索引，例如value.
轉載請註明出處，本文鏈接：https://www.uj5u.com/net/481311.html