請問怎么才能獲得ListView滑鼠所在的行和列？
就象MSFlexGrid的MSFlexGrid1.MouseRow和MSFlexGrid1.MouseCol一樣的功能
請高手指教，先謝謝！！！
uj5u.com熱心網友回復：
如果ListView沒有這樣的屬性那大家給個解決的思路也好啊uj5u.com熱心網友回復：
mouse move的時候是有滑鼠相對于控制元件的坐標的。listview的每行行高和每列列列寬是可以獲取的，于是根據滑鼠的X可以獲知所在的行，根據Y坐標可以獲知所在的列。
uj5u.com熱心網友回復：
但當發生滾動條滾動的時候要另想辦法
uj5u.com熱心網友回復：
我也是按這個思路做的，列的代碼已經寫出來了，就是行數得不到
uj5u.com熱心網友回復：
獲取滑鼠所在的“行”，比獲取所在“列”容易得多了。ListView控制元件有個介面函式： GetFirstVisible()
其回傳值就是“最頂上那行”的 ListItem。
有了這個ListItem，就知道“第1行”是哪行了；
然后按“行高”、y坐標值，就可以計算出滑鼠在哪行上面了。
uj5u.com熱心網友回復：
換個表格控制元件好了。Listview又不是表格控制元件，跟MSFlexGrid不是同一類的。
uj5u.com熱心網友回復：
得空試了一下，能解決。
一個表單，一個lsitview（6.0版本的哈）粘貼下面代碼。隨意改動列寬，隨意拖動滾動條，然后根據滑鼠坐標計算所指向的單元格。結果顯示在表單Caption 上
Option Explicit
Private Sub Form_Load()
Dim i As Integer
ListView1.View = lvwReport
ListView1.GridLines = True
For i = 1 To 20
ListView1.ColumnHeaders.Add , , "col" & i
ListView1.ListItems.Add , , "row" & i
Next
End Sub
Private Sub ListView1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim getRow As Long, getCol As Long
Dim itmTmp As ListItem
Set itmTmp = ListView1.GetFirstVisible
'獲取行，首先獲取第一條顯示的item，它的top值就是列頭的高度，去掉這個固定的高度以后，
'滑鼠Y坐標整除item高度得到的就是滑鼠指向顯示區域的第幾條記錄,再加上首行item的index，
'就是當前滑鼠所指行的index
getRow = (y - itmTmp.Top) \ itmTmp.Height + itmTmp.Index
'滑鼠X坐標減去首行的left，就是滑鼠相對于該行最左邊的橫坐標。
'然后逐個計算列頭寬度，看當前指向第幾個列
getCol = 0
Do
getCol = getCol + 1
x = x - ListView1.ColumnHeaders(getCol).Width
Loop Until x < 0
Me.Caption = getRow & "," & getCol
End Sub
uj5u.com熱心網友回復：
漏寫一行，修正一下
Option Explicit
Private Sub Form_Load()
Dim i As Integer
ListView1.View = lvwReport
ListView1.GridLines = True
For i = 1 To 20
ListView1.ColumnHeaders.Add , , "col" & i
ListView1.ListItems.Add , , "row" & i
Next
End Sub
Private Sub ListView1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim getRow As Long, getCol As Long
Dim itmTmp As ListItem
Set itmTmp = ListView1.GetFirstVisible
'獲取行，首先獲取第一條顯示的item，它的top值就是列頭的高度，去掉這個固定的高度以后，
'滑鼠Y坐標整除item高度得到的就是滑鼠指向顯示區域的第幾條記錄,再加上首行item的index，
'就是當前滑鼠所指行的index
getRow = (y - itmTmp.Top) \ itmTmp.Height + itmTmp.Index
'滑鼠X坐標減去首行的left，就是滑鼠相對于該行最左邊的橫坐標。
'然后逐個計算列頭寬度，看當前指向第幾個列
getCol = 0
x = x - itmTmp.Left
Do
getCol = getCol + 1
x = x - ListView1.ColumnHeaders(getCol).Width
Loop Until x < 0
Me.Caption = getRow & "," & getCol
End Sub
uj5u.com熱心網友回復：
沒有對空listview 以及row和col沒有撐滿顯示區域的情況進行處理哈，懶得寫了，自己加點判斷控制住便是。uj5u.com熱心網友回復：
本來就不支持的東西你硬要他支持，
費時費力還不得勁。
每種控制元件都有他擅長的地方。
uj5u.com熱心網友回復：
不是不支持，只不過沒有封裝進去。grid有也只是人家把相同邏輯的代碼寫進去了而已。
其實沒幾行代碼的事情，頂多再加10行。
uj5u.com熱心網友回復：
加5行，改1行，完善一下邊界判斷。
Option Explicit
Private Sub Form_Load()
Dim i As Integer
ListView1.View = lvwReport
ListView1.GridLines = True
For i = 1 To 10
ListView1.ColumnHeaders.Add , , "col" & i
ListView1.ListItems.Add , , "row" & i
Next
End Sub
Private Sub ListView1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim getRow As Long, getCol As Long
Dim itmTmp As ListItem
Set itmTmp = ListView1.GetFirstVisible
'獲取行，首先獲取第一條顯示的item，它的top值就是列頭的高度，去掉這個固定的高度以后，
'滑鼠Y坐標整除item高度得到的就是滑鼠指向顯示區域的第幾條記錄,再加上首行item的index，
'就是當前滑鼠所指行的index
getRow = (y - itmTmp.Top) \ itmTmp.Height + itmTmp.Index
If getRow > ListView1.ListItems.Count Then getRow = -1
'滑鼠X坐標減去首行的left，就是滑鼠相對于該行最左邊的橫坐標。
'然后逐個計算列頭寬度，看當前指向第幾個列
getCol = 0
x = x - itmTmp.Left
Do
getCol = getCol + 1
If getCol > ListView1.ColumnHeaders.Count Then
getCol = -1
Exit Do
End If
x = x - ListView1.ColumnHeaders(getCol).Width
Loop Until x < 0
Me.Caption = IIf(getRow > 0, "行：" & getRow, "超出行范圍") & "," & IIf(getCol > 0, "列：" & getCol, "超出列范圍")
End Sub
uj5u.com熱心網友回復：
中午閑的，再加30多行代碼，讓listview能夠像grid那樣直接所見即所得的編輯單元格。一個表單，放一個listview，一個timer，一個text
粘貼下面代碼
雙擊單元格，單元格出現文本編輯框，若單元格原來有內容，那么單元格內容回填文本框
文本框編輯狀態下按回車，編輯的字串直接顯示在相應的單元格上
在編輯狀態下拖動滾動條，文本框會隨著單元格滾動。
由于第一列的編輯，listview本身已經有控制，所以從第二列開始可編輯，當然也可以改成第一列也可以編輯。
Option Explicit
Dim getRow As Long, getCol As Long
Dim CX As Long, CY As Long
Dim getPos As Boolean
Private Sub Form_Load()
Dim i As Integer
Text1.Visible = False
Text1.Appearance = 0
ListView1.Appearance = 0
ListView1.View = lvwReport
ListView1.GridLines = True
ListView1.FullRowSelect = True
ListView1.LabelEdit = lvwManual
For i = 1 To 20
ListView1.ColumnHeaders.Add , , "col" & i
ListView1.ListItems.Add , , "row" & i
Next
getPos = True
End Sub
Private Sub ListView1_DblClick()
If getCol <= 1 Then Exit Sub
Timer1.Interval = 50
Timer1.Enabled = True
Text1.Text = ListView1.ListItems(getRow).SubItems(getCol - 1)
End Sub
'listview 沒有scoll事件，為了在編輯狀態下讓textbox跟蹤單元格的位置而使用了timer
Private Sub Timer1_Timer()
Dim i As Long
Dim tmpleft As Long
Static focusFlag As Boolean
getPos = False
tmpleft = ListView1.Left + ListView1.GetFirstVisible.Left
If getRow > 0 And getCol > 0 Then
For i = 2 To getCol
tmpleft = tmpleft + ListView1.ColumnHeaders(i).Width
Next
Text1.Left = tmpleft
Text1.Top = ListView1.Top + (getRow - ListView1.GetFirstVisible.Index) * ListView1.GetFirstVisible.Height + ListView1.GetFirstVisible.Top
Text1.Width = ListView1.ColumnHeaders(getCol).Width
Text1.Height = ListView1.GetFirstVisible.Height
'單元格移動進出listview顯示區域的時候控制textbox是否顯示
If Text1.Left < ListView1.Left Or Text1.Top < ListView1.Top + ListView1.GetFirstVisible.Top Then
Text1.Visible = False: focusFlag = False
Else
Text1.Visible = True
If Not focusFlag Then Text1.SetFocus: focusFlag = True '這個控制是為了防止頻繁的設定焦點導致其他操作受影響
End If
End If
End Sub
Private Sub Text1_KeyPress(KeyAscii As Integer)
If KeyAscii <> 13 Then Exit Sub
Timer1.Enabled = False
ListView1.ListItems(getRow).SubItems(getCol - 1) = Text1.Text
getPos = True
Text1.Visible = False
End Sub
Private Sub ListView1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
If Not getPos Then Exit Sub
Dim itmTmp As ListItem
CX = x
CY = y
Set itmTmp = ListView1.GetFirstVisible
'獲取行，首先獲取第一條顯示的item，它的top值就是列頭的高度，去掉這個固定的高度以后，
'滑鼠Y坐標整除item高度得到的就是滑鼠指向顯示區域的第幾條記錄,再加上首行item的index，
'就是當前滑鼠所指行的index
getRow = (y - itmTmp.Top) \ itmTmp.Height + itmTmp.Index
If getRow > ListView1.ListItems.Count Then getRow = -1
'滑鼠X坐標減去首行的left，就是滑鼠相對于該行最左邊的橫坐標。
'然后逐個計算列頭寬度，看當前指向第幾個列
getCol = 0
x = x - itmTmp.Left
Do
getCol = getCol + 1
If getCol > ListView1.ColumnHeaders.Count Then
getCol = -1
Exit Do
End If
x = x - ListView1.ColumnHeaders(getCol).Width
Loop Until x < 0
Me.Caption = IIf(getRow > 0, "行：" & getRow, "超出行范圍") & "," & IIf(getCol > 0, "列：" & getCol, "超出列范圍")
End Sub
轉載請註明出處，本文鏈接：https://www.uj5u.com/gongcheng/11948.html
標籤：VB基礎類
下一篇：求大神幫忙寫寫代碼