文章目錄
文章目錄
- 文章目錄
- 一、了解串口通信及準備作業
- 1.串口通信簡介
- 2.STM32 的 USART 簡介
- 二、程式撰寫輸出Hello Windows
- 三、結果
- 總結
一、了解串口通信及準備作業
1.串口通信簡介
代碼如下（示例）：
串行通訊是指設備之間通過少量資料信號線，地線以及控制信號線，按資料位形式一位一位地傳輸資料的通訊方式，
分類
單工：資料傳輸只支持資料在一個方向上傳輸，
半雙工：允許資料在兩個方向上傳輸，但同一時刻只允許資料在一個方向上傳輸，它實際上是一種能夠切換方向的單工通信，不需要獨立的接收端和發送端，兩者可以合并使用一個埠，
全雙工：允許資料同時在兩個方向上傳輸，因此全雙工通信是兩個單工通信方式的結合，需要獨立的接收端和發送端，
2.STM32 的 USART 簡介
通用同步異步收發器(Universal Synchronous Asynchronous Receiver and Transmitter)是一個串行通信設備，可以靈活地與外部設備進行全雙工資料交換，有別于 USART 還有一個UART(Universal Asynchronous Receiver and Transmitter)，它是在 USART 基礎上裁剪掉了同步通信功能，只有異步通信，簡單區分同步和異步就是看通信時需不需要對外提供時鐘輸
出，我們平時用的串口通信基本都是 UART，
說明：
任何USART雙向通信至少需要兩個引腳：接收資料輸入(RX)和發送資料輸出(TX)，
RX：接收資料串行輸入，通過過采樣技術來區別資料和噪音，從而恢復資料，
TX：發送資料串行輸出，當發送器被禁止時，輸出引腳恢復到它的I/O埠配置，當發送器被激活且不發送資料時，TX引腳處于高電平，在單線和智能卡模式里，此I/O口被同時用于資料的發送和接收，
SCLK：發送器時鐘輸出，此引腳輸出用于同步傳輸的時鐘， (在Start位和Stop位上沒有時鐘脈沖，軟體可選地，可以在最后一個資料位送出一個時鐘脈沖)，資料可以在RX上同步被接收，這可以用來控制帶有移位暫存器的外部設備(例如LCD驅動器)，時鐘相位和極性都是軟體可編程的，在智能卡模式里，CK可以為智能卡提供時鐘，
在IrDA模式里需要下列引腳：
IrDA_RDI: IrDA模式下的資料輸入，
IrDA_TDO: IrDA模式下的資料輸出，
在硬體流控模式里需要下列引腳：
nCTS: 清除發送，若是高電平，在當前資料傳輸結束時阻斷下一次的資料發送，
nRTS: 發送請求，若是低電平，表明USART準備好接收資料
STM32F103VET6 系統控制器有三個 USART 和兩個 UART，UART(通用異步收發器)只是異步傳輸功能，所以沒有 SCLK、nCTS 和 nRTS 功能引腳，
二、程式撰寫輸出Hello Windows
1.實驗要求
- 設定波特率為115200，1位停止位，無校驗位，
- STM32給上位機（win10）連續發送hello Windows，上位機接收程式使用“串口除錯助手“，
- 當上位機給stm32發送Stop，stm32后，stm32停止發送，
2.實驗原理 - 串口接收
由于前面已經配置好了stm32的串口1中斷，因此當上位機給stm32發送資料時就會觸發該中斷進入中斷處理函式USART1_IRQHandler()接收資料并保存到接受資料緩沖區， - 串口發送
當串口接收完資料并存盤到接受資料緩沖區后，主程式就將該緩沖區中的資料按位放到發送資料緩沖區中并發送出去，由上位機的串口除錯助手顯示stm32發送出來的資料，
創建新專案
選擇對應芯片
在這里不要勾選 直接OK
在檔案夾下新建hello Windows.s檔案：
撰寫代碼:
;RCC暫存器地址映像
RCC_BASE EQU 0x40021000
RCC_CR EQU (RCC_BASE + 0x00)
RCC_CFGR EQU (RCC_BASE + 0x04)
RCC_CIR EQU (RCC_BASE + 0x08)
RCC_APB2RSTR EQU (RCC_BASE + 0x0C)
RCC_APB1RSTR EQU (RCC_BASE + 0x10)
RCC_AHBENR EQU (RCC_BASE + 0x14)
RCC_APB2ENR EQU (RCC_BASE + 0x18)
RCC_APB1ENR EQU (RCC_BASE + 0x1C)
RCC_BDCR EQU (RCC_BASE + 0x20)
RCC_CSR EQU (RCC_BASE + 0x24)
;AFIO暫存器地址映像
AFIO_BASE EQU 0x40010000
AFIO_EVCR EQU (AFIO_BASE + 0x00)
AFIO_MAPR EQU (AFIO_BASE + 0x04)
AFIO_EXTICR1 EQU (AFIO_BASE + 0x08)
AFIO_EXTICR2 EQU (AFIO_BASE + 0x0C)
AFIO_EXTICR3 EQU (AFIO_BASE + 0x10)
AFIO_EXTICR4 EQU (AFIO_BASE + 0x14)
;GPIOA暫存器地址映像
GPIOA_BASE EQU 0x40010800
GPIOA_CRL EQU (GPIOA_BASE + 0x00)
GPIOA_CRH EQU (GPIOA_BASE + 0x04)
GPIOA_IDR EQU (GPIOA_BASE + 0x08)
GPIOA_ODR EQU (GPIOA_BASE + 0x0C)
GPIOA_BSRR EQU (GPIOA_BASE + 0x10)
GPIOA_BRR EQU (GPIOA_BASE + 0x14)
GPIOA_LCKR EQU (GPIOA_BASE + 0x18)
;GPIO C口控制
GPIOC_BASE EQU 0x40011000
GPIOC_CRL EQU (GPIOC_BASE + 0x00)
GPIOC_CRH EQU (GPIOC_BASE + 0x04)
GPIOC_IDR EQU (GPIOC_BASE + 0x08)
GPIOC_ODR EQU (GPIOC_BASE + 0x0C)
GPIOC_BSRR EQU (GPIOC_BASE + 0x10)
GPIOC_BRR EQU (GPIOC_BASE + 0x14)
GPIOC_LCKR EQU (GPIOC_BASE + 0x18)
;串口1控制
USART1_BASE EQU 0x40013800
USART1_SR EQU (USART1_BASE + 0x00)
USART1_DR EQU (USART1_BASE + 0x04)
USART1_BRR EQU (USART1_BASE + 0x08)
USART1_CR1 EQU (USART1_BASE + 0x0c)
USART1_CR2 EQU (USART1_BASE + 0x10)
USART1_CR3 EQU (USART1_BASE + 0x14)
USART1_GTPR EQU (USART1_BASE + 0x18)
;NVIC暫存器地址
NVIC_BASE EQU 0xE000E000
NVIC_SETEN EQU (NVIC_BASE + 0x0010)
;SETENA暫存器陣列的起始地址
NVIC_IRQPRI EQU (NVIC_BASE + 0x0400)
;中斷優先級暫存器陣列的起始地址
NVIC_VECTTBL EQU (NVIC_BASE + 0x0D08)
;向量表偏移暫存器的地址
NVIC_AIRCR EQU (NVIC_BASE + 0x0D0C)
;應用程式中斷及復位控制暫存器的地址
SETENA0 EQU 0xE000E100
SETENA1 EQU 0xE000E104
;SysTick暫存器地址
SysTick_BASE EQU 0xE000E010
SYSTICKCSR EQU (SysTick_BASE + 0x00)
SYSTICKRVR EQU (SysTick_BASE + 0x04)
;FLASH緩沖暫存器地址映像
FLASH_ACR EQU 0x40022000
;SCB_BASE EQU (SCS_BASE + 0x0D00)
MSP_TOP EQU 0x20005000
;主堆疊起始值
PSP_TOP EQU 0x20004E00
;行程堆疊起始值
BitAlias_BASE EQU 0x22000000
;位帶別名區起始地址
Flag1 EQU 0x20000200
b_flas EQU (BitAlias_BASE + (0x200*32) + (0*4))
;位地址
b_05s EQU (BitAlias_BASE + (0x200*32) + (1*4))
;位地址
DlyI EQU 0x20000204
DlyJ EQU 0x20000208
DlyK EQU 0x2000020C
SysTim EQU 0x20000210
;常數定義
Bit0 EQU 0x00000001
Bit1 EQU 0x00000002
Bit2 EQU 0x00000004
Bit3 EQU 0x00000008
Bit4 EQU 0x00000010
Bit5 EQU 0x00000020
Bit6 EQU 0x00000040
Bit7 EQU 0x00000080
Bit8 EQU 0x00000100
Bit9 EQU 0x00000200
Bit10 EQU 0x00000400
Bit11 EQU 0x00000800
Bit12 EQU 0x00001000
Bit13 EQU 0x00002000
Bit14 EQU 0x00004000
Bit15 EQU 0x00008000
Bit16 EQU 0x00010000
Bit17 EQU 0x00020000
Bit18 EQU 0x00040000
Bit19 EQU 0x00080000
Bit20 EQU 0x00100000
Bit21 EQU 0x00200000
Bit22 EQU 0x00400000
Bit23 EQU 0x00800000
Bit24 EQU 0x01000000
Bit25 EQU 0x02000000
Bit26 EQU 0x04000000
Bit27 EQU 0x08000000
Bit28 EQU 0x10000000
Bit29 EQU 0x20000000
Bit30 EQU 0x40000000
Bit31 EQU 0x80000000
;向量表
AREA RESET, DATA, READONLY
DCD MSP_TOP ;初始化主堆疊
DCD Start ;復位向量
DCD NMI_Handler ;NMI Handler
DCD HardFault_Handler ;Hard Fault Handler
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD 0
DCD SysTick_Handler ;SysTick Handler
SPACE 20 ;預留空間20位元組
;代碼段
AREA |.text|, CODE, READONLY
;主程式開始
ENTRY
;指示程式從這里開始執行
Start
;時鐘系統設定
ldr r0, =RCC_CR
ldr r1, [r0]
orr r1, #Bit16
str r1, [r0]
;開啟外部晶振使能
;啟動外部8M晶振
ClkOk
ldr r1, [r0]
ands r1, #Bit17
beq ClkOk
;等待外部晶振就緒
ldr r1,[r0]
orr r1,#Bit17
str r1,[r0]
;FLASH緩沖器
ldr r0, =FLASH_ACR
mov r1, #0x00000032
str r1, [r0]
;設定PLL鎖相環倍率為7,HSE輸入不分頻
ldr r0, =RCC_CFGR
ldr r1, [r0]
orr r1, #(Bit18 :OR: Bit19 :OR: Bit20 :OR: Bit16 :OR: Bit14)
orr r1, #Bit10
str r1, [r0]
;啟動PLL鎖相環
ldr r0, =RCC_CR
ldr r1, [r0]
orr r1, #Bit24
str r1, [r0]
PllOk
ldr r1, [r0]
ands r1, #Bit25
beq PllOk
;選擇PLL時鐘作為系統時鐘
ldr r0, =RCC_CFGR
ldr r1, [r0]
orr r1, #(Bit18 :OR: Bit19 :OR: Bit20 :OR: Bit16 :OR: Bit14)
orr r1, #Bit10
orr r1, #Bit1
str r1, [r0]
;其它RCC相關設定
ldr r0, =RCC_APB2ENR
mov r1, #(Bit14 :OR: Bit4 :OR: Bit2)
str r1, [r0]
;IO埠設定
ldr r0, =GPIOC_CRL
ldr r1, [r0]
orr r1, #(Bit28 :OR: Bit29)
;PC.7輸出模式,最大速度50MHz
and r1, #(~Bit30 & ~Bit31)
;PC.7通用推挽輸出模式
str r1, [r0]
;PA9串口0發射腳
ldr r0, =GPIOA_CRH
ldr r1, [r0]
orr r1, #(Bit4 :OR: Bit5)
;PA.9輸出模式,最大速度50MHz
orr r1, #Bit7
and r1, #~Bit6
;10：復用功能推挽輸出模式
str r1, [r0]
ldr r0, =USART1_BRR
mov r1, #0x271
str r1, [r0]
;配置波特率-> 115200
ldr r0, =USART1_CR1
mov r1, #0x200c
str r1, [r0]
;USART模塊總使能 發送與接收使能
;71 02 00 00 2c 20 00 00
;AFIO 引數設定
;Systick 引數設定
ldr r0, =SYSTICKRVR
;Systick裝初值
mov r1, #9000
str r1, [r0]
ldr r0, =SYSTICKCSR
;設定,啟動Systick
mov r1, #0x03
str r1, [r0]
;NVIC
;ldr r0, =SETENA0
;mov r1, 0x00800000
;str r1, [r0]
;ldr r0, =SETENA1
;mov r1, #0x00000100
;str r1, [r0]
;切換成用戶級執行緒式模式
ldr r0, =PSP_TOP
;初始化執行緒堆疊
msr psp, r0
mov r0, #3
msr control, r0
;初始化SRAM暫存器
mov r1, #0
ldr r0, =Flag1
str r1, [r0]
ldr r0, =DlyI
str r1, [r0]
ldr r0, =DlyJ
str r1, [r0]
ldr r0, =DlyK
str r1, [r0]
ldr r0, =SysTim
str r1, [r0]
;主回圈
main
ldr r0, =Flag1
ldr r1, [r0]
tst r1, #Bit1
;SysTick產生0.5s,置位bit 1
beq main ;0.5s標志還沒有置位
;0.5s標志已經置位
ldr r0, =b_05s
;位帶操作清零0.5s標志
mov r1, #0
str r1, [r0]
bl LedFlas
mov r0, #'H'
bl send_a_char
mov r0, #'e'
bl send_a_char
mov r0, #'l'
bl send_a_char
mov r0, #'l'
bl send_a_char
mov r0, #'o'
bl send_a_char
mov r0, #' '
bl send_a_char
mov r0, #'w'
bl send_a_char
mov r0, #'o'
bl send_a_char
mov r0, #'r'
bl send_a_char
mov r0, #'l'
bl send_a_char
mov r0, #'d'
bl send_a_char
mov r0, #'\n'
bl send_a_char
b main
;子程式 串口1發送一個字符
send_a_char
push {r0 - r3}
ldr r2, =USART1_DR
str r0, [r2]
b1
ldr r2, =USART1_SR
ldr r2, [r2]
tst r2, #0x40
beq b1
;發送完成(Transmission complete)等待
pop {r0 - r3}
bx lr
;子程式 led閃爍
LedFlas
push {r0 - r3}
ldr r0, =Flag1
ldr r1, [r0]
tst r1, #Bit0
;bit0 閃爍標志位
beq ONLED ;為0 打開led燈
;為1 關閉led燈
ldr r0, =b_flas
mov r1, #0
str r1, [r0]
;閃爍標志位置為0,下一狀態為打開燈
;PC.7輸出0
ldr r0, =GPIOC_BRR
ldr r1, [r0]
orr r1, #Bit7
str r1, [r0]
b LedEx
ONLED
;為0 打開led燈
ldr r0, =b_flas
mov r1, #1
str r1, [r0]
;閃爍標志位置為1,下一狀態為關閉燈
;PC.7輸出1
ldr r0, =GPIOC_BSRR
ldr r1, [r0]
orr r1, #Bit7
str r1, [r0]
LedEx
pop {r0 - r3}
bx lr
;例外程式
NMI_Handler
bx lr
HardFault_Handler
bx lr
SysTick_Handler
ldr r0, =SysTim
ldr r1, [r0]
add r1, #1
str r1, [r0]
cmp r1, #500
bcc TickExit
mov r1, #0
str r1, [r0]
ldr r0, =b_05s
;大于等于500次 清零時鐘滴答計數器 設定0.5s標志位
;位帶操作置1
mov r1, #1
str r1, [r0]
TickExit
bx lr
ALIGN
;通過用零或空指令NOP填充,來使當前位置與一個指定的邊界對齊
END
打開魔法棒 勾選Create HEX File，以便輸出HEX檔案：
勾選Use MicroLIB：
編譯：
利用USB轉串口燒錄程式，將波特率改為115200；
將boot0和boot1都接0，重新接電：
三、結果
打開野火串口除錯助手，設定如圖：
打開串口，成功接收：
總結
串口通信可實作高速資料通信，
參考資料
https://blog.csdn.net/weixin_46628481/article/details/120852364
轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/336310.html
標籤：其他