帶回圈的ExcelVBACountifs

我是 VBA 的新手。

我在 Excel 中的每一行的新列 (U) 中有此公式，但耗時太長并崩潰：

=IF(COUNTIFS($E:$E,E2,$A:$A,"<>"&A2)>0,"是","否")

有沒有辦法在 VBA 中做到這一點？

謝謝

uj5u.com熱心網友回復：

而不是雙回圈（按 n^2 的順序運行），另一種使用單回圈的方法是使用查找而不是內回圈（它按 n 順序運行，盡管每次迭代都稍微復雜一些）。

就像是

Sub Example2()
    Dim ws As Worksheet
    Set ws = ActiveSheet
    
    Dim LastRow As Long
    LastRow = ws.Cells(ws.Rows.Count, 5).End(xlUp).Row
    
    Dim TargetRange As Range
    Set TargetRange = ws.Range(ws.Cells(2, 1), ws.Cells(LastRow, 5))
    
    Dim vArr() As Variant
    vArr = TargetRange.Value2
    
    Dim ColU() As Variant
    ReDim ColU(1 To UBound(vArr, 1), 1 To 1)
    
    Dim i As Long
    Dim j As Long
    Dim rE As Range
    Set rE = ws.Range(ws.Cells(2, 5), ws.Cells(LastRow, 5))
    
    ColU(UBound(vArr, 1), 1) = "No"
    For i = 1 To UBound(vArr, 1) - 1
        j = 0
        On Error Resume Next
            j = Application.WorksheetFunction.XMatch(vArr(i, 5), rE.Offset(i, 0), 0, 1)
        On Error GoTo 0
        ColU(i, 1) = "No"
        If j > 0 Then
            If vArr(i, 1) <> vArr(j   i, 1) Then
                ColU(i, 1) = "Yes"
                ColU(j   i, 1) = "Yes"
            End If
        End If
    Next
    ws.Range("U2").Resize(UBound(vArr, 1)).Value = ColU
End Sub

在我的硬體上，運行了任意樣本資料集

uj5u.com熱心網友回復：

根據我對您的 Excel 公式的理解。您試圖在每一行的 U 列中輸入“是”，其中 E 列中的值位于 E 列的其他位置，但前提是 A 列的值不同。

以下是您在 VBA 中執行此操作的方法：

Sub Example()
    Dim Sh As Worksheet
    Set Sh = ActiveSheet
    
    Dim LastRow As Integer
    LastRow = Sh.Cells(Sh.Rows.Count, "E").End(xlUp).Row
    
    Dim TargetRange As Range
    Set TargetRange = Sh.Range("A2:E" & LastRow)
    
    Dim vArr() As Variant
    vArr = TargetRange.Value
    
    Dim ColU() As Variant
    ReDim ColU(1 To UBound(vArr, 1), 1 To 1)
    
    Dim i As Long
    For i = 1 To UBound(vArr, 1)
            ColU(i, 1) = "No"
        Dim j As Long
        For j = 1 To UBound(vArr, 1)
            If vArr(i, 5) = vArr(j, 5) And vArr(i, 1) <> vArr(j, 1) Then
                ColU(i, 1) = "Yes"
                Exit For
            End If
        Next
    Next
    Sh.Range("U2").Resize(UBound(vArr, 1)).Value = ColU
End Sub

我首先將 range 的值A:E放入一個陣列中。然后我遍歷陣列檢查我的陳述是否為真。如果為真，則為“是”，否則默認為“否”。然后我將答案輸出到 U 列。

這種方法的缺點是迭代次數為 n^2，因為我為陣列的每一行回圈遍歷陣列。對于非常大的資料集，它不可避免地會變慢。

@ChrisNeilsen 建議的改進是從 開始內回圈i，將迭代次數減少一半。為了融入這個想法，我首先在自己的回圈中設定 ColU 默認值，然后在找到重復項時，我可以同時將兩個重復項設定為“是”。

Sub Example()
    Dim Sh As Worksheet
    Set Sh = ActiveSheet
    
    Dim LastRow As Integer
    LastRow = Sh.Cells(Sh.Rows.Count, "E").End(xlUp).Row
    
    Dim TargetRange As Range
    Set TargetRange = Sh.Range("A2:E" & LastRow)
    
    Dim vArr() As Variant
    vArr = TargetRange.Value
    
    Dim ColU() As Variant
    ReDim ColU(1 To UBound(vArr, 1), 1 To 1)
    
    Dim i As Long
    For i = 1 To UBound(vArr, 1)
        ColU(i, 1) = "No"
    Next
    
    For i = 1 To UBound(vArr, 1)
        Dim j As Long
        For j = i To UBound(vArr, 1)
            If vArr(i, 5) = vArr(j, 5) And vArr(i, 1) <> vArr(j, 1) Then
                ColU(i, 1) = "Yes"
                ColU(j, 1) = "Yes"
                Exit For
            End If
        Next
    Next
    Sh.Range("U2").Resize(UBound(vArr, 1)).Value = ColU
End Sub

標籤：擅长 vba for循环 县

上一篇：對陣列中的每一列進行簡單排序

下一篇：根據另一個單元格中的值在一個單元格中創建驗證