使用VBA決議JSON物件和集合

uj5u.com熱心網友回復：

請注意，我已經使用 key 作為字典鍵和 label 作為值交換了字典條目，因為 label 不是唯一的（就示例 JSON 而言）并且會導致錯誤（或覆寫先前的條目，具體取決于實作）。

您的使用On Error Resume Next應避免（這適用于任何情況下，除非你使用的是它在其上很少用到的目的），你基本上隱藏所有可能的錯誤，這可能會導致你的代碼產生意外結果。您可以使用陳述句中的Exists方法If..Else..End If首先檢查字典鍵是否存在，只有在存在時才執行任務。

編輯- 更新代碼以處理新舊 JSON 格式

Private Sub Test()
    '==== Change this part according to your implementation..."
    Dim jsontxt As String
    jsontxt = OpenTxtFile("D:/TestJSON2.txt")
    '====

    Dim jSon As Scripting.Dictionary
    Set jSon = JsonConverter.ParseJson(jsontxt)
            
    'Check if first level of components exist and get the collection of components if true
    If jSon.Exists("components") Then
        Dim components As Collection
        Set components = jSon("components")
    
        Dim Dict As Scripting.Dictionary
        Set Dict = New Scripting.Dictionary
        
        Dim comFirst As Variant
        Dim comSecond As Variant
        Dim comThird As Variant
        Dim columnsDict As Variant
        Dim valDict As Variant
                    
        For Each comFirst In components
            'extract key-label from first level component
            If Not Dict.Exists(comFirst("label")) Then Dict.Add comFirst("label"), comFirst("key")
            
            '     New JSON Format     
            '==== Check if second level of "components" key exist and extract label-key if true
            If comFirst.Exists("components") Then
                For Each comSecond In comFirst("components")
                    If Not Dict.Exists(comSecond("label")) Then Dict.Add comSecond("label"), comSecond("key")
                                    
                    '=== Check if "columns" key exist and extract the key-label if true
                    If comSecond.Exists("columns") Then
                        For Each columnsDict In comSecond("columns")
                        
                            '==== Check if third level of "components" key exist and extract key-label if true
                            If columnsDict.Exists("components") Then
                                For Each comThird In columnsDict("components")
                                    If Not Dict.Exists(comThird("label")) Then Dict.Add comThird("label"), comThird("key")
                                    
                                    '==== Check if "values" key exist and extract label-value if true
                                    If comThird.Exists("values") Then
                                        For Each valDict In comThird("values")
                                            If Not Dict.Exists(valDict("label")) Then Dict.Add valDict("label"), valDict("value")
                                        Next valDict
                                    End If
                                    '====
                                    
                                Next comThird
                            End If
                            '====
                            
                        Next columnsDict
                    End If
                    '====
                    
                    '==== Check if "values" key exist and extract the label-value if true
                    If comSecond.Exists("values") Then
                        For Each valDict In comSecond("values")
                            If Not Dict.Exists(valDict("label")) Then Dict.Add valDict("label"), valDict("value")
                        Next valDict
                    End If
                    '====
                Next comSecond
            End If
            '    
            
            '     Old JSON format     
            '==== Check if "data" key exist and extract the label-value if true
            If comFirst.Exists("data") Then
                If comFirst("data").Exists("values") Then
                    For Each valDict In comFirst("data")("values")
                        If Not Dict.Exists(valDict("label")) Then Dict.Add valDict("label"), valDict("value")
                    Next valDict
                End If
            End If
            '====
            
            '==== Check if "values" key exist and extract the label-value if true
            If comFirst.Exists("values") Then
                For Each valDict In comFirst("values")
                    If Not Dict.Exists(valDict("label")) Then Dict.Add valDict("label"), valDict("value")
                Next valDict
            End If
            '====
            '    
        Next comFirst
    End If
End Sub

uj5u.com熱心網友回復：

嘗試這個：

https://github.com/VBA-tools/VBA-JSON

您需要在您的專案中匯入檔案“JsonConverter.bas”，然后按照 README.md 檔案中的示例進行操作

標籤：arrays json vba object parsing

上一篇：Lua中的物件表

下一篇：是否可以通過某些屬性的值過濾嵌套物件？（JS）