核心思想

學會忘記所有輸入法的狀態

為你的常用程式分別設定初始狀態

每次切換回來

默默自動初始化中文 / 英文輸入法狀態

然后你要做的

就是直接開始敲鍵盤

忘記它的的狀態

為了達到這個目的，我們只實作需要一個簡單的介面：

設定當前輸入法的函式為 EN / 中文

然后呢，我們從哪些場景開始動手改造呢？

? 1. 快捷鍵切換程式（鍵盤點名）

; 激活或運行, 默認值為英文輸入法（如需中文，再加逗號和 "中文" 要包含雙引號）
activateOrRun(title, exe_path, language:="EN"){
    if WinExist(title) {
        WinActivate
    }
    else {
        Run exe_path 
    }
    setIME(language) ; 默認以小寫開始
}

呼叫范例

CapsLock & v:: 
    activateOrRun("ahk_exe Code.exe", "D:\TOOLS\Microsoft VS Code\Code.exe")
    setIME("EN")
return

🖱 2. 滑鼠左鍵單擊視窗（滑鼠點名）

滑鼠單擊時，獲取當前視窗的行程名字，如果包含 IDE ，則切換為英文，

setIDEIME(language:="EN")
{
    MouseGetPos , , ahkId
    title := WinGetProcessName(ahkId)
    ToolTip title
    if InStr(title, "idea64.exe") or InStr(title, "Code.exe")
    {
        setIME("EN")
    }
}

系結到滑鼠單擊事件

~LButton::
{
    setIDEIME("EN")
}

~LButton up::
{
    Sleep 1000
    ToolTip
}

🧚🏻?♂? 3. IDE 寫代碼與寫注釋切換（Vim 痛骨貼）

Idea激活時，以下背景關系管理的代碼優先級最高（覆寫舊方法）

;=====================================================================o
#Hotif WinActive("ahk_exe idea64.exe")
;---------------------------------------------------------------------o
; VIM 敏感: 在中文注釋、普通模式和插入模式的邊界，自動切換輸入法
:*b0:o// ::
:*b0:a// ::
:*b0:i// ::
:*b0:// ::
{
    setIME("中文")
}
#HotIf
;---------------------------------------------------------------------o

;=====================================================================o
#Hotif WinActive("ahk_exe idea64.exe") or WinActive("ahk_exe Code.exe")
;---------------------------------------------------------------------o
; VIM 敏感: 在中文注釋、普通模式和插入模式的邊界，自動切換輸入法
CapsLock::
Esc::
{
    Send "{Esc}"
    setIME("EN")
}
#HotIf
;---------------------------------------------------------------------o

;=====================================================================o
#Hotif WinActive("ahk_exe Code.exe")
;---------------------------------------------------------------------o
; VIM 敏感: 在中文注釋、普通模式和插入模式的邊界，自動切換輸入法
:*b0:o; ::
:*b0:a; ::
:*b0:i; ::
:*b0:; ::
{
    setIME("中文")
}
#Hotif
;---------------------------------------------------------------------o

🤔 4. 莫名其妙不知身在何處（基礎介面）

RShift ：短按切換中英文輸入法，長按仍舊上檔鍵

;=====================================================================o
;                    IME Status Utils
;---------------------------------------------------------------------o
; 功能：短按切換中英文輸入法，長按仍舊上檔鍵
; 作者：知乎 @查理
; 時間：2021年9月
; 更新：https://www.zhihu.com/question/470805790/answer/2022570065
;---------------------------------------------------------------------o
~$RShift:: return
~$RShift up:: switchIME()
;---------------------------------------------------------------------o
switchIME()
{
    timeInterval := 50  ; 此數值96次測驗，大于50則短按穩定, 變數放函式之外可能會被污染
    if (A_TimeSincePriorHotkey > timeInterval && A_PriorKey = "RShift") {
        ToolTip
        if (hasIME() = 1) {
            Send "^{Space}"
            ToolTip "EN" ; Shift得反著提示，提示切換后的狀態，
        } else {
            Send "^{Space}"
            ToolTip "中"
        }
        Sleep 1000
        ToolTip
    }
}
;---------------------------------------------------------------------o
setIME(language)
{
    Sleep 50 ; 等一等是為了承接視窗切換的緩沖
    if language == "中文" {
        if (hasIME() = 0) {
            Send "^{Space}"
            ToolTip "中"
        }
    } else if language == "EN" {
        if (hasIME() = 1) {
            Send "^{Space}"
            ToolTip "EN"
        }
    }
    setCaspsLockState "Off"
    Sleep 250 ; 懸浮提示（如有）0.25 秒后消失
    ToolTip
}
;---------------------------------------------------------------------o
; IMEの狀態の取得
;   対象： AHK v2.0.0以升
;   WinTitle : 対象Window (省略時:アクティブウィンドウ)
;   戻り値  1:ON 0:OFF
;---------------------------------------------------------------------o
hasIME(WinTitle:="A")
{
    try {
        hWnd := WinGetID(WinTitle)
    } catch (e) {
        ; ^Esc 開始選單彈窗，會卡死在找不到當前視窗
        return
    }
    DetectHiddenWindows True
    result := SendMessage(
            0x283,  ; Message : WM_IME_CONTROL
            0x005,  ; wParam  : IMC_GETOPENSTATUS
            0,      ; lParam  ： (NoArgs)
            ,       ; Control ： (Window)
            "ahk_id " DllCall( "imm32\ImmGetDefaultIMEWnd", "Uint", hWnd, "Uint")
            )
    DetectHiddenWindows False
    ; 1 非英文狀態
    ; 0 英文狀態
    return result
}

根據二八定律，我們常用軟體就只有兩個，

你需要用的，你不得不用的，

😘 autohotkey V2