一、設計目標

前一陣子偶然接觸到點燈科技平臺，產生了制作一塊ESP8266電路板，擁有以下功能：

1. 使用CH340對ESP8266進行程式下載
2. 使用DHT11進行溫濕度資料讀取
3. 使用點燈科技平臺接入物聯網，可通過手機APP獲得室內溫濕度
4. 接入小愛同學，通過語音獲取室內溫濕度資訊
5. Mico USB 5V供電
6. 0.96OLED進行資料顯示
7. 2按鍵進行畫面切換
8. 多余IO口引出備用
   

二、電路展示

三、存在的問題

電路板在制作的程序中比較匆忙，忽視了ESP8266 HSPI引腳難以復用的問題，錯誤地將其用于0.96寸OLED會導致該OLED無法顯示，說明要驅動0.96寸OLED需通過普通IO口連接，同時這個設計也反應出ESP8266 IO口不足的問題，因此OLED顯示和按鍵控制先擱置，目前僅實作物聯網功能，通過點燈科技平臺接入,以及通過小愛同學語音獲取室內溫濕度資料，

四、代碼

#define BLINKER_PRINT Serial
#define BLINKER_WIFI
#define BLINKER_MIOT_SENSOR

#include <Blinker.h>
#include <dht11.h>

dht11 DHT11;

char auth[] = "************";//設備號，由點燈平臺獲得
char ssid[] = "********";//無線賬號
char pswd[] = "********";//無線密碼

// 新建組件物件
BlinkerButton Button1("LED_Button");
BlinkerNumber HUM("hum");
BlinkerNumber TEMP("temp");

// 設定 DHT 引腳 為 Pin 16
#define DHT11PIN 16
//心跳包
void heartbeat()
{
    //DHT11.read(DHT11PIN);
    HUM.print((float)DHT11.humidity);
    TEMP.print((float)DHT11.temperature);
}
// 按下按鍵即會執行該函式
void button1_callback(const String & state) {
    BLINKER_LOG("get button state: ", state);
    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    if(digitalRead(LED_BUILTIN)==1)
    {
      Button1.print("off");
     }
     else
     {
       Button1.print("on");
      }
}
//云存盤溫濕度資料函式
void dataStorage()
{
    Blinker.dataStorage("temp_chart", (float)DHT11.temperature);//存盤溫度
    Blinker.dataStorage("hum_chart", (float)DHT11.humidity);//存盤濕度
}
// 如果未系結的組件被觸發，則會執行其中內容
void dataRead(const String & data)
{
    BLINKER_LOG("Blinker readString: ", data);

}
//小愛同學處理函式
void miotQuery(int32_t queryCode)
{
    BLINKER_LOG("MIOT Query codes: ", queryCode);
    
    switch (queryCode)
    {
        
        case BLINKER_CMD_QUERY_HUMI_NUMBER :
            BLINKER_LOG("MIOT Query HUMI");
            BlinkerMIOT.humi(DHT11.humidity);
            BlinkerMIOT.print();
            break;
        case BLINKER_CMD_QUERY_TEMP_NUMBER :
            BLINKER_LOG("MIOT Query TEMP");
            BlinkerMIOT.temp(DHT11.temperature);
            BlinkerMIOT.print();
            break;
       case BLINKER_CMD_QUERY_ALL_NUMBER :
            BLINKER_LOG("MIOT Query All");
            BlinkerMIOT.temp(DHT11.temperature);
            BlinkerMIOT.humi(DHT11.humidity);
            BlinkerMIOT.print();
            break;
        default :
            BlinkerMIOT.temp(20);
            BlinkerMIOT.humi(20);
            //BlinkerMIOT.pm25(20);
            //BlinkerMIOT.co2(20);
            BlinkerMIOT.print();
            break;
    }
}

void setup() {
    // 初始化串口
    Serial.begin(115200);

    #if defined(BLINKER_PRINT)
        BLINKER_DEBUG.stream(BLINKER_PRINT);
    #endif

    // 初始化有LED的IO
    pinMode(LED_BUILTIN, OUTPUT);
    digitalWrite(LED_BUILTIN, HIGH);

    // 初始化blinker
    Blinker.begin(auth, ssid, pswd);
    Blinker.attachData(dataRead);
    Button1.attach(button1_callback);//按鍵
    Blinker.attachHeartbeat(heartbeat);//心跳包
    Blinker.attachDataStorage(dataStorage);//圖表
    //小愛回呼函式
    BlinkerMIOT.attachQuery(miotQuery);
}

void loop() {
    DHT11.read(DHT11PIN);
    Blinker.run();
}

DHT11溫濕度傳感器庫檔案：https://download.csdn.net/download/weixin_43278295/15352131 解壓至檔案中arduino檔案夾下的libraries中即可，

五、需要注意的問題

新的ESP8266芯片首次燒寫代碼時需串口連接后手動將GPIO0電平拉低，再按下RST鍵完成燒寫，之后的燒寫就無須手動拉低了，直接串口下載即可，本人第一次燒寫代碼一直燒寫失敗，一度懷疑是串口下載電路設計上出現問題，
ESP8266接收的命令需與云端（手機APP端）下發的命令一致，才能進行執行，所以在設定點燈APP時需注意代碼中的接收命令與云端下發命令要一一對應，詳細教程可根據點燈科技官方教程學習，本文提供的是溫濕度計手機端控制和小愛童鞋語音控制的專案整合，
根據以上代碼，上電后ESP8266接入無線，在手機上的點燈APP中可看到設備在線，可獲得溫濕度資料并對ESP8266板載LED進行開關燈操作，可通過小愛同學語音獲得室內溫濕度資料，
不足之處還望各位大佬不吝賜教！