如何從資源中播放wav檔案

我需要從資源中播放和回圈播放 WAV 音軌。

我在這里找到了類似問題的答案：

我的資源看起來像這樣（不要介意專案名稱）：

我粘貼到我的專案中的代碼是：

procedure TForm1.FormShow(Sender: TObject);
begin
  PlaySound(BG, 0, SND_RESOURCE or SND_ASYNC);
end;

整個事情看起來像這樣：

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Imaging.pngimage, Vcl.ExtCtrls, Unit2, Unit3, Unit4, Unit5,
  Vcl.MPlayer, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Image1: TImage;
    MediaPlayer1: TMediaPlayer;
    Button1: TButton;
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure MediaPlayer1Enter(Sender: TObject);
    procedure MediaPlayer1Notify(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
procedure TForm1.FormShow(Sender: TObject);
begin
  PlaySound(BG, 0, SND_RESOURCE or SND_ASYNC);
end;

也許我需要包括一些圖書館或其他東西？我是德爾福的新手。

uj5u.com熱心網友回復：

要PlaySound()在 Delphi 中使用，您只需將Winapi.MMSystem單位添加到您的uses子句中。

但是，由于您TMediaPlayer的專案中也有 a，您可以使用它來代替PlaySound()，這將具有額外的好處，可以讓您更好地控制播放（暫停/恢復、跳過等）。

TMediaPlayer本身不支持從資源播放 WAV 音頻，但可以通過一些額外的編碼來完成。

在內部，通過函式TMediaPlayer使用MCI 。mciSendCommand()根據微軟（HOWTO: Use MCI to Play AVI/WAVE Files from Memory），您可以通過安裝自定義 IO 回呼設定 MCI 從記憶體（例如資源）播放 WAV 音頻，然后在打開播放器時指定該回呼設備。幸運的是，回呼是由檔案擴展名觸發的，因此這種方法與TMediaPlayer.FileName屬性兼容。

因此，您應該能夠撰寫具有自定義檔案擴展名（例如，.RES用于資源）的 IO 回呼函式，并讓該回呼加載 WAV 資源并讀取其資料，然后您將設定MediaPlayer1.DeviceType為dtWaveAudio和MediaPlayer1.FileName以結尾的檔案名自定義擴展。其余的由作業系統為您處理，然后您可以MediaPlayer1根據需要使用它來控制播放。

例如：

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Imaging.pngimage, Vcl.ExtCtrls, Unit2, Unit3, Unit4, Unit5,
  Vcl.MPlayer, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Image1: TImage;
    MediaPlayer1: TMediaPlayer;
    Button1: TButton;
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure MediaPlayer1Enter(Sender: TObject);
    procedure MediaPlayer1Notify(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses
  Winapi.MMSystem;
  
{$R *.dfm}

function MAKEFOURCC(ch0, ch1, ch2, ch3: BYTE): FOURCC;
begin
  Result := DWORD(ch0) or (DWORD(ch1) shl 8) or (DWORD(ch2) shl 16) or (DWORD(ch3) shl 24); 
end;

function MyResourceIOProc(lpMMIOInfo: PMMIOInfo; uMessage: UINT; lParam1, lParam2: LPARAM): LRESULT; stdcall;
var
  Res: TResourceStream;

  function GetResourceStream: TResourceStream;
  begin
    Move(lpMMIOInfo.adwInfo, Result, SizeOf(TResourceStream));
  end;

  procedure SetResourceStream(Stream: TResourceStream);
  begin
    Move(Stream, lpMMIOInfo.adwInfo, SizeOf(TResourceStream));
  end;

begin
  case uMessage of
    MMIOM_OPEN: begin
      try
        Res := TResourceStream.Create(ChangeFileExt(PChar(lParam1), ''), 'WAVE');
      except
        SetResourceStream(nil);
        Exit(MMIOM_CANNOTOPEN);
      end;
      SetResourceStream(Res);
      lpMMIOInfo.lDiskOffset := 0;
      Exit(MMSYSERR_NOERROR);
    end;   
    MMIOM_CLOSE: begin
      Res := GetResourceStream;
      SetResourceStream(nil);
      Res.Free;
      Exit(MMSYSERR_NOERROR);
    end;   
    MMIOM_READ: begin
      Res := GetResourceStream;
      Move((PByte(Res.Memory)   lpMMIOInfo.lDiskOffset)^, Pointer(lParam1)^, lParam2);
      Inc(lpMMIOInfo.lDiskOffset, lParam2);
      Exit(lParam2);
    end;
    MMIOM_SEEK: begin
      case lParam2 of
        SEEK_SET: begin
          lpMMIOInfo.lDiskOffset := lParam1;
        end;
        SEEK_CUR: begin
          Inc(lpMMIOInfo.lDiskOffset, lParam1);
        end;
        SEEK_END: begin
          Res := GetResourceStream;
          lpMMIOInfo.lDiskOffset := Res.Size - 1 - lParam1;
        end;
      end;
      Exit(lpMMIOInfo.lDiskOffset);
    end;
  else
    Exit(MMSYSERR_NOERROR);
  end;
end;

const
  ccRES: FOURCC = MAKEFOURCC(Ord('R'), Ord('E'), Ord('S'), Ord(' '));

procedure TForm1.FormCreate(Sender: TObject);
begin
  mmioInstallIOProc(ccRES, TFNMMIOProc(MyResourceIOProc), MMIO_INSTALLPROC or MMIO_GLOBALPROC); 
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  mmioInstallIOProc(ccRES, nil, MMIO_REMOVEPROC);
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  MediaPlayer1.FileName := 'BG.RES ';
  MediaPlayer1.Open;
  MediaPlayer1.Play;
end;

標籤：德尔福

上一篇：子視窗上的DelphiVCL樣式

下一篇：如何使關閉按鈕在Delphi上打開一個新表單