主頁 >  其他 > 井字游戲

井字游戲

2021-12-11 04:28:13 其他

我正在嘗試批量撰寫井字游戲。但是我遇到了幾個我無法解決的問題。

  1. 在玩家 1 的第三次移動之后，游戲必須檢查玩家 1 是否贏了。我試圖通過制作所有可能的 8 個 winlines 的 8 個變數來做到這一點。然后游戲檢查是否有任何贏利線等于 XXX 或 OOO。問題是欄位變數（_f1、_f2 等）不會更改為 X 或 O。我在腳本的開頭通過它們的數字設定它們，但我不明白為什么一旦玩家輸入它們，它們就不會改變該欄位/變數中的 X 或 O。

  2. 代碼非常丑陋，而且不必要地長。我知道這個for命令，我可以做基本的回圈，但是如果命令變得太復雜，我就無法理解語法。如何將所有 repititions 放入 for 回圈中？

     @echo off
 setlocal enabledelayedexpansion
 title .:TIC TAC TOE:.
 mode con: cols=40 lines=20
 color 02
 cls



 goto :main

 :check
     if !_win1!==XXX (
         echo END OF GAME
         pause
     )
     if !_win2!==XXX (
         echo END OF GAME
         pause
     )
     if !_win3!==XXX (
         echo END OF GAME
         pause
     )
     if !_win4!==XXX (
         echo END OF GAME
         pause
     )
     if !_win5!==XXX (
         echo END OF GAME
         pause
     )
     if !_win6!==XXX (
         echo END OF GAME
         pause
     )
     if !_win7!==XXX (
         echo END OF GAME
         pause
     )
     if !_win8!==XXX (
         echo END OF GAME
         pause
     )
 goto :eof

 :player2turn
     choice /c 123456789 /n /m "!_player2!, it's your turn!"
     if !errorlevel!==1 (
             if !_f1!==1 (
                 set _f1=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
                 )
         )
         if !errorlevel!==2 (
             if !_f2!==2 (
                 set _f2=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==3 (
             if !_f3!==3 (
                 set _f3=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==4 (
             if !_f4!==4 (
                 set _f4=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==5 (
             if !_f5!==5 (
                 set _f5=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==6 (
             if !_f6!==6 (
                 set _f6=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==7 (
             if !_f7!==7 (
                 set _f7=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==8 (
             if !_f8!==8 (
                 set _f8=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==9 (
             if !_f9!==9 (
                 set _f9=!_player2symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
 goto :eof

 :player1turn
     choice /c 123456789 /n /m "!_player1!, it's your turn!"
         if !errorlevel!==1 (
             if !_f1!==1 (
                 set _f1=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
                 )
         )
         if !errorlevel!==2 (
             if !_f2!==2 (
                 set _f2=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==3 (
             if !_f3!==3 (
                 set _f3=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==4 (
             if !_f4!==4 (
                 set _f4=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==5 (
             if !_f5!==5 (
                 set _f5=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==6 (
             if !_f6!==6 (
                 set _f6=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==7 (
             if !_f7!==7 (
                 set _f7=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==8 (
             if !_f8!==8 (
                 set _f8=!_player1symbol!
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
         if !errorlevel!==9 (
             if !_f9!==9 (
                 set _f9=!_player1symbol!
                 echo !_win1!
                 echo !_player1symbol!
                 pause
                 goto :eof
             ) else (
                 goto :player1turn
             )
         )
 goto :eof

 ::displaying the map
 :map
     echo.
     echo.
     echo.
     echo           !_f7! ^| !_f8! ^| !_f9!
     echo           ---------
     echo           !_f4! ^| !_f5! ^| !_f6!
     echo           ---------
     echo           !_f1! ^| !_f2! ^| !_f3!
     echo.
     echo.
     echo.
 goto :eof


 ::setting variables
 :setvar
     set _f1=1
     set _f2=2
     set _f3=3
     set _f4=4
     set _f5=5
     set _f6=6
     set _f7=7
     set _f8=8
     set _f9=9

     set _win1=!_f7!!_f8!!_f9!
     set /a _win2=!_f4! !_f5! !_f6!
     set /a _win3=!_f1! !_f2! !_f3!
     set /a _win4=!_f7! !_f4! !_f1!
     set /a _win5=!_f8! !_f5! !_f2!
     set /a _win6=!_f9! !_f6! !_f3!
     set /a _win7=!_f7! !_f5! !_f3!
     set /a _win8=!_f9! !_f5! !_f1!
 goto :eof

 ::player settings
 :setup
     echo.
     set /p _player1=Enter name for Player 1: 
     echo.
     choice /c xo /n /m "!_player1! do you want to play as X or O?"
         if !errorlevel!==1 (
             set _player1symbol=X
             set _player2symbol=O
         ) else (
             set _player1symbol=O
             set _player2symbol=X
         )
     echo.
     echo.
     set /p _player2=Enter name for Player 2: 
     echo.
     cls
     echo.
     echo.
     echo.
     echo !_player1!(!_player1symbol!) vs. !_player2!(!_player2symbol!)
     pause>nul
 goto :eof

 :main
 setlocal

     call :setup
     cls
     call :setvar

     call :map
     call :player1turn
     cls
     call :map
     call :player2turn
     cls
     call :map
     call :player1turn
     cls
     call :map
     call :player2turn
     cls
     call :map
     call :player1turn
     call :check


 endlocal
 goto :eof

uj5u.com熱心網友回復：

在撰寫一行程式之前，您應該研究并定義您的編碼方法。此外，您應該學習語言功能以充分利用其設施。這適用于任何編程語言。

這是我會這樣做的方式：

@echo off
setlocal EnableDelayedExpansion

rem Test for win: Horizontal rows
set "win[1]=%%pos[1]%%%%pos[2]%%%%pos[3]%%"
set "win[2]=%%pos[4]%%%%pos[5]%%%%pos[6]%%"
set "win[3]=%%pos[7]%%%%pos[8]%%%%pos[9]%%"
rem Test for win: Vertical cols
set "win[4]=%%pos[1]%%%%pos[4]%%%%pos[7]%%"
set "win[5]=%%pos[2]%%%%pos[5]%%%%pos[8]%%"
set "win[6]=%%pos[3]%%%%pos[6]%%%%pos[9]%%"
rem Test for win: Diagonals
set "win[7]=%%pos[1]%%%%pos[5]%%%%pos[9]%%"
set "win[8]=%%pos[7]%%%%pos[5]%%%%pos[3]%%"

for /L %%i in (1,1,9) do set "pos[%%i]=%%i"
set "taken=_"

cls
set /P "player[X]=Enter player 1 (X) name: "
set /P "player[O]=Enter player 2 (O) name: "
call :showBoard

set "players=XO"
for /L %%n in (1,1,9) do (
   call :playerTurn !players:~0,1!
   if !result! equ 1 echo You win^^^! & goto :EOF
   set "players=!players:~1,1!!players:~0,1!"
)
echo Game was a draw...
goto :EOF


:playerTurn wichOne
choice /C 123456789 /N /M "!player[%1]!, it's your turn: "
set "choice=%errorlevel%"
if "!taken:%choice%=!" neq "%taken%" echo Bad position & goto playerTurn
set "taken=%taken%%choice%"
set "pos[%choice%]=%1"
call :showBoard
rem Test if win
set "result=0"
for /L %%i in (1,1,8) do if !result! equ 0 (
   call set "line=!win[%%i]!
   if "!line!" equ "%1%1%1" set "result=1"
)
exit /B


:showBoard
echo/
echo/
echo           %pos[1]% ^| %pos[2]% ^| %pos[3]%
echo           ---------
echo           %pos[4]% ^| %pos[5]% ^| %pos[6]%
echo           ---------
echo           %pos[7]% ^| %pos[8]% ^| %pos[9]%
echo/
echo/
exit /B

編輯 2021/12/08： 添加了新版本

這個程式的原始版本很簡單，OP 可以理解。下面的下一個版本是為了盡可能高效和簡短而撰寫的：

@echo off
setlocal EnableDelayedExpansion

set "win=" & set "out="
for %%a in (1:2:3 4:5:6 7:8:9  1:4:7 2:5:8 3:6:9  1:5:9 3:5:7) do (
   for /F "tokens=1-3 delims=:" %%x in ("%%a") do (
      set "win=!win! ^!pos[%%x]^!^!pos[%%y]^!^!pos[%%z]^!"
      if "!out:~-3,1!" neq "9" set "out=!out!$^!pos[%%x]^! ^^| ^!pos[%%y]^! ^^| ^!pos[%%z]^!"
   )
)
set "out=!out:~1!"

:menu
cls
set /P "player[X]=Enter player 1 (X) name: "
set /P "player[O]=Enter player 2 (O) name: "

for /L %%i in (1,1,9) do set "pos[%%i]=%%i"
set "options=123456789" & set "filler=asdfghjkl"

for %%n in (X O X O X O X O X) do (
   cls
   echo/& echo/& echo     %out:$=& echo     -- --- --& echo     %& echo/& echo/
   choice /C !options! /N /M "!player[%%n]!, it's your turn: "
   for /F "tokens=1,2" %%e in ("!errorlevel! !filler:~0,1!") do (
      set "options=!options:%%e=%%f!" & set "filler=!filler:~1!" & set "pos[%%e]=%%n"
   )
   set "line=%win%"
   if "!line:%%n%%n%%n=!" neq "!line!" echo You win^^^! & goto nextGame
)
echo Game was a draw...
:nextGame
echo/
pause
goto :menu

uj5u.com熱心網友回復：

@Aacini 發布了一個很好的答案，所以我決定也發布我自己的答案。正如他們所說，有很多方法可以給貓剝皮。

@echo off & Title Tic-Tac-Toe 
setlocal enabledelayedexpansion & mode con: cols=40 lines=20 & color 02
for /F %%i in ('echo prompt $E ^| cmd') do set "n=%%iE"
:menu
cls & set gone=. & for %%p in (player[X] player[O]) do set /p "%%~p=enter name %%p: "
for /l %%i in (1,1,9) do set a%%i=%%i
for /L %%i in (1,1,4) do for %%a in (X O) do (
      for %%x in (!a1!!a2!!a3! !a4!!a5!!a6! !a7!!a8!!a9! !a1!!a4!!a7! !a2!!a5!!a8! !a3!!a6!!a9! !a1!!a5!!a9! !a3!!a5!!a7!) do (
          if "%%x" == "!_h!!_h!!_h!" echo !pl! wins & timeout /t 4 /NOBREAK >nul & goto :menu
      )
          set "pl=!player[%%a]!" & set _h=%%a
          call :play
          set "a!ch!=%%a"
          if %%i geq 4 echo No winners & timeout /t 4 /NOBREAK >nul & goto :menu
 )

:play
cls & echo(
echo     !a1! ^| !a2! ^| !a3!%n%    ----------%n%    !a4! ^| !a5! ^| !a6!%n%    ----------%n%    !a7! ^| !a8! ^| !a9!%n%
choice /c 123456789 /m "!pl!'s turn"
set ch=!errorlevel!
if !ch! equ 0 exit /b
if "!gone:%ch%=!" neq "%gone%" echo That spot has been taken, try again & timeout /t 3 /NOBREAK >nul & goto :play
set "gone=%gone%!ch!"
goto :eof

以及不支持 VT100 的舊 Windows 版本：

@echo off & Title Tic-Tac-Toe 
setlocal enabledelayedexpansion & mode con: cols=40 lines=20 & color 02
:menu
cls & set gone=. & for %%p in (player[X] player[O]) do set /p "%%~p=enter name %%p: "

for /l %%i in (1,1,9) do set a%%i=%%i
for /L %%i in (1,1,4) do for %%a in (X O) do (
      for %%x in (!a1!!a2!!a3! !a4!!a5!!a6! !a7!!a8!!a9! !a1!!a4!!a7! !a2!!a5!!a8! !a3!!a6!!a9! !a1!!a5!!a9! !a3!!a5!!a7!) do (
          if "%%x" == "!_h!!_h!!_h!" echo !pl! wins & timeout /t 4 /NOBREAK >nul & goto :menu
      )
          set "pl=!player[%%a]!" & set _h=%%a
          call :play
          set "a!ch!=%%a"
          if %%i geq 4 echo No winners & timeout /t 4 /NOBREAK >nul & goto :menu
 )

:play
cls & echo(
echo    !a1! ^| !a2! ^| !a3!&echo    ----------&echo    !a4! ^| !a5! ^| !a6!&echo    ----------&echo    !a7! ^| !a8! ^| !a9!&echo(
choice /c 123456789 /m "!pl!'s turn"
set ch=!errorlevel!
if !ch! equ 0 exit /b
if "!gone:%ch%=!" neq "%gone%" echo That spot has been taken, try again & timeout /t 3 /NOBREAK >nul & goto :play
set "gone=%gone%!ch!"
goto :eof

轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/378971.html

標籤：批处理文件

上一篇：如何使用多行輸入（一次）運行netuse？

下一篇：python-nmap使用及詳解

標籤雲
其他(157675) Python(38076) JavaScript(25376) Java(17977) C(15215) 區塊鏈(8255) C＃(7972) AI(7469) 爪哇(7425) MySQL(7132) html(6777) 基礎類(6313) sql(6102) 熊猫(6058) PHP(5869) 数组(5741) R(5409) Linux(5327) 反应(5209) 腳本語言(PerlPython)(5129) 非技術區(4971) Android(4554) 数据框(4311) css(4259) 节点.js(4032) C語言(3288) json(3245) 列表(3129) 扑(3119) C++語言(3117) 安卓(2998) 打字稿(2995) VBA(2789) Java相關(2746) 疑難問題(2699) 细绳(2522) 單片機工控(2479) iOS(2429) ASP.NET(2402) MongoDB(2323) 麻木的(2285) 正则表达式(2254) 字典(2211) 循环(2198) 迅速(2185) 擅长(2169) 镖(2155) 功能(1967) .NET技术(1958) Web開發(1951) python-3.x(1918) HtmlCss(1915) 弹簧靴(1913) C++(1909) xml(1889) PostgreSQL(1872) .NETCore(1853) 谷歌表格(1846) Unity3D(1843) for循环(1842)

熱門瀏覽
  • 網閘典型架構簡述

    網閘架構一般分為兩種：三主機的三系統架構網閘和雙主機的2+1架構網閘。 三主機架構分別為內端機、外端機和仲裁機。三機無論從軟體和硬體上均各自獨立。首先從硬體上來看，三機都用各自獨立的主板、記憶體及存盤設備。從軟體上來看，三機有各自獨立的作業系統。這樣能達到完全的三機獨立。對于“2+1”系統，“2”分為 ......

    uj5u.com 2020-09-10 02:00:44 more
  • 如何從xshell上傳檔案到centos linux虛擬機里

    如何從xshell上傳檔案到centos linux虛擬機里及：虛擬機CentOs下執行 yum -y install lrzsz命令，出現錯誤：鏡像無法找到軟體包 前言 一、安裝lrzsz步驟 二、上傳檔案 三、遇到的問題及解決方案 總結 前言 提示：其實很簡單，往虛擬機上安裝一個上傳檔案的工具 ......

    uj5u.com 2020-09-10 02:00:47 more
  • 一、SQLMAP入門

    一、SQLMAP入門 1、判斷是否存在注入 sqlmap.py -u 網址/id=1 id=1不可缺少。當注入點后面的引數大于兩個時。需要加雙引號， sqlmap.py -u "網址/id=1&uid=1" 2、判斷文本中的請求是否存在注入 從文本中加載http請求，SQLMAP可以從一個文本檔案中 ......

    uj5u.com 2020-09-10 02:00:50 more
  • Metasploit 簡單使用教程

    metasploit 簡單使用教程 浩先生， 2020-08-28 16:18:25 分類專欄： kail 網路安全 linux 文章標簽： linux資訊安全 編輯 著作權 metasploit 使用教程 前言 一、Metasploit是什么？ 二、準備作業 三、具體步驟 前言 Msfconsole ......

    uj5u.com 2020-09-10 02:00:53 more
  • 游戲逆向之驅動層與用戶層通訊

    驅動層代碼： #pragma once #include <ntifs.h> #define add_code CTL_CODE(FILE_DEVICE_UNKNOWN,0x800,METHOD_BUFFERED,FILE_ANY_ACCESS) /* 更多游戲逆向視頻www.yxfzedu.com ......

    uj5u.com 2020-09-10 02:00:56 more
  • 北斗電力時鐘（北斗授時服務器）讓網路資料更精準

    北斗電力時鐘（北斗授時服務器）讓網路資料更精準 北斗電力時鐘（北斗授時服務器）讓網路資料更精準 京準電子科技官微——ahjzsz 近幾年，資訊技術的得了快速發展，互聯網在逐漸普及，其在人們生活和生產中都得到了廣泛應用，并且取得了不錯的應用效果。計算機網路資訊在電力系統中的應用，一方面使電力系統的運行 ......

    uj5u.com 2020-09-10 02:01:03 more
  • 【CTF】CTFHub 技能樹 彩蛋 writeup

    ?碎碎念 CTFHub：https://www.ctfhub.com/ 筆者入門CTF時時剛開始刷的是bugku的舊平臺，后來才有了CTFHub。 感覺不論是網頁UI設計，還是題目質量，賽事跟蹤，工具軟體都做得很不錯。 而且因為獨到的金幣制度的確讓人有一種想去刷題賺金幣的感覺。 個人還是非常喜歡這個 ......

    uj5u.com 2020-09-10 02:04:05 more
  • 02windows基礎操作

    我學到了一下幾點 Windows系統目錄結構與滲透的作用 常見Windows的服務詳解 Windows埠詳解 常用的Windows注冊表詳解 hacker DOS命令詳解（net user / type /md /rd/ dir /cd /net use copy、批處理 等） 利用dos命令制作 ......

    uj5u.com 2020-09-10 02:04:18 more
  • 03.Linux基礎操作

    我學到了以下幾點 01Linux系統介紹02系統安裝，密碼啊破解03Linux常用命令04LAMP 01LINUX windows： win03 8 12 16 19 配置不繁瑣 Linux：redhat,centos(紅帽社區版)，Ubuntu server,suse unix:金融機構，證券，銀 ......

    uj5u.com 2020-09-10 02:04:30 more
  • 05HTML

    01HTML介紹 02頭部標簽講解03基礎標簽講解04表單標簽講解 HTML前段語言 js1.了解代碼2.根據代碼 懂得挖掘漏洞 （POST注入/XSS漏洞上傳）3.黑帽seo 白帽seo 客戶網站被黑帽植入劫持代碼如何處理4.熟悉html表單 <html><head><title>TDK標題，描述 ......

    uj5u.com 2020-09-10 02:04:36 more
最新发布
  • 2023年最新微信小程式抓包教程

    01 開門見山 隔一個月發一篇文章，不過分。 首先回顧一下《微信系結手機號資料庫被脫庫事件》，我也是第一時間得知了這個訊息，然后跟蹤了整件事情的經過。下面是這起事件的相關截圖以及近日流出的一萬條資料樣本： 個人認為這件事也沒什么，還不如關注一下之前45億快遞資料查詢渠道疑似在近日復活的訊息。 訊息是 ......

    uj5u.com 2023-04-20 08:48:24 more
  • web3 產品介紹：metamask 錢包 使用最多的瀏覽器插件錢包

    Metamask錢包是一種基于區塊鏈技術的數字貨幣錢包，它允許用戶在安全、便捷的環境下管理自己的加密資產。Metamask錢包是以太坊生態系統中最流行的錢包之一，它具有易于使用、安全性高和功能強大等優點。 本文將詳細介紹Metamask錢包的功能和使用方法。 一、 Metamask錢包的功能 數字資 ......

    uj5u.com 2023-04-20 08:47:46 more
  • vulnhub_Earth

    前言 靶機地址->>>vulnhub_Earth 攻擊機ip：192.168.20.121 靶機ip：192.168.20.122 參考文章 https://www.cnblogs.com/Jing-X/archive/2022/04/03/16097695.html https://www.cnb ......

    uj5u.com 2023-04-20 07:46:20 more
  • 從4k到42k，軟體測驗工程師的漲薪史，給我看哭了

    清明節一過，盲猜大家已經無心上班，在數著日子準備過五一，但一想到銀行卡里的余額……瞬間心情就不美麗了。最近，2023年高校畢業生就業調查顯示，本科畢業月平均起薪為5825元。調查一出，便有很多同學表示自己又被平均了。看著這一資料，不免讓人想到前不久中國青年報的一項調查：近六成大學生認為畢業10年內會 ......

    uj5u.com 2023-04-20 07:44:00 more
  • 最新版本 Stable Diffusion 開源 AI 繪畫工具之中文自動提詞篇

    🎈 標簽生成器 由于輸入正向提示詞 prompt 和反向提示詞 negative prompt 都是使用英文，所以對學習母語的我們非常不友好 使用網址：https://tinygeeker.github.io/p/ai-prompt-generator 這個網址是為了讓大家在使用 AI 繪畫的時候 ......

    uj5u.com 2023-04-20 07:43:36 more
  • 漫談前端自動化測驗演進之路及測驗工具分析

    隨著前端技術的不斷發展和應用程式的日益復雜，前端自動化測驗也在不斷演進。隨著 Web 應用程式變得越來越復雜，自動化測驗的需求也越來越高。如今，自動化測驗已經成為 Web 應用程式開發程序中不可或缺的一部分，它們可以幫助開發人員更快地發現和修復錯誤，提高應用程式的性能和可靠性。 ......

    uj5u.com 2023-04-20 07:43:16 more
  • CANN開發實踐：4個DVPP記憶體問題的典型案例解讀

    摘要：由于DVPP媒體資料處理功能對存放輸入、輸出資料的記憶體有更高的要求（例如，記憶體首地址128位元組對齊），因此需呼叫專用的記憶體申請介面，那么本期就分享幾個關于DVPP記憶體問題的典型案例，并給出原因分析及解決方法。 本文分享自華為云社區《FAQ_DVPP記憶體問題案例》，作者：昇騰CANN。 DVPP ......

    uj5u.com 2023-04-20 07:43:03 more
  • msf學習

    msf學習 以kali自帶的msf為例 一、msf核心模塊與功能 msf模塊都放在/usr/share/metasploit-framework/modules目錄下 1、auxiliary 輔助模塊，輔助滲透（埠掃描、登錄密碼爆破、漏洞驗證等） 2、encoders 編碼器模塊，主要包含各種編碼 ......

    uj5u.com 2023-04-20 07:42:59 more
  • Halcon軟體安裝與界面簡介

    1. 下載Halcon17版本到到本地 2. 雙擊安裝包后 3. 步驟如下 1.2 Halcon軟體安裝 界面分為四大塊 1. Halcon的五個助手 1) 影像采集助手：與相機連接，設定相機引數，采集影像 2) 標定助手：九點標定或是其它的標定，生成標定檔案及內參外參，可以將像素單位轉換為長度單位 ......

    uj5u.com 2023-04-20 07:42:17 more
  • 在MacOS下使用Unity3D開發游戲

    第一次發博客，先發一下我的游戲開發環境吧。 去年2月份買了一臺MacBookPro2021 M1pro(以下簡稱mbp)，這一年來一直在用mbp開發游戲。我大致分享一下我的開發工具以及使用體驗。 1、Unity 官網鏈接： https://unity.cn/releases 我一般使用的Apple ......

    uj5u.com 2023-04-20 07:40:19 more

Copyright © 2010-2020 有解無憂