Oracle 存盤程序學習總結-有解無憂

創建/更新存盤程序

基礎基礎用法

創建/修改無參存盤程序

CREATE OR REPLACE PROCEDURE procedure_name [IS|AS]
--宣告全域變數(可選)
BEGIN
--存盤程序的執行體
END; --也可以寫成 END procedure_name;

創建/修改攜引數存盤程序

CREATE OR REPLACE PROCEDURE procedure_name(var_name1 IN type, var_name2 IN type,...,var_nameN OUT type) [IS|AS]
--宣告全域變數(可選)
BEGIN
--存盤程序的執行體
END; --也可以寫成 END procedure_name;

說明：IN 表示輸入引數，OUT表示輸出引數，比如存盤回傳值的變數，IN OUT 表示輸入輸出引數（注：都不區分大小寫）

注意：

存盤程序引數資料型別不能指定長度
OUT、IN OUT 模式引數的呼叫，必須通過變數實作

呼叫存盤程序

--呼叫帶引數存盤程序
CALL procedure_name([引數串列]);
--或者
BEGIN procedure_name(引數串列); END; --注意 分號不能少，特別是END后面的分號
--或者
SQL> EXEC procedure_name(引數串列);  --在命令列視窗執行，比如SQLPlus執行視窗

--呼叫不帶引數存盤程序
CALL procedure_name();
--或者
BEGIN procedure_name; END; --注意 分號不能少，特別是END后面的分號
--或者
BEGIN procedure_name(); END; --注意 分號不能少，特別是END后面的分號
--或者
SQL> EXEC procedure_name;

簡單的示例

創建攜帶引數存盤程序

CREATE OR REPLACE PROCEDURE SP_TEST_PROC(workDate IN Date) is
BEGIN
dbms_output.put_line('The input date is:'||to_date(workDate,'yyyy-mm-dd'));
END;

CALL SP_TEST_PROC(sysdate); --輸出：The input date is:22-AUG-24

--創建攜帶回傳值存盤程序
CREATE OR REPLACE PROCEDURE SP_SUM_PROC(number1 IN NUMBER, number2 IN NUMBER, result OUT NUMBER) is
BEGIN
result := number1 + number2;
END;

-- sql視窗中呼叫
DECLARE res NUMBER(6);
BEGIN 
  SP_SUM_PROC(1, 3, res); 
  dbms_output.put_line(res); --輸出：4
END; 

-- 命令列視窗中呼叫
SQL> VARIABLE res NUMBER;
SQL> EXEC SP_SUM_PROC(1, 3, :res);
PL/SQL procedure successfully completed
res
---------
4

--創建帶輸入輸出引數的存盤程序
CREATE OR REPLACE PROCEDURE SP_SUM_PROC(number1 IN NUMBER, number2 IN OUT NUMBER) is
BEGIN
number2 := number1 + number2;
END;

-- 呼叫
DECLARE num NUMBER(6) :=3; --注意，不能在存盤程序中宣告變數時這樣賦值
BEGIN 
  dbms_output.put_line('呼叫前num變數值：' || num); --輸出：呼叫前num變數值：3
  SP_SUM_PROC(1, num); 
  dbms_output.put_line('呼叫后num變數值：' || num); --輸出：呼叫后num變數值：4
END;

DECLARE基礎用法說明

可以在BEGIN關鍵字之前，使用DECLARE定義、宣告區域變數，宣告基礎用法如下：

DECLARE 變數名[,變數名2...] 資料型別(含長度、精度） [DEFAULT value]; --沒有使用DEFAULT子句時，默認值為NULL

示例：

DECLARE num INT  DEFAULT 10; --宣告變數 num，資料型別為INT型，默認值為10
DECLARE usrname VARCHAR2(15) DEFAULT 'tester'; --宣告變數 username,默認值為tester
DECLARE age, num int； -- 定義多個變數
DECLARE length, width NUMBER(18,2) DEFAULT 10; -- 宣告變數 length, width，默認值都為10
BEGIN
-- do something
END;

創建無引數存盤程序

CREATE OR REPLACE PROCEDURE SP_TEST_PROC is
BEGIN
dbms_output.put_line('hello, tester');
END;

--呼叫
CALL SP_TEST_PROC(); --輸出：hello, tester
--或者
BEGIN
SP_TEST_PROC;
END;

宣告全域變數

方式一：直接宣告資料型別

格式：變數名資料型別(大小及精度)

示例：

v_username VARCHAR2(15);
v_num NUMBER(9,2);

方式二：使用%TYPE宣告

格式：變數名表名.欄位名%TYPE

含義：該變數的資料型別與指定表的指定欄位的資料型別一致

示例：

r_carrierID  CARRIERS.carrier_id%type;

方式三：使用%ROWTYPE宣告

格式：變數名表名%ROWTYPE

含義：該變數的資料型別與指定表的指定行記錄（所有欄位）的資料型別一致

示例：

V_row_user USERS%ROWTYPE;　--V_row_user存放整行資料

注：不管使用哪種宣告方式，變數名都不區分大小寫，以字母開頭；此外，變數的宣告必須在BEGIN關鍵字之前進行，

變數賦值

方式一：使用":="直接賦值

注意，這種方式不適合使用%ROWTYPE宣告的變數

示例：

v_username := 'shouke';

我們可以在宣告變數的同時對變數進行賦值，

v_username VARCHAR2(15) := 'shouke'

方式二：select 表欄位 into 變數 from 表

1：查詢指定表的某些指定欄位　　

不適合使用%ROWTYPE宣告的變數

SELECT field1,field2,...,field3 INTO varName1,varName2,...,varNameN FROM tableName;

2：查詢指定表的所有欄位　　

SELECT * INTO v_row_varName FROM tableName; --其中v_row_varName為使用%ROWTYPE宣告的變數

注意：使用這種方式給使用%ROWTYPE宣告的變數賦值時，查詢結果只能回傳一條記錄，且查詢結果必須包含該表的所有欄位，

變數宣告與賦值示例

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
v_username VARCHAR2(15);
v_companyCode NUMBER(9,2);
v_erpOrderNo EFFECTIVE_OMS_MSG_FOR_TEST.erp_Orderno%TYPE;
v_record EFFECTIVE_OMS_MSG_FOR_TEST%ROWTYPE;
BEGIN
  v_username := 'shouke';
  SELECT request_msg_id INTO v_companyCode FROM EFFECTIVE_MSG_FOR_TEST WHERE rownum <2;
  SELECT erp_orderno INTO v_erpOrderNo FROM EFFECTIVE_MSG_FOR_TEST WHERE rownum <2;
  SELECT * INTO v_record FROM EFFECTIVE_MSG_FOR_TEST WHERE rownum <2;

  dbms_output.put_line('v_username: ' || v_username);
  dbms_output.put_line('v_companyCode: ' || v_companyCode);
  dbms_output.put_line('v_erpOrderNo: ' || v_erpOrderNo);
  dbms_output.put_line('v_record.company_code: ' || v_record.company_code); 

END;

call SP_TEST_PROC();

注意：

采用變數名.表欄位名的方式來參考通過%ROWTYPE宣告的變數
不能直接使用變數名作為查詢列，錯誤用法形如 SELECT v_erpOrderNo FROM EFFECTIVE_MSG_FOR_TEST;

一個應用實體

--創建序列
CREATE SEQUENCE check_orders_seq
increment By 1 
start With 1
Maxvalue 2000
Minvalue 1
cycle
Nocache;

--創建存盤程序
CREATE OR REPLACE PROCEDURE "SP_GET_CHECK_ORDERS_FOR_TEST" (IN_serverID IN VARCHAR2, IN_rowLimit IN INT, OUT_returnCode OUT VARCHAR2)
IS
sqlStr VARCHAR2(5000);
BEGIN
  OUT_returnCode := '000';

  --將揀貨完成未復核，且未在臨時表check_orders_for_test的訂單拉入臨時表
  sqlStr := 'insert into check_orders_for_test(warehouseID, orderNo, rangeNo, checkFlag, serverID) select h.warehouseID, h.orderNo, check_orders_seq.nextval rangeNo, ''N'' checkFlag,'''||IN_serverID||''' serverID 
               from doc_order_header h 
               where h.sostatus = ''60'' 
               and exists (select 1 from act_allocation_details a 
                           where a.orderNo = h.orderNo
                           and a.packflag = ''N'') 
               and not exists (select 1 from check_orders_for_test m 
                               where m.orderno = h.orderno) 
               and rownum <= '||IN_rowLimit;
  execute immediate sqlStr;
  commit;
  Return;
EXCEPTION
  WHEN OTHERS THEN
    OUT_returnCode := 'SP_GET_CHECK_ORDERS_FOR_TEST' || SQLerrm; 
    dbms_output.put_line(OUT_returnCode);
    ROLLBACK;
END;

說明：兩個''表示一個'

執行體之邏輯判斷陳述句

IF陳述句

基礎用法

IF 條件運算式 THEN
  -- do something
END IF;

IF 條件運算式 THEN
  -- do something
ELSE
  -- do something
END IF;

IF 條件運算式 THEN
  -- do something
ELSIF 條件運算式 THEN
  -- do something
... --表省略，支持更多的ELSIF
ELSE --子句可選
  -- do something
END IF;

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC(num IN NUMBER) IS
BEGIN
  --如果num為1，則輸出true
  IF num=1 THEN
    BEGIN
      dbms_output.put_line('true');
    END;
  END IF;
END;

CALL SP_TEST_PROC(1);


CREATE OR REPLACE PROCEDURE SP_TEST_PROC(num IN NUMBER) IS
BEGIN
  IF NUM=1 THEN --如果num為1，則輸出 true
    dbms_output.put_line('true');
  ELSE --否則輸出 false
    dbms_output.put_line('false');
  END IF;
END;


CREATE OR REPLACE PROCEDURE SP_TEST_PROC(num IN NUMBER) IS
BEGIN
  IF NUM=1 THEN --如果num為1，則輸出 true
    dbms_output.put_line('true');
  ELSIF NUM=0 THEN --否則，如果num為2，則輸出 false
    dbms_output.put_line('false');
  ELSE --否則輸出 invalid num
    dbms_output.put_line('invalid num');
  END IF;
END;

CASE WHEN陳述句

基礎用法

CASE 
  WHEN num=1 THEN 
    --do something
  WHEN num=2 THEN 
    --do something
  ... --表省略，支持更多的WHEN
  ELSE 
    --do something
END CASE;

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC(num IN NUMBER) IS
BEGIN
  CASE 
    WHEN num=1 THEN  --如果num為1，則輸出 true
      dbms_output.put_line('true');
    WHEN num=2 THEN  --如果num為1，則輸出 false
      dbms_output.put_line('false');
    ELSE --否則輸出 invalid num
      dbms_output.put_line('invalid num');
  END CASE;
END;

執行體之回圈遍歷陳述句

FOR回圈

基礎用法

FOR var IN range LOOP
--do something
END LOOP;

--遍歷查詢結果集
FOR row IN (查詢陳述句) LOOP
--do something
END LOOP;

--回圈遍歷陣列

--回圈遍歷游標（使用示例參見下文 執行體之游標）

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
BEGIN
  -- FOR i IN REVERSE 0..5 LOOP --REVERSE 采用逆序，從大到小，i取值從5到0
  FOR i IN 0..5 LOOP -- i取值從0到5
    dbms_output.put_line('運行第' || i || '次');
  END LOOP;
END;

CALL SP_TEST_PROC();

運行輸出：

運行第0次
運行第1次
運行第2次
運行第3次
運行第4次
運行第5次

遍歷查詢結果集

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
BEGIN
  FOR cur_row IN (SELECT request_msg_id, erp_orderno FROM effective_oms_msg_for_test WHERE ROWNUM<5)
  LOOP
    dbms_output.put_line('msg_id: ' || cur_row.request_msg_id || ' orderno: ' || cur_row.erp_orderno);    
  END LOOP;
END;

CALL SP_TEST_PROC();

WHILE回圈

基礎用法

WHILE 條件陳述句 LOOP
-- do something
END LOOP;

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
i INT :=1 ;
BEGIN
  WHILE i < 3 LOOP
    dbms_output.put_line('運行第' || i || '次');
    i := i + 1;
  END LOOP;
END;

CALL SP_TEST_PROC();

呼叫輸出

運行第1次
運行第2次

LOOP回圈

基礎用法

LOOP
  --do something
  IF 退出回圈條件 THEN
    --do something
    EXIT;
  END IF;
  --do something
END LOOP;

LOOP
  --do something
  EXIT WHEN 退出回圈條件;
  --do something
END LOOP;

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
i INT :=1;
BEGIN
  LOOP
    IF i=3 THEN --如果i=3,則退出
      EXIT;
    END IF;
    dbms_output.put_line('運行第' || i || '次');
    i := i + 1;
  END LOOP;
END;

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
i INT :=1;
BEGIN
  LOOP
    EXIT WHEN i = 3;
    dbms_output.put_line('運行第' || i || '次');
    i := i + 1;
  END LOOP;
END;

呼叫結果，同上述WHILE回圈示例

執行體之GOTO跳轉陳述句

基礎用法

<<gotoLabel>>
-- do something
GOTO gotoLabel;

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
i int := 1;
BEGIN
  <<loop_lable>>
  dbms_output.put_line('運行第' || i || '次');
  i := i + 1;
  IF i < 3 THEN
    GOTO loop_lable;
  END IF;
END;

呼叫結果，同上述WHILE回圈示例

說明：如上，我們也可以利用GOTO陳述句來實作回圈

執行體之游標

基礎用法

CURSOR型游標

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
CURSOR cursor_name IS 查詢陳述句;  -- 定義CURSOR型別游標(不能用于引數傳遞)
BEGIN
    FOR varName IN cursor_name LOOP 
    --do something --參考變數 varName.field
    END LOOP;
END;

注意：通過以上方式，采用FOR回圈遍歷游標，會自動關閉游標，不需要在END LOOP; 后添加關閉游標的代碼CLOSE cursor_name;，會報錯

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
CURSOR cursor_for_msgs IS SELECT request_msg_id, erp_orderno FROM effective_msg_for_test WHERE ROWNUM<5;
BEGIN
  FOR msg IN cursor_for_msgs LOOP
    dbms_output.put_line('msg_id: ' || msg.request_msg_id || ' orderno: ' || msg.erp_orderno);
  END LOOP;
END;

SYS_REFCURSOR型游標

SYS_REFCURSOR型游標，該游標是Oracle以預先定義的游標，可作出引數進行傳遞

基礎用法

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
v_cursor_name SYS_REFCURSOR ;
--變數定義
BEGIN
  OPEN v_cursor_name FOR 查詢陳述句;
  LOOP
    FETCH v_cursor_name INTO 變數1, 變數2, ..., 變數N; --變數個數和查詢結果記錄包含的欄位數量保持一致
    EXIT WHEN v_cursor_name%NOTFOUND;
  END LOOP;
  CLOSE v_cursor_name; 
END;

說明： SYS_REFCURSOR中可使用三個狀態屬性：

%NOTFOUND 表示未找到記錄資訊
%FOUND 表示找到記錄資訊
%ROWCOUNT 表示當前游標所指向的行位置
%ISOPEN 如果游標已經打開，則回傳TRUE，否則回傳FALSE

注意：

SYS_REFCURSOR游標只能通過OPEN方法來打開和賦值
SYS_REFCURSOR游標只能通過FETCH INTO方法來遍歷取值

示例

CREATE OR REPLACE PROCEDURE SP_TEST_PROC IS
v_cursor_for_msgs SYS_REFCURSOR ;
v_request_msg_id VARCHAR2(20);
v_erp_orderno VARCHAR2(50);
BEGIN
  OPEN v_cursor_for_msgs FOR SELECT request_msg_id, erp_orderno FROM effective_msg_for_test WHERE ROWNUM<5;
  LOOP
    FETCH v_cursor_for_msgs INTO v_request_msg_id, v_erp_orderno;
    EXIT WHEN v_cursor_for_msgs%NOTFOUND;
    dbms_output.put_line('msg_id: ' || v_request_msg_id || ' orderno: ' || v_erp_orderno);    
  END LOOP;
  -- 注意，上述回圈執行完成后，Orable并沒有自動關閉游標，需要顯示關閉游標
  IF v_cursor_for_msgs%ISOPEN THEN
    dbms_output.put_line('CLOSING CURSOR');
    CLOSE v_cursor_for_msgs;
  END IF;  
END;

顯示關閉游標

CLOSE cursor_name;

洗掉存盤程序

基礎語法

DROP PROCEDURE procedure_name;

作者：授客
微信/QQ：1033553122
全國軟體測驗QQ交流群：7156436
Git地址：https://gitee.com/ishouke
友情提示：限于時間倉促，文中可能存在錯誤，歡迎指正、評論！
作者五行缺錢，如果覺得文章對您有幫助，請掃描下邊的二維碼打賞作者，金額隨意，您的支持將是我繼續創作的源動力，打賞后如有任何疑問，請聯系我!!!
微信打賞支付寶打賞全國軟體測驗交流QQ群

轉載請註明出處，本文鏈接：https://www.uj5u.com/shujuku/519099.html

標籤：其他

上一篇：MySQL資料庫規范

下一篇：ClickHouse(08)ClickHouse表引擎概況