如題，把對應資料填到word里，并用b列的內容命名word，一個word里填入多行，如果b列數字改變則換另一個word表格，應該怎么寫？求解答謝謝orz奉上全部積分
uj5u.com熱心網友回復：
在Excel2003和Word2003中開始記錄宏，手動完成所需功能，結束記錄宏，按Alt+F11鍵，查看剛才記錄的宏對應的VBA代碼。uj5u.com熱心網友回復：
這是VB程式的代碼，如果要放在Excel/Word的VBA中，自己改一下，利用當前的Excel.Application/Word.ApplicationOption Explicit
Sub Main()
Dim xlApp As Excel.Application
Dim xlBook As Excel.Workbook
Dim xlSheet As Excel.Worksheet
Dim wdApp As Word.Application
Set xlApp = New Excel.Application
Set xlBook = xlApp.Workbooks.Open(App.Path & "\Book1.xls")
Set xlSheet = xlBook.Sheets(1)
Set wdApp = New Word.Application
Export xlSheet, wdApp
wdApp.Quit
Set wdApp = Nothing
Set xlSheet = Nothing
xlBook.Close
Set xlBook = Nothing
xlApp.Quit
Set xlApp = Nothing
End Sub
Sub Export(ByVal xlSheet As Excel.Worksheet, ByVal wdApp As Word.Application)
Dim xlTable As Excel.Range
Dim xlRowCount As Long
Dim xlColumnCount As Long
Dim wdDoc As Word.Document
Dim wdTable As Word.Table
Dim wdRow As Long
Dim vLastGroup As Variant
Dim i As Long
Dim j As Long
Set xlTable = xlSheet.UsedRange
xlRowCount = xlTable.Rows.Count
xlColumnCount = xlTable.Columns.Count
For i = 1 To xlRowCount
If (wdTable Is Nothing) Or (xlTable.Cells(i, 2).Value <> vLastGroup) Then
'保存、關閉舊檔案'
If Not wdDoc Is Nothing Then
Set wdTable = Nothing
wdDoc.SaveAs App.Path & "\" & vLastGroup & ".doc"
wdDoc.Close
Set wdDoc = Nothing
End If
'新建檔案'
Set wdDoc = wdApp.Documents.Add()
'添加表格'
wdApp.Selection.EndKey Unit:=wdStory
wdApp.Selection.TypeText Text:=xlTable.Cells(i, 2)
wdApp.Selection.TypeParagraph
Set wdTable = wdDoc.Tables.Add(wdApp.Selection.Range, 1, xlColumnCount)
wdRow = 1
vLastGroup = xlTable.Cells(i, 2).Value
Else
'添加一行'
wdTable.Rows.Add
wdRow = wdRow + 1
End If
For j = 1 To xlColumnCount
wdTable.Cell(wdRow, j).Range.Text = xlTable.Cells(i, j).Value
Next
Next
If Not wdDoc Is Nothing Then
Set wdTable = Nothing
wdDoc.SaveAs App.Path & "\" & vLastGroup & ".doc"
wdDoc.Close
Set wdDoc = Nothing
End If
End Sub
Word的截圖（才43K）死活傳不上去，你自己看效果吧。
轉載請註明出處，本文鏈接：https://www.uj5u.com/gongcheng/84144.html
標籤：VBA
上一篇：VB或者C語言撰寫一段可以不斷在intouch上獲取滑鼠位置的語言，請教各位大師了
下一篇：急！生成的DBF檔案名只有8位