一切混亂開端的透明效果——ShaderCp8-有解無憂

——20.8.18

Unity中，通常用兩種方法來實作透明效果 1）透明度測驗 2）透明度混合這兩個分別是什么呢

1.透明度測驗指的只要不符合條件（即在物體顏色中的alpha通道的值小于某一個閾值）對應片元會被直接舍棄，（該片元不會對顏色緩沖有任何影響）否則就按照不透明物體處理，進行深度測驗和深度寫入，特點：不關閉深度寫入沒法做到半透明要么不透明要么全透明

2.透明度混合指的是使用當前片元透明度為混合因子于已經儲存的在顏色快取中的顏色進行混合，要關閉深度寫入不關閉深度測驗，通過深度測驗能夠正確的確定非透明物體于透明物體之間的覆寫關系，特點：關閉深度寫入做到半透明

在我們對上面兩個定義進行下一步解讀之前先回顧兩個概念深度寫入以及深度測驗兩者發生的程序是在GPU渲染的時候發生的，即下面這張圖的關系

深度測驗就是通過攝像機與該片元的距離（也就是深度）于之前存在深度快取區的深度值進行比較對應的條件來決定是否舍棄該片元 ZTest

深度寫入則是是否要將深度測驗的結果覆寫到深度快取區中因為半透明物體的存在是不可以作為深度的標準來舍棄因為半透明物體與其他物體是疊加的關系的 ZWrite

接著我們就可以引入一個新的重要性的問題就是渲染順序這是在Tags中的一個元素 “Queue”

因為我們對半透明物體關閉了深度寫入的操作則對我們的渲染順序有一定的要求也就是在關閉了深度寫入的條件下渲染順序的正確與否便是十分重要因為會引發兩個問題 1）對非透明物體與半透明物體之間因為關閉了深度寫入，當半透明物體先渲染由于深度快取為空則非透明物體直接覆寫 2）半透明物體與半透明物體之間渲染順序如果與深度一致（由近到遠）則導致看上去位置相反

常用方法：1.先渲染所有不透明物體開啟深度測驗與寫入（“Queue”=“Geometry”） 2.把半透明物體由遠到近順序渲染并開啟深度測驗關閉寫入（“Queue”=“AlphaTest“）

但依舊還是有問題所以才叫做混亂的開端因為存在重疊現象一個物體有兩個渲染順序（每個像素都有深度，逐像素去遍歷無法選取）便采取分割網格并且務必使用凸面體需要具體問題具體分析

下面就是久違的ShaderLab部分了，我的想法是堅決不做搬運工，下面的部分直接選取部分代碼說自己的理解還是要自己敲一遍最后再上原始碼雖然上面部分就是書上的用我的理解包括一些大佬的理解順序也很像書上的順序就是慢慢改進吧嘿嘿

一、透明度測驗

void Clip(x) x:float4,float3,flaot2,float
void Clip（float4 x）
{
　　if(any(x < 0))
　　　　discard;
}

　　引數x是裁剪時所使用的標量或矢量

　　如果給定引數的任何一個分量是負數則直接舍棄該像素

Tags { "RenderType"="TransparentCutOut" "Queue"="AlphaTest" "IgnoreProjector"="True" }

　　樣例給的要點主要有要在SubShader中設定”Queue“為了透明度測驗 ”IgnoreProjector“為了設定不受到投影器的影響

clip(texColor.a - _Cutoff);

　　內部引數為原影像的透明度減去_Cutoff(為能接受的閾值) 當這個值小于0則直接discard

原始碼：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unlit/8-1AlphaTest"
{
    Properties
    {
		_Color("Color", Color) = (1,1,1,1)
        _MainTex ("Texture", 2D) = "white" {}
		_Cutoff ("Alpha Cutoff", Range(0, 1)) = 0.5
    }
    SubShader
    {
        Tags { "RenderType"="TransparentCutOut" "Queue"="AlphaTest" "IgnoreProjector"="True" }
        Pass
        {
			Tags{ "LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
			fixed4 _Color;
			fixed _Cutoff;

            v2f vert (appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed4 texColor = tex2D(_MainTex, i.uv);
				clip(texColor.a - _Cutoff);
				fixed3 albedo = texColor.rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				fixed3 diffuse = _LightColor0 * albedo * saturate(dot(worldNormal, worldLightDir));
				return fixed4(diffuse + ambient, 1.0);
            }
            ENDCG
        }
    }FallBack "Transparent/Cutout/VertexLit"
}

二、透明度混合

說到混合就要講混合指令Blend

采用的是以下的公式源顏色就是該片元的顏色目標顏色就是顏色快取的顏色

ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha

　　要關閉深度寫入同時開啟混合（設定的時候即開啟）如果不打開blend默認是關閉的就以深度測驗的結構決定直接覆寫A=1（？沒找到依據但實驗結果如此）

原始碼：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Unlit/8-2AlphaBlend"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
		_Color ("Color", Color) = (1,1,1,1)
		_AlphaScale ("AlphaScale", Range(0,1)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" "IgnoreProjector"="True" "Queue"="Transparent" }
        Pass
        {
			Tags { "LightMode"="ForwardBase" }
			ZWrite Off
			Blend SrcAlpha OneMinusSrcAlpha 
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

           struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
			fixed4 _Color;
			fixed _AlphaScale;

            v2f vert (appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed4 texColor = tex2D(_MainTex, i.uv);
				fixed3 albedo = texColor.rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(worldNormal, worldLightDir));
				return fixed4(ambient + diffuse, texColor.a * _AlphaScale);
            }
            ENDCG
        }
    }FallBack "Transparent/VertexLit"
}

三、開啟深度寫入的半透明

我們可以看一下上面這個圖可以發現這個圖全露出就是當模型存在互相交叉的時候會得到這樣錯誤的效果本質的原因就是沒有打開深度寫入導致的單物體內部錯誤那有什么解決方方能就是用雙Pass 第一個Pass把最前面的輸出片元的深度值通過比較后存入深度快取中但不輸出顏色第二個Pass再關閉深度寫入可以直接和正確的比較直接discard

ColorMask 0 | RGB | G |

　　設定顏色通道的寫掩碼就是指定輸出的顏色通道 0就是不輸出

原始碼：

Shader "Unlit/8-3AlphaBlendZWrite"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
		_Color ("Color", Color) = (1,1,1,1)
		_AlphaScale ("AlphaScale", Range(0, 1)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" "IgnoreProjector"="True" "Queue"="Transparent" }

		Pass{
			ZWrite On
			ColorMask 0
		}

       Pass
        {
			Tags { "LightMode"="ForwardBase" }
			ZWrite Off
			//Alpha Blend
			Blend SrcAlpha OneMinusSrcAlpha
			//Soft Additive
			//Blend OneMinusDstColor One
			//Multiply
			//Blend DstColor Zero
			//Multiply 2X
			//Blend DstColor SrcColor
			//Darken
			//BlendOp min
			//Blend One One
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

           struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
			fixed4 _Color;
			fixed _AlphaScale;

            v2f vert (appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed4 texColor = tex2D(_MainTex, i.uv);
				fixed3 albedo = texColor.rgb * _Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(worldNormal, worldLightDir));
				return fixed4(ambient + diffuse, texColor.a * _AlphaScale);
            }
            ENDCG
        }
    }FallBack "Diffuse"
}

這張圖有一點奇怪就是存在投影，可以看Cp9的半透明投影部分主要是FallBack設定，

四、雙面渲染的透明效果

這個是最后的內容啦加加油也就是剔除渲染圖元的關系默認的情況下為了節約資源只渲染證明不渲染背面我們則需要用指令打開

Cull off | back | Front

　　設定back不渲染back 設定off就是都渲染

那么對應的透明度測驗的雙目渲染我直接放圖代碼便是在以上基礎上在Pass里面添加以上指令

可以明顯對比

然后就是透明度混合的雙目渲染比上述的麻煩了一點就是雙Pass 先渲染背面后渲染正面因為從視角看上去避免了之前說的半透明物體與半透明物體之間因為渲染順序的導致的問題可以直接比較一下畢竟圖形學是效果的學科看看啥效果就知道了

可以很明顯看出第二個比第一個有了對面的背面（奇妙的比喻）也就是雙目渲染第三個則是渲染順序相反背面先渲染攝像機進入物體能看到顏色鮮艷的正面

最后最后留個小坑就是BlendOp 我也沒太看懂可能需要具體例子才會用吧只有一些效果

謝謝你看到最后 cheers！

ps.剛剛看完Shader入門Cp8記錄記錄一些細碎的知識點以及相關深度研究學習

轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/557.html

標籤：其他

上一篇：【短道速滑四】Halcon的texture_laws算子自我研究

下一篇：記一次 glTF 模型的繪制性能提升：從ppt到dove，絲滑感受