DAX教程：籃子分析2.0-有解無憂

作者|Davis Zhang
編譯|VK
來源|Towards Data Science

本文旨在利用DAX分析Power-BI中的客戶購買行為，并深入了解產品潛力，

幾年前，Marco Russo和Alberto Ferrari發表了一篇名為“籃子分析”的博客

https://www.daxpatterns.com/basket-analysis/

這篇有趣的文章詳細描述了如何使用DAX計算任何產品組合下的訂單數量和客戶數量等非常有用的指標，本文可以看作是“籃子分析”的一個擴展，它考慮了顧客購買不同產品的時間順序，

與原始的“籃子分析”相比

假設A和B代表兩種不同的產品，那么“籃子分析”計算P(AB)，而本文計算P(A|B)和P(B|A)，你可以比較下面的兩個數字：

上圖是“籃子分析”中“兩種產品都有顧客”的衡量標準，顯示72位顧客同時擁有“瓶籠”和“自行車架”的購買記錄，

但是，下圖中顯示的資料考慮了客戶購買產品的時間順序，你可以發現，先購買自行車架后購買瓶、籠的客戶有8家，先購買瓶、籠后購買自行車架的客戶有14家(注：暫時不考慮同時購買A、B的情況)

為什么這個分析有意義

客戶的訂單記錄反映了一些非常有用的事實，為產品之間的相關性提供了方向，換言之，“購物籃分析”在分析超市資料時非常有用，因為顧客通常在購物時選擇多種產品，然后到收銀臺一起下訂單，

在這種情況下，所有產品都被視為同時訂購，但事實上，在超市購物程序中，顧客選擇的不同產品的記錄是無法追蹤的，

但如果是在其他情況下，比如客戶在電子商務平臺或官網上下單，如果你是店長，你可能想知道A和B是最暢銷的車型，哪一款可以帶來更多的回頭客，哪一款更容易流失客戶，

因此，我們需要知道每種產品的回購百分比，例如，所有先購買產品A的顧客，未來會有多少人再回來購買產品，進一步分析，在這些人中，購買的仍然是產品A或其他產品？各占多少比例，這是一個值得研究的問題，

計算程序

經過計算程序，我們最終將得到如下圖所示的計算結果(注：我使用與“籃子分析”相同的資料集)：

如前所述，它顯示了哪些客戶先購買了產品A并有后續的購買記錄，他們中有多少人購買了產品B或產品C等，

因此，為了達到這個計算結果，這里有五個步驟：

1.首先，對銷售表中的所有訂單進行分類，在客戶的所有訂單中，一個或多個訂單日期最早的訂單被分類為第一個訂單，其余的為“非第一”：

IsFirstOrder = 
VAR
E_Date = 'Sales'[OrderDateKey]
VAR
CUST = 'Sales'[CustomerKey]
RETURN
IF(
    SUMX(
        FILTER('Sales',
        CUST = 'Sales'[CustomerKey]&&
        E_Date > 'Sales'[OrderDateKey]),
        COUNTROWS('Sales'))>0,FALSE,TRUE)

2.過濾銷售中所有產品A的訂單資料，然后進一步過濾哪些訂單被標記為客戶的第一個訂單，我們在此過濾表中提取客戶串列，并向其添加一個名為“ROWS”的虛擬列，得到虛擬表VT1，

3.使用Sales作為主表，并使用NATURALLEFTOUTERJOIN()與虛擬表“VT1”關聯，然后使用filter()排除[ROWS]值不等于1的行，其余資料(VT2)是“VT1”回傳的所有客戶的所有訂單，最后，對除“一階”外的所有訂單進一步過濾資料，結果命名為“CustDistinctValue”：

CustDistinctValue = 
https://www.cnblogs.com/panchuangai/p/VAR
FIRSTORDERPROD = 
IF(HASONEVALUE('Product'[Subcategory]),
    VALUES('Product'[Subcategory]),0)
VAR
VT1 = 
SUMMARIZE(
    FILTER(Sales,
        AND(related('Product'[Subcategory]) = FIRSTORDERPROD,
            'Sales'[IsFirstOrder]=TRUE)),
        'Sales'[CustomerKey],
        "ROWS",
        DISTINCTCOUNT(Sales[CustomerKey]))
VAR
VT2 = 
FILTER(
    NATURALLEFTOUTERJOIN(ALL(Sales),VT1),
    [ROWS] = 1)
RETURN
CALCULATE(
    DISTINCTCOUNT('Sales'[CustomerKey]),
    FILTER(VT2,'Sales'[IsFirstOrder] = FALSE)
)

4.之后，我們需要確保這些資料可以按產品進行過濾(在這種情況下，我們只使用子類別)，這里與宏的計算方法基本相同，使用產品表(Filter product)和主表的副本建立非活動關系，然后創建一個度量值，以便其背景關系忽略產品表的所有欄位，并從其副本(Filter product)接受背景關系，

CustPurchaseOthersSubcategoryAfter = 
VAR CustPurchaseOthersSubcategoryAfter = 
CALCULATE (
    'Sales'[CustDistinctValue],
    CALCULATETABLE (
        SUMMARIZE ( Sales, Sales[CustomerKey] ),
        'Sales'[IsFirstOrder] = FALSE,
        ALLSELECTED ('Product'),
        USERELATIONSHIP ( Sales[ProductCode],
             'Filter Product'[Filter ProductCode] )
    )
)
RETURN
IF(NOT([SameSubCategorySelection]),
    CustPurchaseOthersSubcategoryAfter)

注：“SameSubCategorySelection”用于排除選擇相同子類別的資料，此公式還使用宏的方法來完成：

SameSubCategorySelection = 
IF (
    HASONEVALUE ( 'Product'[Subcategory] )
        && HASONEVALUE ( 'Filter Product'[Filter Subcategory] ),
    IF (
        VALUES ( 'Product'[Subcategory])
            = VALUES ( 'Filter Product'[Filter Subcategory] ),
        TRUE
    )
)

5.現在，我們已經計算出購買產品A的客戶中有多少人首先購買了其他產品，現在我們需要計算出這些客戶占購買產品A的客戶總數的比例，然后才有購買記錄，以下是計算該比例分母的代碼，

AsFirstOrderCust = 
VAR
FIRSTORDERPROD = 
IF(
    HASONEVALUE('Product'[Subcategory]),
    VALUES('Product'[Subcategory]),0)
VAR
VT1 = 
SUMMARIZE(
    FILTER(Sales,
        AND(
            RELATED('Product'[Subcategory]) = FIRSTORDERPROD,
                'Sales'[IsFirstOrder]=TRUE)),
            'Sales'[CustomerKey]
)
return
CALCULATE(
    DISTINCTCOUNT('Sales'[CustomerKey]),
    VT1)
-------------------------------------------------------------------------------
IsLastOrder = 
VAR
E_Date = 'Sales'[OrderDateKey]
VAR
CUST = 'Sales'[CustomerKey]
RETURN
IF(
    SUMX(
        FILTER('Sales',
        CUST = 'Sales'[CustomerKey]&&
        E_Date < 'Sales'[OrderDateKey]),
        COUNTROWS('Sales'))>0,"F","T")
-------------------------------------------------------------------------------
AsFirstOrderCustRepurchase = 
CALCULATE(
    'Sales'[AsFirstOrderCust],
    'Sales'[IsLastOrder] = "F")

現在我們得到了最終的結果:CustPurchaseOthersSubCategoryAfter %，這個度量的名稱很長，因為它的邏輯很復雜，就像上面的計算程序一樣，

CustPurchaseOthersSubCategoryAfter % = 
DIVIDE ( 'Sales'[CustPurchaseOthersSubcategoryAfter],
    'Sales'[AsFirstOrderCustRepurchase])

最終結果

最后，我們將成功獲得如下的最終結果，并選擇使用名為“CHORD”的自定義視覺效果將其可視化，

如你所見，首先購買公路自行車的顧客中，1853人后來購買了山地自行車，而有趣的是，只有200名顧客在購買了山地自行車之后購買了公路自行車，

附上了PBIX檔案，如果你有興趣的話可以在這里下載，

https://1drv.ms/u/s!AjpQa2fseaxaoDLeh4yBlBSaa-qx

原文鏈接：https://towardsdatascience.com/explore-the-potential-of-products-through-customers-purchase-behaviour-in-power-bi-basket-a1f77e8a2bf6

歡迎關注磐創AI博客站：
http://panchuang.net/

sklearn機器學習中文官方檔案：
http://sklearn123.com/

歡迎關注磐創博客資源匯總站：
http://docs.panchuang.net/

轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/6838.html

標籤：其他

上一篇：MNIST資料集下載及可視化

下一篇：如何在視頻中的物件后面添加影像