【Godot】制作技能節點-有解無憂

Godot 3.2.3

制作技能前我里可能想到技能有「立即施放完成的技能」和「持續施放的技能」（也許有別的，但我暫時只想到有這兩個），有「冷卻時間」和「持續時間」，按下施放技能的按鍵等，
以下是所有技能的基礎類，我覺得你照著前去寫一下，大概能明白什么意思和實作的思路，

新建一個 SkillBase 腳本，寫入如下內容，

#============================================
# 「技能基類」 -  2020-9-12 22:23
# @author: Apprentice Zhang
#============================================

extends Node2D
class_name SkillBase


#>>> 列舉 <<<
# 技能狀態型別
enum SKILL_STATE{
	IDLE			# 空閑，可施放的
	CASTED			# 已經施放
	CASTING			# 正在施放
	FINISHED		# 技能施放完成
}


#>>> 面板屬性 <<<
export (NodePath) var host_node = @'..'
export (String) var skill_name					# 技能名稱
export (Texture) var skill_icon					# 技能圖示
export (String) var input_key					# 施放鍵（獲取「鍵位映射」里的）
export (float, 0, 10000) var cooldown = 1.0		# 冷卻時間
export (float, 0, 10000) var duration = 0.5		# 技能持續時間


#>>> 私有變數 <<<
var _skill_state: int = SKILL_STATE.IDLE		# 當前技能狀態
var _can_cast: bool = true						# 能否施放技能
var _duration_countdown: float = -1				# 施放持續技能倒計時


#>>> 節點 <<<
var _cooling_timer := Timer.new()				# 技能冷卻計時器



#============================================
#		內置的方法
#============================================
func _ready() -> void:
	set_physics_process(false)
	
	if input_key == '':
		print("--> SkillBase < 提示 > 未設定按鍵")
		set_process(false)
	
	# 添加「冷卻時間」計時器
	if not _cooling_timer.is_inside_tree():
		_cooling_timer.connect("timeout", self, 'cooling_complete')
		_cooling_timer.one_shot = true
		_cooling_timer.autostart = false
		add_child(_cooling_timer)


func _input(event: InputEvent) -> void:
	# 獲取用戶按鍵
	if event.is_action_pressed(input_key):
		if is_can_cast():
			cast_skill()


func _physics_process(delta: float) -> void:
	# 「持續技能倒計時」到達時間，則關閉行程
	if _duration_countdown <= 0:
		cast_over()
		set_physics_process(false)
		return
	_duration_countdown -= delta	# 「持續技能時間倒計時」
	duration_process(delta)			# 呼叫持續技能方法



#============================================
#		可重寫方法
#============================================
func cast_skill():
	"""施放技能"""
#	print("--> 開始施放技能：", skill_name)
	_start_duration_countdown()
	_start_cooldown_countdown()
	_can_cast = false
	switch_skill_state(SKILL_STATE.CASTED)


func duration_process(delta: float):
	"""持續時間行程"""
#	print('---> ', skill_name)
	pass


func cast_over():
	"""技能施放結束"""
#	print("--> 技能施放結束：", skill_name)
	if _skill_state != SKILL_STATE.IDLE:
		switch_skill_state(SKILL_STATE.FINISHED)


func is_can_cast() -> bool:
	"""能否施放技能
	< 后續重寫時，可再添加魔法值等屬性是否足夠的判斷，來確定可否施放技能 >
	"""
	return _can_cast && _skill_state == SKILL_STATE.IDLE


func cooling_complete() -> void:
	"""技能冷卻完成"""
	switch_skill_state(SKILL_STATE.IDLE)
	_can_cast = true


func switch_skill_state(state):
	"""切換技能狀態"""
	_skill_state = state



#============================================
#		最終的方法（不能重寫的方法）
#============================================
func _start_duration_countdown() -> void:
	"""開啟持續技能倒計時"""
	if duration <= 0:
		cast_over()
		return
	switch_skill_state(SKILL_STATE.CASTING)
	_duration_countdown = duration
	set_physics_process(true)


func _start_cooldown_countdown() -> void:
	"""開始冷卻時間倒計時"""
	if cooldown > 0 :	_cooling_timer.start(cooldown)
	else:				_cooling_timer.start(0.001)


func get_timer_once(
	wait_time: float,
	target: Object = null,
	method: String = ""
) -> Timer:
	"""回傳一個一次性的計時器
	< 計時器結束后呼叫指定的方法，用于那些需要間隔時間施放的「立即施放」技能 >
	"""
	var _timer = Timer.new()
	if wait_time <= 0:	_timer.wait_time = 0.001
	else:				_timer.wait_time = wait_time
	_timer.connect("timeout", self, '__on_Timer_timeout', [_timer])
	_timer.autostart = true
	_timer.one_shot = true
	if target != null: 
		_timer.connect("timeout", target, method)
	add_child(_timer)
	return _timer


func __on_Timer_timeout(timer: Timer) -> void:
	timer.queue_free()


func _get_host_node() -> Node2D:
	"""獲取節點的宿主"""
	return get_node(host_node) as Node2D

現在我們試著做一個「持續施放」的技能 ——「沖刺」，
新建一個 Sprint 腳本，繼承自 SkillBase，代碼如下：

#============================================
# 「Sprint」 -  2020-9-13 00:08
# @author: Apprentice Zhang
#============================================

class_name Sprint
extends SkillBase

enum DIRECTION_TYPE {
	SELF_ANGLE,			# 自己面向的角度
	MOUSE_POS			# 滑鼠位置的角度
}

export (DIRECTION_TYPE) var direction_mode = DIRECTION_TYPE.SELF_ANGLE	# 沖刺方向方式
export (float) var speed = 700									# 沖刺速度（每秒沖刺多少像素距離）


var _vel: Vector2		# 沖刺的向量



#============================================
#		Override
#============================================
func cast_skill():
	.cast_skill()
	match direction_mode:
		DIRECTION_TYPE.SELF_ANGLE:
			_vel = Vector2(1, 0).rotated(_get_host_node().rotation) * speed		# 朝自己面向的角度沖刺的向量
		DIRECTION_TYPE.MOUSE_POS:
			_vel = self.global_position.direction_to(get_global_mouse_position()) * speed	# 朝滑鼠的位置沖刺的向量


func duration_process(delta: float):
	_get_host_node().position += _vel * delta

現在我們新建一個 2D 場景，根節點為 Node2D，將檔案夾中的勞模 —— Godot 小兄弟 拖入到場景中，然后按 Ctrl + A，輸入 Sprint，添加我們新建的「沖刺」技能節點，節點樹如下：

在這里插入圖片描述
設定「Sprint」節點的屬性，按下 ui_accept 就是空格或Enter鍵，就觸發這個技能，冷卻時間為 3 秒，沖刺持續 1 秒，每秒沖刺距離為 200，沖刺方向型別為滑鼠的方向，

這樣我們就做好了一個技能，讓我們按下 F5，選擇這個場景運行一下，

運行游戲后，我們按下空格鍵看看效果，是不是 Godot 向滑鼠位置沖刺了？😄

我們可以乘勝追擊，再做一個發射「霰彈」的技能節點 —— 「Canister」節點，我們新建一個腳本，寫入如下代碼：

#============================================
# 「Canister」 -  2020-9-12 00:34
# @author: Apprentice Zhang
#============================================

class_name Canister
extends SkillBase

# 添加節點的型別
enum ADD_TYPE {
	MAIN,		# 添加到當前游戲場景中
	HOST		# 添加到「宿主」節點上
}


export (ADD_TYPE) var add_mode = ADD_TYPE.MAIN		# 添加節點的方式
export (PackedScene) var bullet						# 子彈的型別
export (int, 1, 10000) var launches_num = 1			# 發射次數
export (float) var launches_interval = 0.2			# 每次發射間隔時間
export (int, 1, 10000) var add_num = 8				# 每次添加的個數，也就是發射的個數
export (float) var angular_start = -30				# 開始發射的節點角度
export (float) var angular_end = 30					# 發射結束的節點的角度


func cast_skill():
	if bullet == null:
		return
	
	.cast_skill()
	launches()
	for i in range(launches_num):
		# 間隔時間啟動「發射」技能
		get_timer_once(i * launches_interval, self, 'launches')


func launches() -> void:
	"""發射"""
	for i in range(add_num):
		var b = bullet.instance() as Node2D
		match add_mode:
			ADD_TYPE.HOST:
				_get_host_node().add_child(b)		# 添加到宿主的節點下
			ADD_TYPE.MAIN:
				get_tree().current_scene.add_child(b)	# 添加到當前游戲主場景中
		
		# 最開始時的角度
		b.global_rotation = _get_host_node().global_rotation
		# 角度偏移
		b.global_rotation += deg2rad(lerp(angular_start, angular_end, float(i) / add_num-1))
		# 子彈的位置為技能的「宿主」的位置
		b.global_position = _get_host_node().global_position

我們再做一個「子彈」節點，新建一個場景，直接將 icon 拖入到空的場景中，然后把他的 Position 屬性都歸零，把它的 Scale 屬性縮小到 0.2，如下，

在這里插入圖片描述
我們再把這個節點命名為 Bullet，保存，在這個節點上添加一個 Bullet 腳本，代碼內容如下：

extends Sprite

export (int) var speed = 700

func _ready() -> void:
	yield(get_tree().create_timer(1), "timeout")	# 等待 1 秒后，執行 queue_free() 
	queue_free()		# 洗掉自身

func _physics_process(delta: float) -> void:
	# 向自己面向的位置移動
	position += Vector2(1, 0).rotated(self.global_rotation) * speed * delta

好，我們的「子彈」就做好了，開始我們之前的游戲場景中的 Godot 添加「Canister」個節點，

在這里插入圖片描述
我們選中 Canister 節點，然后將檔案系統中做好的 Bullet 節點拖入到 Canister 節點的 Bullet 屬性中，再調整一下屬性，如下：

我們再運行一下，按下空格鍵看看效果，😃

邊沖刺，邊發射子彈，看完是不是覺得還挺簡單？哈哈，都動手試試吧，熟能生巧，😄

轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/55680.html

標籤：其他

上一篇：動態規劃演算法解題思路

下一篇：PAT乙級練習