我正在嘗試制作一個公式，它將取消一些價格資料，稍后會有幾列額外的資料，包括一些 SKU 資料，然后是 3 列價格，3 列凈價，以及折扣金額/單位大小每個對應的行。
目前，只是試圖讓一小部分適用于公式的基礎，我讓它正常作業，但只適用于串列中 3 個 SKU 中的 1 個。我如何調整此 LAMBDA 以使所有 3 個 SKU 都采用相同的格式？這是我目前正在使用的 LAMBDA：
=LAMBDA(SKU_col,FL_cols,
LET(SCT,COUNTA(SKU_col)-2,
SKUA,INDEX(SKU_col,3,1):INDEX(SKU_col,SCT,1),
FLC,INDEX(FL_cols,3,1):INDEX(FL_cols,SCT,1),
FLP,INDEX(FL_cols,3,2):INDEX(FL_cols,SCT,2),
FLU,INDEX(FL_cols,3,3):INDEX(FL_cols,SCT,3),
SROWS,SEQUENCE(ROWS(SCT*3)),
SR,CEILING(SROWS/3,1),
MD,IF(MOD(SROWS,3)=0,3,MOD(SROWS,3)),
VSTACK( HSTACK(INDEX(SKUA,SR,1),INDEX(FLC,SR,1)),
HSTACK(INDEX(SKUA,SR,1),INDEX(FLP,SR,1)),
HSTACK(INDEX(SKUA,SR,1),INDEX(FLU,SR,1))
)))
這是一張圖片，我將 A 列用作“SKU_col”，將 B:D 列用作“FL_cols”。F:G 列顯示此 LAMBDA 的當前結果，I:J 列顯示此理想結果。
編輯以添加示例資料（即使它實際上只有 3 行，所以我在 StackOverflow 中輸入它比在 excel 中輸入它要困難 5 倍）
| 庫存單位 | FLC | FLP | 流感 |
|---|---|---|---|
| 99999 | 100 | 0 | 20 |
| 12345 | 48 | 24 | 2 |
| 67890 | 0 | 0 | 50 |
uj5u.com熱心網友回復：
你可以使用這個公式：
= LET(SKU,A2:A4,FL,B2:D4,
s,MAKEARRAY(ROWS(SKU),COLUMNS(FL)*2,
LAMBDA(r,c,IF(ISODD(c),INDEX(SKU,r),INDEX(FL,r,c/2)))),
WRAPROWS(TOCOL(s),2))
或作為 LAMBDA：
= LAMBDA(SKU,FL,
LET(
s,MAKEARRAY(ROWS(SKU),COLUMNS(FL)*2,
LAMBDA(r,c,IF(ISODD(c),INDEX(SKU,r),INDEX(FL,r,c/2)))),
WRAPROWS(TOCOL(s),2))
)
轉載請註明出處，本文鏈接：https://www.uj5u.com/shujuku/527649.html
標籤：擅长拉姆达excel公式
上一篇：如何在MASM中跨段填充塊？