原文地址：https://www.jianshu.com/p/98f53dc4e9f6
前言
OpenGL 圖形庫專案中一直也沒用過，最近也想學著使用這個圖形庫，感徑訓是很有意思，也就自然想著好好的總結一下，希望對大家能有所幫助。下面內容來自歡迎來到OpenGL的世界。
1. OpenGL 圖形庫使用（一） —— 概念基礎
2. OpenGL 圖形庫使用（二） —— 渲染模式、物件、擴展和狀態機
3. OpenGL 圖形庫使用（三） —— 著色器、資料型別與輸入輸出
4. OpenGL 圖形庫使用（四） —— Uniform及更多屬性
5. OpenGL 圖形庫使用（五） —— 紋理
6. OpenGL 圖形庫使用（六） —— 變換
7. OpenGL 圖形庫的使用（七）—— 坐標系統之五種不同的坐標系統（一）
8. OpenGL 圖形庫的使用（八）—— 坐標系統之3D效果（二）
9. OpenGL 圖形庫的使用（九）—— 攝像機（一）
10. OpenGL 圖形庫的使用（十）—— 攝像機（二）
11. OpenGL 圖形庫的使用（十一）—— 光照之顏色
12. OpenGL 圖形庫的使用（十二）—— 光照之基礎光照
13. OpenGL 圖形庫的使用（十三）—— 光照之材質
14. OpenGL 圖形庫的使用（十四）—— 光照之光照貼圖
15. OpenGL 圖形庫的使用（十五）—— 光照之投光物
16. OpenGL 圖形庫的使用（十六）—— 光照之多光源
17. OpenGL 圖形庫的使用（十七）—— 光照之復習總結
18. OpenGL 圖形庫的使用（十八）—— 模型加載之Assimp
19. OpenGL 圖形庫的使用（十九）—— 模型加載之網格
20. OpenGL 圖形庫的使用（二十）—— 模型加載之模型
21. OpenGL 圖形庫的使用（二十一）—— 高級OpenGL之深度測驗
22. OpenGL 圖形庫的使用（二十二）—— 高級OpenGL之模板測驗Stencil testing
23. OpenGL 圖形庫的使用（二十三）—— 高級OpenGL之混合Blending
24. OpenGL 圖形庫的使用（二十四）—— 高級OpenGL之面剔除Face culling
25. OpenGL 圖形庫的使用（二十五）—— 高級OpenGL之幀緩沖Framebuffers
26. OpenGL 圖形庫的使用（二十六）—— 高級OpenGL之立方體貼圖Cubemaps
27. OpenGL 圖形庫的使用（二十七）—— 高級OpenGL之高級資料Advanced Data
28. OpenGL 圖形庫的使用（二十八）—— 高級OpenGL之高級GLSL Advanced GLSL
幾何著色器
在頂點和片段著色器之間有一個可選的幾何著色器(Geometry Shader)，幾何著色器的輸入是一個圖元（如點或三角形）的一組頂點。幾何著色器可以在頂點發送到下一著色器階段之前對它們隨意變換。然而，幾何著色器最有趣的地方在于，它能夠將（這一組）頂點變換為完全不同的圖元，并且還能生成比原來更多的頂點。
廢話不多說，我們直接先看一個幾何著色器的例子：
#version 330 core
layout (points) in;
layout (line_strip, max_vertices = 2) out;
void main() {
gl_Position = gl_in[0].gl_Position + vec4(-0.1, 0.0, 0.0, 0.0);
EmitVertex();
gl_Position = gl_in[0].gl_Position + vec4( 0.1, 0.0, 0.0, 0.0);
EmitVertex();
EndPrimitive();
}
在幾何著色器的頂部，我們需要宣告從頂點著色器輸入的圖元型別。這需要在in關鍵字前宣告一個布局修飾符(Layout Qualifier)。這個輸入布局修飾符可以從頂點著色器接收下列任何一個圖元值：
points：繪制GL_POINTS圖元時（1）。
lines：繪制GL_LINES或GL_LINE_STRIP時（2）
lines_adjacency：GL_LINES_ADJACENCY或GL_LINE_STRIP_ADJACENCY（4）
triangles：GL_TRIANGLES、GL_TRIANGLE_STRIP或GL_TRIANGLE_FAN（3）
triangles_adjacency：GL_TRIANGLES_ADJACENCY或GL_TRIANGLE_STRIP_ADJACENCY（6）
以上是能提供給glDrawArrays渲染函式的幾乎所有圖元了。如果我們想要將頂點繪制為GL_TRIANGLES，我們就要將輸入修飾符設定為triangles。括號內的數字表示的是一個圖元所包含的最小頂點數。
接下來，我們還需要指定幾何著色器輸出的圖元型別，這需要在out關鍵字前面加一個布局修飾符。和輸入布局修飾符一樣，輸出布局修飾符也可以接受幾個圖元值：
points
line_strip
triangle_strip
有了這3個輸出修飾符，我們就可以使用輸入圖元創建幾乎任意的形狀了。要生成一個三角形的話，我們將輸出定義為triangle_strip，并輸出3個頂點。
幾何著色器同時希望我們設定一個它最大能夠輸出的頂點數量（如果你超過了這個值，OpenGL將不會繪制多出的頂點），這個也可以在out關鍵字的布局修飾符中設定。在這個例子中，我們將輸出一個line_strip，并將最大頂點數設定為2個。
如果你不知道什么是線條(Line Strip)：線條連接了一組點，形成一條連續的線，它最少要由兩個點來組成。在渲染函式中每多加一個點，就會在這個點與前一個點之間形成一條新的線。在下面這張圖中，我們有5個頂點：
如果使用的是上面定義的著色器，那么這將只能輸出一條線段，因為最大頂點數等于2。
為了生成更有意義的結果，我們需要某種方式來獲取前一著色器階段的輸出。GLSL提供給我們一個內建(Built-in)變數，在內部看起來（可能）是這樣的：
in gl_Vertex
{
vec4 gl_Position;
float gl_PointSize;
float gl_ClipDistance[];
} gl_in[];
這里，它被宣告為一個介面塊（Interface Block，我們在上一節已經討論過），它包含了幾個很有意思的變數，其中最有趣的一個是gl_Position，它是和頂點著色器輸出非常相似的一個向量。
要注意的是，它被宣告為一個陣列，因為大多數的渲染圖元包含多于1個的頂點，而幾何著色器的輸入是一個圖元的所有頂點。
有了之前頂點著色器階段的頂點資料，我們就可以使用2個幾何著色器函式，EmitVertex和EndPrimitive，來生成新的資料了。幾何著色器希望你能夠生成并輸出至少一個定義為輸出的圖元。在我們的例子中，我們需要至少生成一個線條圖元。
void main() {
gl_Position = gl_in[0].gl_Position + vec4(-0.1, 0.0, 0.0, 0.0);
EmitVertex();
gl_Position = gl_in[0].gl_Position + vec4( 0.1, 0.0, 0.0, 0.0);
EmitVertex();
EndPrimitive();
}
每次我們呼叫EmitVertex時，gl_Position中的向量會被添加到圖元中來。當EndPrimitive被呼叫時，所有發射出的(Emitted)頂點都會合成為指定的輸出渲染圖元。在一個或多個EmitVertex呼叫之后重復呼叫EndPrimitive能夠生成多個圖元。在這個例子中，我們發射了兩個頂點，它們從原始頂點位置平移了一段距離，之后呼叫了EndPrimitive，將這兩個頂點合成為一個包含兩個頂點的線條。
現在你（大概）了解了幾何著色器的作業方式，你可能已經猜出這個幾何著色器是做什么的了。它接受一個點圖元作為輸入，以這個點為中心，創建一條水平的線圖元。如果我們渲染它，看起來會是這樣的：
目前還并沒有什么令人驚嘆的效果，但考慮到這個輸出是通過呼叫下面的渲染函式來生成的，它還是很有意思的：
glDrawArrays(GL_POINTS, 0, 4);
雖然這是一個比較簡單的例子，它的確向你展示了如何能夠使用幾何著色器來（動態地）生成新的形狀。在之后我們會利用幾何著色器創建出更有意思的效果，但現在我們仍將從創建一個簡單的幾何著色器開始。
使用幾何著色器
為了展示幾何著色器的用法，我們將會渲染一個非常簡單的場景，我們只會在標準化設備坐標的z平面上繪制四個點。這些點的坐標是：
float points[] = {
-0.5f, 0.5f, // 左上
0.5f, 0.5f, // 右上
0.5f, -0.5f, // 右下
-0.5f, -0.5f // 左下
};
頂點著色器只需要在z平面繪制點就可以了，所以我們將使用一個最基本頂點著色器：
#version 330 core
layout (location = 0) in vec2 aPos;
void main()
{
gl_Position = vec4(aPos.x, aPos.y, 0.0, 1.0);
}
直接在片段著色器中硬編碼，將所有的點都輸出為綠色：
#version 330 core
out vec4 FragColor;
void main()
{
FragColor = vec4(0.0, 1.0, 0.0, 1.0);
}
為點的頂點資料生成一個VAO和一個VBO，然后使用glDrawArrays進行繪制：
shader.use();
glBindVertexArray(VAO);
glDrawArrays(GL_POINTS, 0, 4);
結果是在黑暗的場景中有四個（很難看見的）綠點：
但我們之前不是學過這些嗎？是的，但是現在我們將會添加一個幾何著色器，為場景添加活力。
出于學習目的，我們將會創建一個傳遞(Pass-through)幾何著色器，它會接收一個點圖元，并直接將它傳遞(Pass)到下一個著色器：
#version 330 core
layout (points) in;
layout (points, max_vertices = 1) out;
void main() {
gl_Position = gl_in[0].gl_Position;
EmitVertex();
EndPrimitive();
}
現在這個幾何著色器應該很容易理解了，它只是將它接收到的頂點位置不作修改直接發射出去，并生成一個點圖元。
和頂點與片段著色器一樣，幾何著色器也需要編譯和鏈接，但這次在創建著色器時我們將會使用GL_GEOMETRY_SHADER作為著色器型別：
geometryShader = glCreateShader(GL_GEOMETRY_SHADER);
glShaderSource(geometryShader, 1, &gShaderCode, NULL);
glCompileShader(geometryShader);
...
glAttachShader(program, geometryShader);
glLinkProgram(program);
著色器編譯的代碼和頂點與片段著色器代碼都是一樣的。記得要檢查編譯和鏈接錯誤！
如果你現在編譯并運行程式，會看到和下面類似的結果：
這和沒使用幾何著色器時是完全一樣的！我承認這是有點無聊，但既然我們仍然能夠繪制這些點，所以幾何著色器是正常作業的，現在是時候做點更有趣的東西了！
造幾個房子
繪制點和線并沒有那么有趣，所以我們會使用一點創造力，利用幾何著色器在每個點的位置上繪制一個房子。要實作這個，我們可以將幾何著色器的輸出設定為triangle_strip，并繪制三個三角形：其中兩個組成一個正方形，另一個用作房頂。
OpenGL中，三角形帶(Triangle Strip)是繪制三角形更高效的方式，它使用頂點更少。在第一個三角形繪制完之后，每個后續頂點將會在上一個三角形邊上生成另一個三角形：每3個臨近的頂點將會形成一個三角形。如果我們一共有6個構成三角形帶的頂點，那么我們會得到這些三角形：(1, 2, 3)、(2, 3, 4)、(3, 4, 5)和(4, 5, 6)，共形成4個三角形。一個三角形帶至少需要3個頂點，并會生成N-2個三角形。使用6個頂點，我們創建了6-2 = 4個三角形。下面這幅圖展示了這點：
通過使用三角形帶作為幾何著色器的輸出，我們可以很容易創建出需要的房子形狀，只需要以正確的順序生成3個相連的三角形就行了。下面這幅圖展示了頂點繪制的順序，藍點代表的是輸入點：
變為幾何著色器是這樣的：
#version 330 core
layout (points) in;
layout (triangle_strip, max_vertices = 5) out;
void build_house(vec4 position)
{
gl_Position = position + vec4(-0.2, -0.2, 0.0, 0.0); // 1:左下
EmitVertex();
gl_Position = position + vec4( 0.2, -0.2, 0.0, 0.0); // 2:右下
EmitVertex();
gl_Position = position + vec4(-0.2, 0.2, 0.0, 0.0); // 3:左上
EmitVertex();
gl_Position = position + vec4( 0.2, 0.2, 0.0, 0.0); // 4:右上
EmitVertex();
gl_Position = position + vec4( 0.0, 0.4, 0.0, 0.0); // 5:頂部
EmitVertex();
EndPrimitive();
}
void main() {
build_house(gl_in[0].gl_Position);
}
這個幾何著色器生成了5個頂點，每個頂點都是原始點的位置加上一個偏移量，來組成一個大的三角形帶。最終的圖元會被光柵化，然后片段著色器會處理整個三角形帶，最終在每個繪制的點處生成一個綠色房子：
你可以看到，每個房子實際上是由3個三角形組成的——全部都是使用空間中一點來繪制的。這些綠房子看起來是有點無聊，所以我們會再給每個房子分配一個不同的顏色。為了實作這個，我們需要在頂點著色器中添加一個額外的頂點屬性，表示顏色資訊，將它傳遞至幾何著色器，并再次發送到片段著色器中。
下面是更新后的頂點資料：
float points[] = {
-0.5f, 0.5f, 1.0f, 0.0f, 0.0f, // 左上
0.5f, 0.5f, 0.0f, 1.0f, 0.0f, // 右上
0.5f, -0.5f, 0.0f, 0.0f, 1.0f, // 右下
-0.5f, -0.5f, 1.0f, 1.0f, 0.0f // 左下
};
然后我們更新頂點著色器，使用一個介面塊將顏色屬性發送到幾何著色器中：
#version 330 core
layout (location = 0) in vec2 aPos;
layout (location = 1) in vec3 aColor;
out VS_OUT {
vec3 color;
} vs_out;
void main()
{
gl_Position = vec4(aPos.x, aPos.y, 0.0, 1.0);
vs_out.color = aColor;
}
接下來我們還需要在幾何著色器中宣告相同的介面塊（使用一個不同的介面名）：
in VS_OUT {
vec3 color;
} gs_in[];
因為幾何著色器是作用于輸入的一組頂點的，從頂點著色器發來輸入資料總是會以陣列的形式表示出來，即便我們現在只有一個頂點。
我們并不是必須要用介面塊來向幾何著色器傳遞資料。如果頂點著色器發送的顏色向量是out vec3 vColor，我們也可以這樣寫：
in vec3 vColor[];
然而，介面塊在幾何著色器這樣的著色器中會更容易處理一點。實際上，幾何著色器的輸入能夠變得非常大，將它們合并為一個大的介面塊陣列會更符合邏輯一點。
接下來我們還需要為下個片段著色器階段宣告一個輸出顏色向量：
out vec3 fColor;
因為片段著色器只需要一個（插值的）顏色，發送多個顏色并沒有什么意義。所以，fColor向量就不是一個陣列，而是一個單獨的向量。當發射一個頂點的時候，每個頂點將會使用最后在fColor中儲存的值，來用于片段著色器的運行。對我們的房子來說，我們只需要在第一個頂點發射之前，使用頂點著色器中的顏色填充fColor一次就可以了。
因為片段著色器只需要一個（已進行了插值的）顏色，傳送多個顏色沒有意義。fColor向量這樣就不是一個陣列，而是一個單一的向量。當發射一個頂點時，為了它的片段著色器運行，每個頂點都會儲存最后在fColor中儲存的值。對于這些房子來說，我們可以在第一個頂點被發射，對整個房子上色前，只使用來自頂點著色器的顏色填充fColor一次：
fColor = gs_in[0].color; // gs_in[0] 因為只有一個輸入頂點
gl_Position = position + vec4(-0.2, -0.2, 0.0, 0.0); // 1:左下
EmitVertex();
gl_Position = position + vec4( 0.2, -0.2, 0.0, 0.0); // 2:右下
EmitVertex();
gl_Position = position + vec4(-0.2, 0.2, 0.0, 0.0); // 3:左上
EmitVertex();
gl_Position = position + vec4( 0.2, 0.2, 0.0, 0.0); // 4:右上
EmitVertex();
gl_Position = position + vec4( 0.0, 0.4, 0.0, 0.0); // 5:頂部
EmitVertex();
EndPrimitive();
所有發射出的頂點都將嵌有最后儲存在fColor中的值，即頂點的顏色屬性值。所有的房子都會有它們自己的顏色了：
僅僅是為了有趣，我們也可以假裝這是冬天，將最后一個頂點的顏色設定為白色，給屋頂落上一些雪。
fColor = gs_in[0].color;
gl_Position = position + vec4(-0.2, -0.2, 0.0, 0.0); // 1:左下
EmitVertex();
gl_Position = position + vec4( 0.2, -0.2, 0.0, 0.0); // 2:右下
EmitVertex();
gl_Position = position + vec4(-0.2, 0.2, 0.0, 0.0); // 3:左上
EmitVertex();
gl_Position = position + vec4( 0.2, 0.2, 0.0, 0.0); // 4:右上
EmitVertex();
gl_Position = position + vec4( 0.0, 0.4, 0.0, 0.0); // 5:頂部
fColor = vec3(1.0, 1.0, 1.0);
EmitVertex();
EndPrimitive();
最終結果看起來是這樣的：
你可以將你的代碼與這里的OpenGL代碼進行比對。
#include <glad/glad.h>
#include <GLFW/glfw3.h>
#include <learnopengl/shader.h>
#include <iostream>
void framebuffer_size_callback(GLFWwindow* window, int width, int height);
// settings
const unsigned int SCR_WIDTH = 1280;
const unsigned int SCR_HEIGHT = 720;
int main()
{
// glfw: initialize and configure
// ------------------------------
glfwInit();
glfwWindowHint(GLFW_CONTEXT_VERSION_MAJOR, 3);
glfwWindowHint(GLFW_CONTEXT_VERSION_MINOR, 3);
glfwWindowHint(GLFW_OPENGL_PROFILE, GLFW_OPENGL_CORE_PROFILE);
#ifdef __APPLE__
glfwWindowHint(GLFW_OPENGL_FORWARD_COMPAT, GL_TRUE); // uncomment this statement to fix compilation on OS X
#endif
// glfw window creation
// --------------------
GLFWwindow* window = glfwCreateWindow(SCR_WIDTH, SCR_HEIGHT, "LearnOpenGL", NULL, NULL);
if (window == NULL)
{
std::cout << "Failed to create GLFW window" << std::endl;
glfwTerminate();
return -1;
}
glfwMakeContextCurrent(window);
// glad: load all OpenGL function pointers
// ---------------------------------------
if (!gladLoadGLLoader((GLADloadproc)glfwGetProcAddress))
{
std::cout << "Failed to initialize GLAD" << std::endl;
return -1;
}
// configure global opengl state
// -----------------------------
轉載請註明出處，本文鏈接：https://www.uj5u.com/qita/27416.html
標籤：Unity3D
上一篇：NGUI 背包滑塊效果
下一篇：畢設有什么題材比較適合啊？