紋理可以用來存盤任何表面屬性，
可以通過使用漸變紋理來實作插畫風格的渲染效果，
這項技術是由Valve公司提出的，Valve使用它來渲染游戲中具有插畫風格的角色，
我們使用半蘭伯特模型計算漫反射，
因為我們使用的實際上是一個一維紋理：
所以在片元著色器中，我們使用fixed2(halfLambert, halfLambert)作為uv坐標進行紋理采樣，
代碼實作如下：
Shader "Unity Shader Book/Chapter 7/RampTexture"
{
Properties
{
_Color ("Color", Color) = (1,1,1,1)
_RampTex ("RampTex", 2D) = "white" {}
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader
{
Pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma fragment frag
#pragma vertex vert
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _RampTex;
float4 _RampTex_ST;
fixed4 _Specular;
float _Gloss;
struct a2v{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD;
};
struct v2f{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert(a2v v){
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
//計算偏移后的紋理坐標
o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//使用半蘭伯特計算模型
fixed halfLambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
//使用紋理計算漫反射顏色
fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, halfLambert)).rgb * _Color.rgb;
//計算漫反射項
fixed3 diffuse = _LightColor0.rgb * diffuseColor;
//高光反射
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 halfdir = normalize(worldLightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfdir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
把不同的紋理賦給應用此shader的材質，可以得到不同的效果，
使用突變的色塊作為紋理可以模擬卡通風格，如下圖所示，
另外，我們需要把漸變紋理的Wrap Mode設定為Clamp模式，
因為我們使用fixed2(halfLambert, halfLambert)進行紋理采樣，Repeat模式下會舍棄整數部分，如果halfLambert大于1（如1.00001），會只保留0.00001，導致映射出現問題，
轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/472898.html
標籤：其他
下一篇：面試技巧