首先，以下代碼用masm5.0或者tasm2.0均可以編譯生成t10-5.obj，然后再用tlink.exe /3 t10-5.obj可以正確生成exe檔案。
為了便于理解，我把書上對這個例子的說明也貼出來，這樣方便大大們快速識別出問題
看不懂的地方都在代碼的注釋區標出來了
;T10-5.ASM
;演示任務切換和任務內特權級變換
include 386SCD.ASM
.386P
;全域描述符表
GDTSEG SEGMENT PARA USE16
GDT LABEL BYTE
dummy descriptor <>
normal descriptor <0ffffh,0,0,atdw,0>
normal_sel=normal-gdt
effgdt label byte
demotss descriptor <demotsslen-1,demotssseg,,at386tss,>
demotss_sel=demotss-gdt
demoldtab descriptor <demoldtlen-1,demoldtseg,,atldt,>
demoldt_sel=demoldtab-gdt
;臨時任務的任務狀態段描述符
temptss descriptor <temptsslen-1,temptssseg,,at386tss+dpl2,>
temptss_sel=temptss-gdt
;臨時任務代碼段
tempcode descriptor <0ffffh,tempcodeseg,,atce,>
tempcode_sel=tempcode-gdt
;子程式代碼段描述符
subr descriptor <subrlen-1,subrseg,,atce+d32,>
subr_sel=subr-gdt+rpl3
videobuff descriptor <0ffffh,0,0,0f00h+atdw+dpl3,0>
video_sel=videobuff-gdt
gdnum=($-effgdt)/(size descriptor)
gdtlen=$-gdt
gdtseg ends
;演示任務的任務狀態段
DemoTSSSEG segment para use16
dd 0 ;鏈接字
dd DemoStack0LEN ;0級堆疊指標
dw DemoStack0_SEL,0
dd 0 ;1級堆疊指標
dw ?,0
dd DemoStack2LEN ;2級堆疊指標
DW Demostack2_sel,0
dd 0 ;cr3
dw demobegin,0 ;eip
dd 0 ;eflags
dd 0 ;eax
dd 0 ;ecx
dd 0 ;edx
dd 0 ;ebx
dd DemoStack2LEN ;esp
dd 0 ;ebp
dd 0 ;esi
dd 0B8000H ;edi
dw video_sel,0 ;es
dw DemoCode_sel,0 ;cs
dw DemoStack2_sel,0 ;ss
dw DemoData_sel,0 ;ds
dw ToDLDT_SEL,0 ;fs
dw ToTTSS_SEL,0 ;gs
dw DemoLDT_SEL,0 ;ldtr
dw 0
dw $+2 ;I/O許可位圖指標
db 0ffh ;I/O許可位圖結束位元組
DemoTSSLEN=$
DemoTSSSEG ends
;演示任務的區域描述符表LDT
DemoLDTSEG segment para use16
demoldt label byte
demostack0 descriptor <demostack0len-1,demostack0seg,,atdw+d32,>
demostack0_sel=(demostack0-demoldt)+til
demostack2 descriptor <demostack2len-1,demostack2seg,,atdw+d32+dpl2,>
demostack2_sel=(demostack2-demoldt)+til+rpl2
;演示代碼段描述符
democode descriptor <democodelen-1,democodeseg,,atce+d32+dpl2,>
democode_sel=(democode-demoldt)+til+rpl2
;演示資料段描述符
demodata descriptor <demodatalen-1,demodataseg,,atdw+d32+dpl3,>
demodata_sel=(demodata-demoldt)+til
;把LDT作為普通資料段描述的描述符（DPL=2）
todldt descriptor <demoldtlen-1,demoldtseg,,atdw+dpl2,>
todldt_sel=(todldt-demoldt)+til
;把tss作為普通資料段描述的描述符（DPL=2）
TOTTSS descriptor <temptsslen-1,temptssseg,,atdw+dpl2,>
tottss_sel=(tottss-demoldt)+til
demoLDNUM=($-demoldt)/(size descriptor)
;指向子程式subrb的呼叫門（dpl=3）
tosubr gate <subrb,subr_sel,0,at386cgat+dpl3,0>
tosubr_sel=(tosubr-demoldt)+til+rpl2
;指向臨時任務temp的任務門（DPL=3）
totempt gate <0,temptss_sel,0,attaskgat+dpl3,0>
totempt_sel=(totempt-demoldt)+til
demoldtlen=$-demoldt
demoldtseg ends
;演示任務的0級堆疊
DemoStack0SEG segment para use32
demostack0len=1024
db demostack0len dup(0)
demostack0seg ends
DemoStack2SEG segment para use32
demostack2len=512
db demostack2len dup(0)
demostack2seg ends
;演示任務的資料段
DemoDataSEG segment para use32
message db 'Value='https://bbs.csdn.net/topics/,0
demodatalen=$
demodataseg ends
subrseg segment para use32
assume cs:subrseg
subrb proc far
push ebp
mov ebp,esp
pushad
mov eax,[ebp+12]
mov esi,eax
mov ah,7
jmp short subr2
subr1: stosw
subr2: lodsb
or al,al
jnz subr1
mov edx,[ebp+16]
mov ecx,8
subr3: rol edx,4
mov al,dl
call htoasc
stosw
loop subr3
popad
pop ebp
ret 8
subrb endp
htoasc proc
and al,0fh
add al,90h
daa
adc al,40h
daa
ret
htoasc endp
subrlen=$
subrseg ends
DemoCodeSEG segment para use32
assume cs:DemoCodeSEG
DemoBegin:
mov fs:tosubr.dcount,2 ;?看不懂的地方2，這里的段暫存器為啥是fs
push dword ptr gs:temptask.treip ;?看不懂的地方3，這里的段暫存器為啥是gs
push offset Message
call32 tosubr_sel,0 ;這個子函式看得懂
assume ds:temptssseg
push gs
pop ds ;看不懂的地方4，為啥要push gs然后pop ds
mov ax,normal_sel
mov temptask.trds,ax
mov temptask.tres,ax
mov temptask.trfs,ax
mov temptask.trgs,ax
mov temptask.trss,ax
jump32 totempt_sel,0 ;看不懂的地方5，這里的totempt_sel選擇子對應的是段temptssseg，而段temptssseg是個沒賦初值的結構
;體，怎么跳轉過去呢？
DemoCodeLEN=$
DemoCodeSEG ends
temptssseg segment para use16
temptask taskss <>
db 0ffh
temptsslen=$
temptssseg ends
tempcodeseg segment para use16
assume cs:tempcodeseg
Virtual:
mov BX,tempTSS_SEL
LTR BX
jump16 demotss_sel,0 ;這里進行了切換到任務DemoTSSSEG，因為EIP是demobegin，這里跳轉到demobegin
toreal:
clts
mov eax,cr0
and eax,0fffffffeh
mov cr0,eax
jump16 <seg real>,<offset real>
tempcodelen=$
tempcodeseg ends
RDataSEG segment para use16
VGDTR PDESC <GDTLEN-1,>
SPVAR DW ?
SSVAR DW ?
RDataSEG ends
RCodeSEG segment para use16
assume cs:rcodeseg,ds:rdataseg,es:rdataseg ;看不懂的地方1，以前沒見到過一個段同時和兩個段暫存器對應的代碼
start:
mov ax,Rdataseg
mov ds,ax
cld
call init_gdt
mov ax,DemoLDTSEG
mov fs,ax
mov cx,DemoLDNUM
mov SI,OFFSET DemoLDT
call init_ldt
mov ssvar,ss
mov spvar,sp
lgdt qword ptr vgdtr
cli
mov eax,cr0
or eax,1
mov cr0,eax
jump16 <tempCode_sel>,<offset virtual>
Real:
mov ax,RDataSEG
mov ds,ax
lss sp,dword ptr spvar
sti
mov ax,4c00h
int 21h
init_gdt proc near
push ds
mov ax,gdtseg
mov ds,ax
mov cx,gdnum
mov si,offset effgdt
initg: mov ax,[si].basel
movzx eax,ax
shl eax,4
shld edx,eax,16
mov [si].basel,ax
mov [si].basem,dl
mov [si].baseh,dh
add si,size descriptor
loop initg
pop ds
mov bx,16
mov ax,gdtseg
mul bx
mov word ptr vgdtr.base,ax
mov word ptr vgdtr.base+2,dx
ret
init_gdt endp
init_ldt proc
ildt: mov ax,fs:[si].basel
movzx eax,ax
SHL eax,4
shld edx,eax,16
mov fs:[si].basel,ax
mov fs:[si].basem,dl
mov fs:[si].baseh,dh
add si,size descriptor
loop ildt
ret
init_ldt endp
RCodeSEG ends
end start
uj5u.com熱心網友回復：
把386scd.asm也貼上去吧，點回復沒出來專門的回復頁面，就不以專門的代碼格式發了;符號常量等的定義
;存盤段描述符/系統段描述符結構型別的定義
descriptor struc
limitl dw 0
basel dw 0
basem db 0
attributes dw 0
baseh db 0
descriptor ends
;門描述符結構型別的定義
gate struc
offsetl dw 0
selector dw 0
dcount db 0
gtype db 0
offseth dw 0
gate ends
;偽描述符結構型別的定義
pdesc struc
limit dw 0
base dd 0
pdesc ends
;TSS結構型別的定義
taskss struc
trlink dw ?,0
tresp0 dd ?
trss0 dw ?,0
tresp1 dd ?
trss1 dw ?,0
tresp2 dd ?
trss2 dw ?,0
trcr3 dd ?
treip dd ?
treflag dw ?,?
treax dd ?
trecx dd ?
tredx dd ?
trebx dd ?
tresp dd ?
trebp dd ?
tresi dd ?
tredi dd ?
tres dw ?,0
trcs dw ?,0
trss dw ?,0
trds dw ?,0
trfs dw ?,0
trgs dw ?,0
trldt dw ?,0
trflag dw 0
triomap dw $+2
taskss ends
;存盤段描述符型別值說明
ATDR=90h
ATDW=92H
ATDWA=93H
ATCE=98H
ATCER=9AH
ATCCO=9CH ;存在的只執行一致代碼段型別值
ATCCOR=9EH
;系統描述符和門描述符型別值說明
ATLDT=82h ;區域描述符表段值型別
ATTASKGAT=85H
AT386TSS=89H ;?386TSS型別值
AT386CGAT=8CH ;386呼叫門
AT386IGAT=8EH
AT386TGAT=8FH
;DPL和RPL值說明
DPL1=20H
DPL2=40H
DPL3=60H
RPL1=01H
RPL2=02H
RPL3=03H
IOPL1=1000H
IOPL2=2000H
IOPL3=3000H
;其他常量值說明
D32=4000H ;在描述可執行段的描述符中，表示32位代碼段
TIL=04H ;描述符表標志
VFML=0002H
IFL=0200H
;32位偏移的段間轉移宏指令
JUMP32 MACRO selector,offsetv
DB 0eaH
DW offsetv ;32位偏移
DW 0
DW selector
ENDM
CALL32 MACRO selector,offsetv
db 09ah
dw offsetv
dw 0
dw selector
endm
JUMP16 MACRO selector,offsetv
db 0eah
dw offsetv
dw selector
endm
call16 MACRO selector,offsetv
db 9ah
dw offsetv
dw selector
endm
uj5u.com熱心網友回復：
把386scd.asm也貼上去吧，發現還是用代碼格式貼清晰一些，多謝各位;符號常量等的定義
;存盤段描述符/系統段描述符結構型別的定義
descriptor struc
limitl dw 0
basel dw 0
basem db 0
attributes dw 0
baseh db 0
descriptor ends
;門描述符結構型別的定義
gate struc
offsetl dw 0
selector dw 0
dcount db 0
gtype db 0
offseth dw 0
gate ends
;偽描述符結構型別的定義
pdesc struc
limit dw 0
base dd 0
pdesc ends
;TSS結構型別的定義
taskss struc
trlink dw ?,0
tresp0 dd ?
trss0 dw ?,0
tresp1 dd ?
trss1 dw ?,0
tresp2 dd ?
trss2 dw ?,0
trcr3 dd ?
treip dd ?
treflag dw ?,?
treax dd ?
trecx dd ?
tredx dd ?
trebx dd ?
tresp dd ?
trebp dd ?
tresi dd ?
tredi dd ?
tres dw ?,0
trcs dw ?,0
trss dw ?,0
trds dw ?,0
trfs dw ?,0
trgs dw ?,0
trldt dw ?,0
trflag dw 0
triomap dw $+2
taskss ends
;存盤段描述符型別值說明
ATDR=90h
ATDW=92H
ATDWA=93H
ATCE=98H
ATCER=9AH
ATCCO=9CH ;存在的只執行一致代碼段型別值
ATCCOR=9EH
;系統描述符和門描述符型別值說明
ATLDT=82h ;區域描述符表段值型別
ATTASKGAT=85H
AT386TSS=89H ;?386TSS型別值
AT386CGAT=8CH ;386呼叫門
AT386IGAT=8EH
AT386TGAT=8FH
;DPL和RPL值說明
DPL1=20H
DPL2=40H
DPL3=60H
RPL1=01H
RPL2=02H
RPL3=03H
IOPL1=1000H
IOPL2=2000H
IOPL3=3000H
;其他常量值說明
D32=4000H ;在描述可執行段的描述符中，表示32位代碼段
TIL=04H ;描述符表標志
VFML=0002H
IFL=0200H
;32位偏移的段間轉移宏指令
JUMP32 MACRO selector,offsetv
DB 0eaH
DW offsetv ;32位偏移
DW 0
DW selector
ENDM
CALL32 MACRO selector,offsetv
db 09ah
dw offsetv
dw 0
dw selector
endm
JUMP16 MACRO selector,offsetv
db 0eah
dw offsetv
dw selector
endm
call16 MACRO selector,offsetv
db 9ah
dw offsetv
dw selector
endm
uj5u.com熱心網友回復：
assume cs:rcodeseg,ds:rdataseg,es:rdataseg ;看不懂的地方1，以前沒見到過一個段同時和兩個段暫存器對應的代碼=========================================
這個確實沒啥用，但是也可以這么寫，可能有用的地方是串掃描、串復制，這里沒有
mov fs:tosubr.dcount,2 ;?看不懂的地方2，這里的段暫存器為啥是fs
=========================================
他初始化的代碼有：
mov ax,DemoLDTSEG
mov fs,ax
剩下的你慢慢看吧
uj5u.com熱心網友回復：
DemoCodeSEG 這個段的執行環境已經在DemoTSSSEG中設定好了。jump16 demotss_sel,0 ;
這里通過TSS切換到DemoCodeSEG,將DemoTSSSEG中設定的值全部加載到對應的暫存器中。你的問題全部在DemoTSSSEG這個TSS段中，要仔細看。
ASSUME 是偽指令, 配合SEGMENT偽指令使用的，其作用是告訴編譯器尋址某一特定段時要使用哪一個段暫存器。
uj5u.com熱心網友回復：
感謝樓上兩位，最近領導布置任務比較多，等過一段再細看這個exa，多謝uj5u.com熱心網友回復：
關于這個example，第一個“沒見到過一個段同時和兩個段暫存器對應的代碼”，感謝早打大打核戰爭老師解釋；
剩下幾個，確實看不懂為啥這樣寫，能否請老師們具體解釋一下，多謝。 另外，語法什么的明白，就是看不懂二、三的用法和四的安排，以及五的原理。多謝
uj5u.com熱心網友回復：
原來第5個問題書上有講，只怪自己當時一邊干別的事，一邊看書，浮躁沒看下去。。totempt_sel這個選擇子，是采用段間轉移指令JMP，通過任務門TOTEMPT切換到臨時任務。臨時任務的現場從臨時任務的TSS恢復，臨時任務的掛起點是臨時任務代碼段內的ToReal點，所以就從該點下去繼續執行
uj5u.com熱心網友回復：
上面的內容是抄書上的，繼續作一下筆記。。totempt_sel這個選擇子，是被采用段間轉移指令JMP，通過任務門TOTEMPT切換到臨時任務temptssseg；而臨時任務在切換到DemoCodeSEG這段之前，掛起的點是ToReal點，所以第5個地方切換以后得以繼續執行。。
轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/102365.html
標籤：匯編語言