主頁 >  其他 > 第四十九章 Caché 函式大全 $PIECE 函式

第四十九章 Caché 函式大全 $PIECE 函式

2020-10-12 08:52:52 其他

文章目錄

  • 第四十九章 Caché 函式大全 $PIECE 函式
  • 大綱
    • 引數
  • 描述
    • 回傳一個子字串，
  • 引數
    • string
    • delimiter
    • from
    • to
    • 指定`* -n`和`* + n`引數值
    • 示例：回傳帶分隔符的子字串
  • 使用SET $PIECE替換子字串
    • 示例：替換分隔的子字串
    • 初始化字串變數
    • 分隔符為空字串
    • 引數超過32,768個字符的$PIECE
  • 注意
    • 使用`$PIECE`解包資料值
    • $PIECE 與 $LENGTH
    • Null Values
    • 強制數值計算
    • 嵌套$PIECE操作
    • `$PIECE`與`$EXTRACT`和`$LIST`的比較

第四十九章 Caché 函式大全 $PIECE 函式

使用定界符回傳或替換子字串，

大綱

$PIECE(string,delimiter,from,to)
$P(string,delimiter,from,to)

SET $PIECE(string,delimiter,from,to)=value
SET $P(string,delimiter,from,to)=value

引數

  • string 標識分隔的子字串的目標字串，將字串指定為計算結果為帶引號的字串或數字值的運算式，在SET $PIECE語法中，字串必須是變數或多維屬性，
  • 用于標識字串中子字串的定界符，將定界符指定為一個運算式，該運算式的結果為包含一個或多個字符的帶引號的字串，
  • from 可選-運算式的計算結果為指定字串中子字串的位置或子字串范圍的開頭的代碼，子字串由定界符分隔，并從1開始計數，允許的值為n（正整數，指定從字串開頭的子字串計數），*（指定字串中的最后一個子字串）和* -n（偏移整數計數），從字串末尾開始倒數的子字串）， SET $PIECE語法還支持* + n（要追加到字串末尾的子字串的偏移整數計數），因此，第一個定界子串是1，第二個定界子串是2，最后一個定界子串是*，倒數第二個定界子串是* -1，如果忽略from，則默認為第一個帶分隔符的子字串，
  • to 可選—一個運算式，其計算結果為指定字串中一系列子字串的結尾子字串的代碼，必須與from一起使用，允許的值為n（從字串開頭指定子字串計數的正整數），*（指定字串中最后一個子字串）和* -n（從字串末尾偏移的子字串整數）， SET $PIECE語法還支持* + n（用于附加到字串末尾的一系列子字串的偏移整數），如果to在字串中位于from之前，則不執行任何操作，也不產生錯誤，

描述

$PIECE通過分隔符的存在來標識字串中的子字串，如果分隔符未出現在字串中，則整個字串將被視為單個子字串，

$PIECE可以通過兩種方式使用：

  • 從字串回傳子字串，這使用$PIECE(string,delimiter,from,to)語法，
  • 替換字串中的子字串，它標識一個子字串并將其替換為另一個子字串，替換子字串的長度可以與原始子字串相同，更長或更短，這使用$PIECE(string,delimiter,from,to) = value 語法，

注意：$PIECE是用于處理包含定界子字串的字串的通用函式，若要處理包含特定MultiValue定界符的MultiValue動態陣列字串，請使用$MV函式，

回傳一個子字串，

從字串回傳指定的子字串（片斷）時，回傳的子字串取決于所使用的引數：

  • $PIECE(string,delimiter)回傳字串中的第一個子字串，如果定界符出現在字串中，則這是第一次出現定界符之前的子字串，如果字串中未出現定界符，則回傳的子字串為字串，
  • $PIECE(string,delimiter,from)回傳一個子字串，其位置由from引數指定，子字串由定界符以及字串的開頭和結尾定界，分隔符本身不回傳，
  • $PIECE(string,delimiter,from,to)回傳一系列子字串，包括從中指定的子字串到in至（包括）中指定的子字串， $PIECE的這種四引數形式回傳一個子字串，該子字串包括在from和to子字串之間出現的定界符的任何中間出現，如果to大于子字串的數量，則回傳的子字串將包括字串末尾的所有子字串，

引數

string

當使用$PIECE回傳子字串時，string可以是用引號引起來的字串文字，規范數字，變數，物件屬性或任何求值為字串或數字的有效ObjectScript運算式，如果將空字串（“”）指定為目標字串，則$PIECE始侄訓傳該空字串，而不考慮其他引數值，

目標字串通常包含用作分隔符的字符（或字串）實體，此字符或字串也不能用作字串中的資料值，

當$PIECE與等號左側的SET一起使用以替換子字串時，string可以是變數或多維屬性參考，它不能是非多維物件屬性，

delimiter

用于在字串中定界子字串的搜索字串，它可以是用引號引起來的字串文字，規范的數字，變數或任何有效的ObjectScript運算式（其結果為字串或數字），

通常，定界符是一個指定字符，從不用作字串中的資料，而是專門留出用作分隔子字串的定界符，例如，如果定界符為“^”，則字串“Red^Orange^Yellow”包含三個定界子字串，

分隔符可以是多字符字串，可以在字串資料中使用其各個字符，例如，如果定界符為“^＃”，則字串“Red^Orange^#^Yellow#Green#^Blue”包含兩個定界子字串：“Red^Orange”和“^Yellow#Green#^Blue”，

通常，字串不以定界符開頭或結尾，如果字串以分隔符開始或結束，則$PIECE將此分隔符視為使用空字串（“”）值劃分子字串，例如，如果定界符為“^”，則字串“^Red^Orange^Yellow^” 包含五個定界子字串；子字串1和5具有空字串值，

如果指定的定界符不在字串中，則$PIECE回傳整個字串，如果指定的分隔符是空字串（“”），則$PIECE回傳空字串，

from

子字串在字串中的位置，使用n（正整數）從字串開頭算起定界的子字串，使用*指定字串中最后一個定界的子字串，使用* -n通過與字串中最后一個分隔的子字串的偏移量來計數分隔的子字串，

  • 1指定字串的第一個子字串（在第一次出現定界符之前的子字串），如果string不包含指定的分隔符，則from值1將回傳string，如果忽略from，則默認為1，
  • 2指定字串的第二個子字串（出現在分隔符的第一次和第二次出現之間，或第一次出現的分隔符和字串結尾之間的子字串），
  • *指定字串的最后一個子字串（最后一次出現定界符之后的子字串），如果string不包含指定的分隔符，則from值*會回傳string，
  • *-1指定字串的倒數第二個子字串， * -n通過相對于字串最后一個子字串的偏移量進行計數， * -0是字串的最后一個子字串； *和* -0在功能上相同，
  • 僅適用于SET $PIECE語法— * + n（星號后跟一個正數）將定界的子字串附加偏移量，超出字串末尾，因此，* + 1在字串末尾附加一個帶分隔符的子字串，* + 2在字串末尾兩個位置附加一個分隔的子字串，并用定界符填充，
  • 如果from是空字串（“”），零，負數，或者指定了超出字串中子字串數量的計數或偏移量，則$PIECE回傳空字串，

$PIECE將a從數字形式轉換為規范形式（決議前導正負號并洗掉前導零），然后將其截斷為整數，

如果from引數與to引數一起使用，則它將標識要作為字串回傳的子字串范圍的開始，并且應小于to的值，

to

字串中子字串的編號，該字串終止由from引數啟動的范圍，回傳的字串包括from和to子字串，以及任何中間子字串和分隔它們的定界符， to引數必須與from一起使用，并且應大于from的值，

使用n（正整數）從字串開頭算起定界的子字串，使用*指定字串中最后一個定界的子字串，使用* -n通過從字串中最后一個帶分隔符的子字串向后偏移來計數帶分隔符的子字串，

僅對于SET $PIECE語法-* + n（星號后跟一個正數）指定要附加到字串末尾之外的子字串范圍的末尾，

  • 如果from小于to，則$PIECE回傳一個字串，該字串包括此范圍內的所有帶分隔符的子字串，包括from和to子字串，回傳的字串包含此范圍內的子字串和定界符，如果to大于分隔的子字串的數量，則回傳的字串包含從from子字串開始，一直到字串末尾的所有字串資料（子字串和定界符），
  • 如果from等于to，則$PIECE回傳from子字串，如果from和to是相同的值，或者是參考相同子字串的不同值，則可能發生這種情況，
  • 如果from大于to，為零（0），或者為空字串（“”），則$PIECE回傳一個空字串，

$PIECE將a轉換為標準格式（決議前導正負號并洗掉前導零），然后將其截斷為整數，

指定* -n和* + n引數值

使用變數指定* -n或* + n時，必須始終在引數本身中指定星號和符號字符，

以下是* -n的有效規格：

/// d ##class(PHA.TEST.Function).PIECE()
ClassMethod PIECE()
{
	SET count=2
	SET alph="a^b^c^d"
	WRITE $PIECE(alph,"^",*-count)
}


DHC-APP>d ##class(PHA.TEST.Function).PIECE()
b

/// d ##class(PHA.TEST.Function).PIECE1()
ClassMethod PIECE1()
{
	SET count=-2
	SET alph="a^b^c^d"
	WRITE $PIECE(alph,"^",*+count)
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE1()
b

以下是* + n的有效規范：

/// d ##class(PHA.TEST.Function).PIECE2()
ClassMethod PIECE2()
{
	SET count=2
	SET alph="a^b^c^d"
	SET $PIECE(alph,"^",*+count)="F"
	WRITE alph
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE2()
a^b^c^d^^F

這些引數值內允許使用空格，

示例：回傳帶分隔符的子字串

在下面的示例中，每個$PIECE回傳指定的子字串，該子字串由“，”定界符標識：

/// d ##class(PHA.TEST.Function).PIECE3()
ClassMethod PIECE3()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	WRITE $PIECE(colorlist,","),!     ; returns "Red" (substring 1) by default
	WRITE $PIECE(colorlist,",",3),!   ; returns "Blue" the third substring
	WRITE $PIECE(colorlist,",",*),!   ; returns "Black" the last substring
	WRITE $PIECE(colorlist,",",*-1),! ; returns "Orange" the next-to-last substring
}


DHC-APP>d ##class(PHA.TEST.Function).PIECE3()
Red
Blue
Black
Orange

在下面的示例中，$PIECE回傳數字的整數和小數部分：

/// d ##class(PHA.TEST.Function).PIECE4()
ClassMethod PIECE4()
{
	SET int=$PIECE(123.999,".")
	SET frac=$PIECE(123.999,".",*)
	WRITE "integer=",int," fraction =.",frac
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE4()
integer=123 fraction =.999

下面的示例回傳“Blue，Yellow，Orange”，即顏色串列中的第三到第五個子字串，用“，”分隔：

/// d ##class(PHA.TEST.Function).PIECE5()
ClassMethod PIECE5()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	SET extract=$PIECE(colorlist,",",3,5)
	WRITE extract
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE5()
Blue,Yellow,Orange

以下WRITE陳述句均回傳第一個子字串“123”，表明當from的值等于1時，這些格式是等效的：

/// d ##class(PHA.TEST.Function).PIECE6()
ClassMethod PIECE6()
{
	SET numlist="123#456#789"
	WRITE !,"2-arg=",$PIECE(numlist,"#")
	WRITE !,"3-arg=",$PIECE(numlist,"#",1)
	WRITE !,"4-arg=",$PIECE(numlist,"#",1,1)
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE6()
 
2-arg=123
3-arg=123
4-arg=123

在下面的示例中，兩個$PIECE函式都回傳整個字串字串，因為在字串中沒有出現定界符：

/// d ##class(PHA.TEST.Function).PIECE7()
ClassMethod PIECE7()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	SET extract1=$PIECE(colorlist,"#")
	SET extract2=$PIECE(colorlist,"#",1,4)
	WRITE "#   =",extract1,!,"#,1,4=",extract2
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE7()
#   =Red,Green,Blue,Yellow,Orange,Black
#,1,4=Red,Green,Blue,Yellow,Orange,Black

以下示例$PIECE從物件屬性回傳第二個子字串：

/// d ##class(PHA.TEST.Function).PIECE8()
ClassMethod PIECE8()
{
	SET tStatement = ##class(%SQL.Statement).%New()
	SET tStatement.%SchemaPath="MyTests,Sample,Cinema"
	WRITE "whole schema path: ",tStatement.%SchemaPath,!
	WRITE "2nd piece of schema path: ",$PIECE(tStatement.%SchemaPath,",",2),!
}


DHC-APP>d ##class(PHA.TEST.Function).PIECE8()
whole schema path: MyTests,Sample,Cinema
2nd piece of schema path: Sample

以下兩個示例使用更復雜的定界符，

本示例使用定界符字串“＃-＃”回傳字串numlist的三個子字串，此處，定界字串的組成字符“＃”和“-”可用作資料值；僅保留指定的字符序列（＃-＃）：

/// d ##class(PHA.TEST.Function).PIECE9()
ClassMethod PIECE9()
{
	SET numlist="1#2-3#-#45##6#-#789"
	WRITE !,$PIECE(numlist,"#-#",1)
	WRITE !,$PIECE(numlist,"#-#",2)
	WRITE !,$PIECE(numlist,"#-#",3)
}


DHC-APP>d ##class(PHA.TEST.Function).PIECE9()
 
1#2-3
45##6
789

下面的示例使用一個非ASCII分隔符（在本例中為pi的Unicode字符），該字符通過$CHAR函式指定，并通過連接運算子（_）插入到字串中：

/// d ##class(PHA.TEST.Function).PIECE10()
ClassMethod PIECE10()
{
	IF $SYSTEM.Version.IsUnicode()  {
		SET a = $CHAR(960)
		SET colorlist="Red"_a_"Green"_a_"Blue"
		SET extract1=$PIECE(colorlist,a)
		SET extract2=$PIECE(colorlist,a,2)
		SET extract3=$PIECE(colorlist,a,2,3)
		WRITE extract1,!,extract2,!,extract3
	} ELSE {
		WRITE "此示例需要Caché的Unicode安裝"
	}
}


DHC-APP>d ##class(PHA.TEST.Function).PIECE10()
Red
Green
GreenπBlue

使用SET $PIECE替換子字串

使用SET命令進行分配時，可以在等號的左側和右側使用$PIECE，在等號左側使用時，$PIECE指定要由分配的值替換的子字串，

當$PIECE與等號左側的SET一起使用時，字串可以是有效的變數名，如果該變數不存在，則SET $PIECE對其進行定義，字串引數也可以是多維屬性參考，它不能是非多維物件屬性，嘗試在非多維物件屬性上使用SET $PIECE會導致<OBJECT DISPATCH>錯誤，

在這種情況下，$PIECE（以及$LIST和$EXTRACT）的使用不同于其他標準函式，因為它修改了一個現有值，而不是僅僅回傳一個值，如果函式使用相對偏移語法，則不能將SET（a，b，c，...）= value語法與等號左邊的$PIECE（或$LIST或$EXTRACT）一起使用：*表示結尾一個字串，*-n或* + n代表距字串末尾的相對偏移量，必須改為使用SET a = value，b = value，c = value，…語法，

示例：替換分隔的子字串

以下示例將顏色串列的值更改為"Magenta,Green,Cyan,Yellow,Orange,Black":

/// d ##class(PHA.TEST.Function).PIECE11()
ClassMethod PIECE11()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	WRITE colorlist,!
	SET $PIECE(colorlist,",",1)="Magenta"
	WRITE colorlist,!
	SET $PIECE(colorlist,",",*-3)="Cyan"
	WRITE colorlist,!
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE11()
Red,Green,Blue,Yellow,Orange,Black
Magenta,Green,Blue,Yellow,Orange,Black
Magenta,Green,Cyan,Yellow,Orange,Black

當然，替換子字串可以比原始子字串長或短，并且可以包括定界符：

/// d ##class(PHA.TEST.Function).PIECE12()
ClassMethod PIECE12()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	WRITE colorlist,!
	SET $PIECE(colorlist,",",3)="Turquoise,Aqua,Teal"
	WRITE colorlist,!
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE12()
Red,Green,Blue,Yellow,Orange,Black
Red,Green,Turquoise,Aqua,Teal,Yellow,Orange,Black

如果指定了from和to引數，則將包含的子字串替換為指定的值，在這種情況下，是第4到第6個定界子字串：

/// d ##class(PHA.TEST.Function).PIECE13()
ClassMethod PIECE13()
{
	SET colorlist="Red,Blue,Yellow,Green,Orange,Black"
	WRITE !,colorlist
	SET $PIECE(colorlist,",",4,6)="Yellow+Blue,Yellow+Red"
	WRITE !,colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE13()
 
Red,Blue,Yellow,Green,Orange,Black
Red,Blue,Yellow,Yellow+Blue,Yellow+Red

可以通過分隔的子字串計數（使用n）或從字串末尾的偏移量（使用* + n）追加一個或多個分隔的子字串， SET $PIECE根據需要附加其他定界符，以在指定位置附加定界的子字串，以下示例都將colorlist的值更改為“Green^Blue^^Red”，并使用額外的空字串分隔子字串進行填充：

/// d ##class(PHA.TEST.Function).PIECE14()
ClassMethod PIECE14()
{
	SET colorlist="Green^Blue"
	SET $PIECE(colorlist,"^",4)="Red"
	WRITE colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE14()
Green^Blue^^Red

/// d ##class(PHA.TEST.Function).PIECE15()
ClassMethod PIECE15()
{
	SET colorlist="Green^Blue"
	SET $PIECE(colorlist,"^",*+2)="Red"
	WRITE colorlist
}


DHC-APP>d ##class(PHA.TEST.Function).PIECE15()
Green^Blue^^Red

如果定界符未出現在字串中，則$PIECE會將字串視為單個片段，并執行與上述相同的替換，如果未指定from引數，則新值將替換原始字串：


/// d ##class(PHA.TEST.Function).PIECE16()
ClassMethod PIECE16()
{
	SET colorlist="Red,Green,Blue"
	WRITE colorlist,!
	SET $PIECE(colorlist,"^")="Purple^Orange"
	WRITE colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE16()
Red,Green,Blue
Purple^Orange

如果定界符未出現在字串中，并且from被指定為大于1的整數，則$PIECE將from-1定界符和提供的值附加到字串的末尾：

/// d ##class(PHA.TEST.Function).PIECE17()
ClassMethod PIECE17()
{
	SET colorlist="Red,Green,Blue"
	WRITE colorlist,!
	SET $PIECE(colorlist,"^",3)="Purple"
	WRITE colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE17()
Red,Green,Blue
Red,Green,Blue^^Purple

如果from表示字串開頭之前的位置，則Caché不執行任何操作：

/// d ##class(PHA.TEST.Function).PIECE18()
ClassMethod PIECE18()
{
	SET colorlist="Red,Green,Blue"
	WRITE colorlist,!
	SET $PIECE(colorlist,",",*-7)="Purple"
	WRITE colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE18()
Red,Green,Blue
Red,Green,Blue

如果from表示字串開頭之前的位置并提供to，則Caché將from視為位置1：

/// d ##class(PHA.TEST.Function).PIECE19()
ClassMethod PIECE19()
{
	SET colorlist="Red,Green,Blue"
	WRITE colorlist,!
	SET $PIECE(colorlist,",",*-7,1)="Purple"
	WRITE colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE19()
Red,Green,Blue
Purple,Green,Blue

初始化字串變數

在為字串變數賦值之前，不需要定義它，下面的示例將newvar初始化為字符模式“ >>>>>> TOTAL”：

DHC-APP>SET $PIECE(newvar,">",7)="TOTAL"
 
DHC-APP>WRITE newvar
>>>>>>TOTAL

分隔符為空字串

如果定界符為空字串，則無論from和to引數的值如何，新值都會替換原始字串，

以下兩個示例都將顏色串列設定為“Purple”：

/// d ##class(PHA.TEST.Function).PIECE20()
ClassMethod PIECE20()
{
	SET colorlist="Red,Green,Blue"
	WRITE !,colorlist
	SET $PIECE(colorlist,"")="Purple"
	WRITE !,colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE20()
 
Red,Green,Blue
Purple

/// d ##class(PHA.TEST.Function).PIECE21()
ClassMethod PIECE21()
{
	SET colorlist="Red,Blue,Yellow,Green,Orange,Black"
	WRITE !,colorlist
	SET $PIECE(colorlist,"",3,5)="Purple"
	WRITE !,colorlist
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE21()
 
Red,Blue,Yellow,Green,Orange,Black
Purple

引數超過32,768個字符的$PIECE

下面的示例創建一個由5個句點和一個null組成的字串：

/// d ##class(PHA.TEST.Function).PIECE22()
ClassMethod PIECE22()
{
	SET x=""
	SET $PIECE(x,".",6)=""
	WRITE x
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE22()
.....

現在考慮下面的示例，該示例創建一個32767的字串和一個null：

    SET x=""
    SET $PIECE(x,".",32768)=""

盡管從技術上講，它在字串的最大長度之內，但是如果未啟用長字串，則此示例將生成MAXSTRING>錯誤，默認情況下，長字串在系統范圍內啟用，如果希望將$PIECE與大于32,767個字符的引數一起使用，則可以使用Config.Miscellaneous類的EnableLongStrings屬性檢查或設定系統范圍的長字串設定，

注意

使用$PIECE解包資料值

$PIECE通常用于“解包”包含由分隔符分隔的多個欄位的資料值，典型的分隔符包括斜杠（/），逗號（，），空格（）和分號（;），以下樣本值是與$PIECE一起使用的良好候選者：

"John Jones/29 River St./Boston MA, 02095"
"Mumps;Measles;Chicken Pox;Diptheria"
"45.23,52.76,89.05,48.27"

$PIECE 與 $LENGTH

$LENGTH的兩個引數形式基于定界符回傳字串中子字串的數量，使用$LENGTH確定字串中子字串的數量，然后使用$PIECE提取單個子字串，如以下示例所示：

/// d ##class(PHA.TEST.Function).PIECE24()
ClassMethod PIECE24()
{
	SET sentence="The quick brown fox jumped over the lazy dog's back."
	SET delim=" "
	SET countdown=$LENGTH(sentence,delim)
	SET countup=1
	FOR reps=countdown:-1:1 {
		SET extract=$PIECE(sentence,delim,countup)
		WRITE !,countup," ",extract
		SET countup=countup+1
	}
	WRITE !,"All done!"
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE24()
 
1 The
2 quick
3 brown
4 fox
5 jumped
6 over
7 the
8 lazy
9 dog's
10 back.
All done!

Null Values

$PIECE不會區分帶有空字串值的帶分隔符的子字串和不存在的子字串，兩者都回傳一個空字串值，例如，下面的示例均回傳from值7的空字串：

/// d ##class(PHA.TEST.Function).PIECE25()
ClassMethod PIECE25()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	SET extract1=$PIECE(colorlist,",",6)
	SET extract2=$PIECE(colorlist,",",7)
	WRITE "6=",extract1,!,"7=",extract2
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE25()
6=Black
7=

/// d ##class(PHA.TEST.Function).PIECE26()
ClassMethod PIECE26()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black,"
	SET extract1=$PIECE(colorlist,",",6)
	SET extract2=$PIECE(colorlist,",",7)
	WRITE "6=",extract1,!,"7=",extract2
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE26()
6=Black
7=

在第一種情況下，沒有第七個子字串；回傳一個空字串，在第二種情況下，有第七個子字串，如字串末尾的定界符所指示；該第七個子字串的值是空字串，

下面的示例顯示字串中的空值，它提取子字串1和3，這些子字串存在，但都包含一個空字串， （子字串1定義為第一個定界符之前的字串）：

/// d ##class(PHA.TEST.Function).PIECE27()
ClassMethod PIECE27()
{
	SET colorlist=",Red,,Blue,"
	SET extract1=$PIECE(colorlist,",")
	SET extract3=$PIECE(colorlist,",",3)
	WRITE !,"sub1=",extract1,!,"sub3=",extract3
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE27()
 
sub1=
sub3=

以下示例還回傳一個空字串，因為指定的子字串不存在：

/// d ##class(PHA.TEST.Function).PIECE28()
ClassMethod PIECE28()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	SET extract=$PIECE(colorlist,",",0)
	WRITE !,"Length=",$LENGTH(extract),!,"Value=",extract
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE28()
 
Length=0
Value=

/// d ##class(PHA.TEST.Function).PIECE29()
ClassMethod PIECE29()
{
	SET colorlist="Red,Green,Blue,Yellow,Orange,Black"
	SET extract=$PIECE(colorlist,",",8,20)
	WRITE !,"Length=",$LENGTH(extract),!,"Value=",extract
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE29()
 
Length=0
Value=

強制數值計算

在$PIECE（或任何ObjectScript函式）前加一元+號可強制對回傳值進行數值計算，它以規范形式回傳數字子字串，它回傳一個非數字子字串為0，它回傳一個混合數字子字串的前導數字部分，對于空字串值或不存在的子字串，它將回傳0，

/// d ##class(PHA.TEST.Function).PIECE30()
ClassMethod PIECE30()
{
	SET str="snow white,7dwarves,+007.00,99.90,,-0,"
	WRITE "Substrings:",!
	FOR i=1:1:7 {WRITE i,"=",$PIECE(str,",",i)," "}
	WRITE !,"Forced Numerics:",!
	FOR i=1:1:7 {WRITE i,"=",+$PIECE(str,",",i)," "}
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE30()
Substrings:
1=snow white 2=7dwarves 3=+007.00 4=99.90 5= 6=-0 7=
Forced Numerics:
1=0 2=7 3=7 4=99.9 5=0 6=0 7=0

嵌套$PIECE操作

要執行復雜的提取，可以將 $PIECE參考彼此嵌套，內部$PIECE回傳一個由外部$PIECE操作的子字串，每個$PIECE使用其自己的定界符，例如，以下回傳狀態縮寫“MA”：

/// d ##class(PHA.TEST.Function).PIECE31()
ClassMethod PIECE31()
{
	SET patient="John Jones/29 River St./Boston MA 02095"
	SET patientstateaddress=$PIECE($PIECE(patient,"/",3)," ",2)
	WRITE patientstateaddress
}

DHC-APP>d ##class(PHA.TEST.Function).PIECE31()
MA

以下是使用定界符層次結構嵌套$PIECE操作的另一個示例，首先，內部$PIECE使用脫字符號（^）分隔符查找第二個嵌套串列：“A，B，C”，然后，外部$PIECE使用逗號（，）分隔符回傳子字串“A，B，C”的第一部分和第二部分（“A，B”）：

/// d ##class(PHA.TEST.Function).PIECE32()
ClassMethod PIECE32()
{
	SET nestlist="1,2,3^A,B,C^@#!"
	WRITE $PIECE($PIECE(nestlist,"^",2),",",1,2)
}

DHC-APP> d ##class(PHA.TEST.Function).PIECE32()
A,B

$PIECE與$EXTRACT和$LIST的比較

$PIECE通過計算字串中用戶定義的定界符來確定子字串， $PIECE將包含要用作定界符的一個或多個字符實體的普通字串作為輸入，

$EXTRACT通過從字串開頭計數字符來確定子字串， $EXTRACT將普通字串作為輸入，

$LIST通過從串列的開頭計數元素（而非字符）來確定編碼串列中的元素， $LIST函式無需使用指定的分隔符即可指定子字串，如果預留定界符或字符序列不適合資料型別（例如，位串資料），則應使用$LISTBUILD和$LIST函式存盤和檢索子串，可以使用$LISTFROMSTRING函式將定界字串轉換為串列，可以使用$LISTTOSTRING函式將串列轉換為定界字串，

$PIECE和$LIST函式使用的資料存盤策略不兼容，因此不應將其結合使用，例如，嘗試在使用$LISTBUILD創建的串列上使用$PIECE會產生不可預測的結果，應避免使用，

轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/168734.html

標籤：其他

上一篇：mysql資料庫主從同步中斷的各種情況

下一篇：mysql 計算時間函式差

標籤雲
其他(157675) Python(38076) JavaScript(25376) Java(17977) C(15215) 區塊鏈(8255) C＃(7972) AI(7469) 爪哇(7425) MySQL(7132) html(6777) 基礎類(6313) sql(6102) 熊猫(6058) PHP(5869) 数组(5741) R(5409) Linux(5327) 反应(5209) 腳本語言(PerlPython)(5129) 非技術區(4971) Android(4554) 数据框(4311) css(4259) 节点.js(4032) C語言(3288) json(3245) 列表(3129) 扑(3119) C++語言(3117) 安卓(2998) 打字稿(2995) VBA(2789) Java相關(2746) 疑難問題(2699) 细绳(2522) 單片機工控(2479) iOS(2429) ASP.NET(2402) MongoDB(2323) 麻木的(2285) 正则表达式(2254) 字典(2211) 循环(2198) 迅速(2185) 擅长(2169) 镖(2155) 功能(1967) .NET技术(1958) Web開發(1951) python-3.x(1918) HtmlCss(1915) 弹簧靴(1913) C++(1909) xml(1889) PostgreSQL(1872) .NETCore(1853) 谷歌表格(1846) Unity3D(1843) for循环(1842)

熱門瀏覽
  • 網閘典型架構簡述

    網閘架構一般分為兩種：三主機的三系統架構網閘和雙主機的2+1架構網閘。 三主機架構分別為內端機、外端機和仲裁機。三機無論從軟體和硬體上均各自獨立。首先從硬體上來看，三機都用各自獨立的主板、記憶體及存盤設備。從軟體上來看，三機有各自獨立的作業系統。這樣能達到完全的三機獨立。對于“2+1”系統，“2”分為 ......

    uj5u.com 2020-09-10 02:00:44 more
  • 如何從xshell上傳檔案到centos linux虛擬機里

    如何從xshell上傳檔案到centos linux虛擬機里及：虛擬機CentOs下執行 yum -y install lrzsz命令，出現錯誤：鏡像無法找到軟體包 前言 一、安裝lrzsz步驟 二、上傳檔案 三、遇到的問題及解決方案 總結 前言 提示：其實很簡單，往虛擬機上安裝一個上傳檔案的工具 ......

    uj5u.com 2020-09-10 02:00:47 more
  • 一、SQLMAP入門

    一、SQLMAP入門 1、判斷是否存在注入 sqlmap.py -u 網址/id=1 id=1不可缺少。當注入點后面的引數大于兩個時。需要加雙引號， sqlmap.py -u "網址/id=1&uid=1" 2、判斷文本中的請求是否存在注入 從文本中加載http請求，SQLMAP可以從一個文本檔案中 ......

    uj5u.com 2020-09-10 02:00:50 more
  • Metasploit 簡單使用教程

    metasploit 簡單使用教程 浩先生， 2020-08-28 16:18:25 分類專欄： kail 網路安全 linux 文章標簽： linux資訊安全 編輯 著作權 metasploit 使用教程 前言 一、Metasploit是什么？ 二、準備作業 三、具體步驟 前言 Msfconsole ......

    uj5u.com 2020-09-10 02:00:53 more
  • 游戲逆向之驅動層與用戶層通訊

    驅動層代碼： #pragma once #include <ntifs.h> #define add_code CTL_CODE(FILE_DEVICE_UNKNOWN,0x800,METHOD_BUFFERED,FILE_ANY_ACCESS) /* 更多游戲逆向視頻www.yxfzedu.com ......

    uj5u.com 2020-09-10 02:00:56 more
  • 北斗電力時鐘（北斗授時服務器）讓網路資料更精準

    北斗電力時鐘（北斗授時服務器）讓網路資料更精準 北斗電力時鐘（北斗授時服務器）讓網路資料更精準 京準電子科技官微——ahjzsz 近幾年，資訊技術的得了快速發展，互聯網在逐漸普及，其在人們生活和生產中都得到了廣泛應用，并且取得了不錯的應用效果。計算機網路資訊在電力系統中的應用，一方面使電力系統的運行 ......

    uj5u.com 2020-09-10 02:01:03 more
  • 【CTF】CTFHub 技能樹 彩蛋 writeup

    ?碎碎念 CTFHub：https://www.ctfhub.com/ 筆者入門CTF時時剛開始刷的是bugku的舊平臺，后來才有了CTFHub。 感覺不論是網頁UI設計，還是題目質量，賽事跟蹤，工具軟體都做得很不錯。 而且因為獨到的金幣制度的確讓人有一種想去刷題賺金幣的感覺。 個人還是非常喜歡這個 ......

    uj5u.com 2020-09-10 02:04:05 more
  • 02windows基礎操作

    我學到了一下幾點 Windows系統目錄結構與滲透的作用 常見Windows的服務詳解 Windows埠詳解 常用的Windows注冊表詳解 hacker DOS命令詳解（net user / type /md /rd/ dir /cd /net use copy、批處理 等） 利用dos命令制作 ......

    uj5u.com 2020-09-10 02:04:18 more
  • 03.Linux基礎操作

    我學到了以下幾點 01Linux系統介紹02系統安裝，密碼啊破解03Linux常用命令04LAMP 01LINUX windows： win03 8 12 16 19 配置不繁瑣 Linux：redhat,centos(紅帽社區版)，Ubuntu server,suse unix:金融機構，證券，銀 ......

    uj5u.com 2020-09-10 02:04:30 more
  • 05HTML

    01HTML介紹 02頭部標簽講解03基礎標簽講解04表單標簽講解 HTML前段語言 js1.了解代碼2.根據代碼 懂得挖掘漏洞 （POST注入/XSS漏洞上傳）3.黑帽seo 白帽seo 客戶網站被黑帽植入劫持代碼如何處理4.熟悉html表單 <html><head><title>TDK標題，描述 ......

    uj5u.com 2020-09-10 02:04:36 more
最新发布
  • 2023年最新微信小程式抓包教程

    01 開門見山 隔一個月發一篇文章，不過分。 首先回顧一下《微信系結手機號資料庫被脫庫事件》，我也是第一時間得知了這個訊息，然后跟蹤了整件事情的經過。下面是這起事件的相關截圖以及近日流出的一萬條資料樣本： 個人認為這件事也沒什么，還不如關注一下之前45億快遞資料查詢渠道疑似在近日復活的訊息。 訊息是 ......

    uj5u.com 2023-04-20 08:48:24 more
  • web3 產品介紹：metamask 錢包 使用最多的瀏覽器插件錢包

    Metamask錢包是一種基于區塊鏈技術的數字貨幣錢包，它允許用戶在安全、便捷的環境下管理自己的加密資產。Metamask錢包是以太坊生態系統中最流行的錢包之一，它具有易于使用、安全性高和功能強大等優點。 本文將詳細介紹Metamask錢包的功能和使用方法。 一、 Metamask錢包的功能 數字資 ......

    uj5u.com 2023-04-20 08:47:46 more
  • vulnhub_Earth

    前言 靶機地址->>>vulnhub_Earth 攻擊機ip：192.168.20.121 靶機ip：192.168.20.122 參考文章 https://www.cnblogs.com/Jing-X/archive/2022/04/03/16097695.html https://www.cnb ......

    uj5u.com 2023-04-20 07:46:20 more
  • 從4k到42k，軟體測驗工程師的漲薪史，給我看哭了

    清明節一過，盲猜大家已經無心上班，在數著日子準備過五一，但一想到銀行卡里的余額……瞬間心情就不美麗了。最近，2023年高校畢業生就業調查顯示，本科畢業月平均起薪為5825元。調查一出，便有很多同學表示自己又被平均了。看著這一資料，不免讓人想到前不久中國青年報的一項調查：近六成大學生認為畢業10年內會 ......

    uj5u.com 2023-04-20 07:44:00 more
  • 最新版本 Stable Diffusion 開源 AI 繪畫工具之中文自動提詞篇

    🎈 標簽生成器 由于輸入正向提示詞 prompt 和反向提示詞 negative prompt 都是使用英文，所以對學習母語的我們非常不友好 使用網址：https://tinygeeker.github.io/p/ai-prompt-generator 這個網址是為了讓大家在使用 AI 繪畫的時候 ......

    uj5u.com 2023-04-20 07:43:36 more
  • 漫談前端自動化測驗演進之路及測驗工具分析

    隨著前端技術的不斷發展和應用程式的日益復雜，前端自動化測驗也在不斷演進。隨著 Web 應用程式變得越來越復雜，自動化測驗的需求也越來越高。如今，自動化測驗已經成為 Web 應用程式開發程序中不可或缺的一部分，它們可以幫助開發人員更快地發現和修復錯誤，提高應用程式的性能和可靠性。 ......

    uj5u.com 2023-04-20 07:43:16 more
  • CANN開發實踐：4個DVPP記憶體問題的典型案例解讀

    摘要：由于DVPP媒體資料處理功能對存放輸入、輸出資料的記憶體有更高的要求（例如，記憶體首地址128位元組對齊），因此需呼叫專用的記憶體申請介面，那么本期就分享幾個關于DVPP記憶體問題的典型案例，并給出原因分析及解決方法。 本文分享自華為云社區《FAQ_DVPP記憶體問題案例》，作者：昇騰CANN。 DVPP ......

    uj5u.com 2023-04-20 07:43:03 more
  • msf學習

    msf學習 以kali自帶的msf為例 一、msf核心模塊與功能 msf模塊都放在/usr/share/metasploit-framework/modules目錄下 1、auxiliary 輔助模塊，輔助滲透（埠掃描、登錄密碼爆破、漏洞驗證等） 2、encoders 編碼器模塊，主要包含各種編碼 ......

    uj5u.com 2023-04-20 07:42:59 more
  • Halcon軟體安裝與界面簡介

    1. 下載Halcon17版本到到本地 2. 雙擊安裝包后 3. 步驟如下 1.2 Halcon軟體安裝 界面分為四大塊 1. Halcon的五個助手 1) 影像采集助手：與相機連接，設定相機引數，采集影像 2) 標定助手：九點標定或是其它的標定，生成標定檔案及內參外參，可以將像素單位轉換為長度單位 ......

    uj5u.com 2023-04-20 07:42:17 more
  • 在MacOS下使用Unity3D開發游戲

    第一次發博客，先發一下我的游戲開發環境吧。 去年2月份買了一臺MacBookPro2021 M1pro(以下簡稱mbp)，這一年來一直在用mbp開發游戲。我大致分享一下我的開發工具以及使用體驗。 1、Unity 官網鏈接： https://unity.cn/releases 我一般使用的Apple ......

    uj5u.com 2023-04-20 07:40:19 more

Copyright © 2010-2020 有解無憂