我的問題受到
我的問題：
有沒有辦法利用公式根據列中的檔案 ID 和范圍的數量生成此E結果F？因此，如果添加了第四個和范圍，列中ID的所需結果會顯示出來嗎？我懷疑 Lambda 會起作用，但我對它并沒有我應該做的那么強大。ab
不成功的嘗試：
=lambda(someIDs,SomeRanges,IMPORTRANGE(someIds,SomeRanges))(filter(E2:E,E2:E<>""),filter(F2:F,F2:F<>""))
非常糟糕的嘗試：
=contact(Player()*1800-CoffeeBribe*Not(Home))
=company(theMaster(emailed)*(false))<>??
如果不被接受，所有有用的答案都將被投票。謝謝。
uj5u.com熱心網友回復：
如果范圍相同：
=LAMBDA(x, QUERY(REDUCE({"ID", "Amount"}, x,
LAMBDA(a, c, {a; IMPORTRANGE(c, "Sheet1!A2:B")})),
"where Col1 is not null", 1))
(E2:INDEX(E:E, MAX((E:E<>"")*ROW(E:E))))
如果范圍不同：
=INDEX(LAMBDA(x, y, QUERY(SPLIT(TRANSPOSE(SPLIT(QUERY(MAP(x, y,
LAMBDA(e, f, QUERY("?"&FLATTEN(QUERY("?"&TRANSPOSE(
IMPORTRANGE(e, f)),,9^9)),,9^9))),,9^9),
"?")), "?"), "where Col1 <> ' ' order by Col2", 1))(
E2:INDEX(E:E, MAX((E:E<>"")*ROW(E:E))),
F2:INDEX(F:F, MAX((F:F<>"")*ROW(F:F)))))
或者：
=LAMBDA(x, QUERY(REDUCE({"ID", "Amount"}, x,
LAMBDA(a, b, {a; IMPORTRANGE(b, OFFSET(b,,1))})),
"where Col2 is not null", 1))
(E2:INDEX(E:E, MAX((E:E<>"")*ROW(E:E))))
在過去，它將通過生成它來解決：
={""; INDEX("={"&TEXTJOIN("; ", 1, "IMPORTRANGE("""&
FILTER(E2:E, E2:E<>"")&""", """&FILTER(F2:F, F2:F<>"")&""")")&"}")}
uj5u.com熱心網友回復：
REDUCE接受并回傳陣列。我們可以用它來堆疊范圍。INDEX/COUNTA可用于獲取不帶空格所需的范圍。OFFSET可用于獲取下一列的值。
=QUERY(
REDUCE(
{"Id","Amount"},
E2:INDEX(E2:E,COUNTA(E2:E)),
LAMBDA(
a,e,
{a;IMPORTRANGE(e,OFFSET(e,0,1))}
)
),
"Select * where Col1 is not null order by Col1",
1
)
轉載請註明出處，本文鏈接：https://www.uj5u.com/net/525246.html
上一篇：用冒號連接公式的范圍