SRP Batcher 原理及應用

SRP Batcher 概述

SRP Batcher 是 Unity 在 2018 年隨著 SRP 的發布而推出的一種新的批處理方式，啟用 SRP Batcher 并不會減少 Draw Call，而會減少每 Batch 所需要做的設定作業，此外 SRP Batcher 還能減少另一種開銷較大的呼叫：SetPass calls，

這是有其道理的，通常來說，程式員希望減少 Draw Call 來降低 CPU 方面的渲染開銷，其真正原因不是 Draw Call 本身很耗時，而是 Unity 必須在呼叫 Draw Call 前進行大量的設定作業，渲染所帶來的 CPU 開銷主要就來自這些設定作業而非 Draw Call 本身，實際上，Draw Call 的作業只是將一些 Bytes 傳遞給 GPU command buffer，

左 Standard Rendering Workflow，右 SRP Batcher Rendering Workflow

從上圖我們可以確切的看到，SRP Batcher 實實在在的減少了設定作業，這使得每個 Draw Call 的代價降低了很多，

在 Standard Rendering Workflow 中，每當我們切換 Material 時，都會被迫呼叫開銷有點大的 SetShaderCall(SetPassCall)，而在 SRP Batcher Rendering Workflow 中，只有當我們的材質所使用的 Shader 變化時才會呼叫 SetShaderCall(SetPassCall)，這也就意味著 SRP Batcher 還能某種程度上減少 SetPassCall，其原因也是很直觀的：Material 的數量總是會比 Shader 的數量多的，

現在我們來看看傳統的 Standard Rendering Workflow 與 SRP Batcher Renderinig Workflow 的具體實作區別，

Standard Rendering Workflow

對于 Standard Rendering Workflow 來說，每當檢測到一個新的 Material 時，CPU 都會收集所有的 properties（collects all properties）并在 GPU 中設定不同的常量緩沖區，GPU 緩沖區的數量取決于 Shader 如何宣告它的 CBUFFER，

換言之，對于標準渲染作業流，每次渲染到一個新的 Material 時，Unity 都需要把新 Material 所 attach 的 Object 的 properties 加上 Material 資料存盤到單獨的緩沖區中，期間需要執行大量設定作業，也就是說，標準渲染作業流下，Material 越多，CPU 提交給 GPU 的資料就越多，所執行的設定作業就越多，

而之所以每幀的渲染中，CPU 檢測到不同的 Material 都要提交資料有其歷史原因：

The Unity editor has a really flexible rendering engine. You can modify any Material property at any time during a frame. Plus, Unity historically was made for non-constant buffers, supporting Graphics APIs such as DirectX9.

也就是說過往的 Unity 是基于非常量緩沖區（non-constant buffers）的，這帶來了靈活性，但也有其缺點：

However, such nice features have some drawbacks. For example, there is a lot of work to do when a DrawCall is using a new Material. So basically, the more Materials you have in a Scene, the more CPU will be required to setup GPU data.

你使用越多的 Material，CPU 就需要設定提交越多的資料給 GPU，

SRP Batcher Renderinig Workflow

SRP Batcher Renderinig Workflow 支持將 Material 資料持久性存放在 GPU 中，這也就意味著，如果 Material 沒有發生改變，CPU 完全不需要每次渲染都設定并將 Material 的資料提交給 GPU，因為它可以持久存放在 GPU 的顯存里，此外，SRP Batcher 使用專門的代碼路徑來快速地更新存盤有所有 built-in properties（Object data）的，位于 GPU 的超大 buffer，也就是說，采用 SRP Batcher 的游戲物件的 built-in properties 會被單獨的通過一個新的代碼路徑管理其設定和提交作業，而且這些資料在 GPU 中都位于同一個超大的 GPU Buffer 中，GPU 可以簡單通過 offset 訪問指定物件的基本資料，

總結來說，采用 SRP Batcher 后，渲染時 CPU 只設定或處理 built-in properties，labeled object matrix transform（指定物件的矩陣），而 Material 資料存盤在 GPU 顯存中的 CBUFFER 中，

SRP Batcher 通過以下兩步加速了渲染的作業流，

1. Each material content is now persistent in GPU memory
2. A dedicated code is managing a large “per object” GPU CBUFFER

如何使用 SRP Batcher

不是所有的 Shader 都支持 SRP Batcher 的，通常來說我們需要做一些作業，才能使 Shader 支持它，下面是一個簡單 Shader，它僅僅簡單地將 _Color1 和 _Color2 的顏色相乘，Common.hlsl 僅提供用于變換的函式：

Shader "Custom/SRPSupport"
{
    Properties
    {
        _Color1 ("Color 1", Color) = (1,1,1,1)
        _Color2 ("Color 2", Color) = (1,1,1,1)
    }

    SubShader
    {
        Pass
        {
            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "./ShaderLibrary/Common.hlsl"

            float4 _Color1;
            float4 _Color2;

            struct Attributes
            {
                float3 positionOS : POSITION;
            };

            struct Varyings
            {
                float4 positionCS : SV_POSITION;
            };

            Varyings vert (Attributes input)
            {
                Varyings output;
                float3 positionWS = TransformObjectToWorld(input.positionOS);
                output.positionCS = TransformWorldToHClip(positionWS);
                return output;
            }

            float4 frag (Varyings input) : SV_TARGET
            {
                return _Color1 * _Color2;
            }
            ENDHLSL
        }
    }
}

這個 Shader 是不能使用 SRP Batcher 的，我們可以在 Inspector 中選中這個 Shader 看到 MessageBox 給出的原因：

Unity 告訴我們，材質的屬性（_Color1 和 _Color2）并沒有存放在 UnityPerMaterial cbuff 中，想來這是很合理的，SRP Batcher 本身就要把屬性統一管理，你不放在指定位置，人家就不愿意管，為此我們需要在 Shader 中做出如下修改：

CBUFFER_START(UnityPerMaterial)
    float4 _Color1;
    float4 _Color2;
CBUFFER_END

也就是說，我們要用 CBUFFER_START(UnityPerMaterial) 和 CBUFFER_END 包住所有 per material 的屬性，此外，當需要宣告常用變換矩陣時（自定義管線），需要用 CBUFFER_START(UnityPerDraw) 和 CBUFFER_END 包住這些矩陣，次序建議不要亂：

CBUFFER_START(UnityPerDraw)
    float4x4 unity_ObjectToWorld;
    float4x4 unity_WorldToObject;
    float4 unity_LODFade;
    real4 unity_WorldTransformParams;
CBUFFER_END

最后，如果是自定義管線，還需要在創建管線時用 C# 明確支持 SRP Batcher，

GraphicsSettings.useScriptableRenderPipelineBatching = true;

這樣，Shader 就能夠支持 SRP Batcher 了，

SRP Batcher 實際效果

場景中的 6 個 Cube 均使用同一材質時，

場景中的 6 個 Cube 使用兩種材質（紅綠兩種材質），這兩種材質采用了同一 Shader，

六種材質，一種 Shader，

可以發現，SRP Batcher 本質上并沒有減少 Draw Call 數量，Frame Debugger 里可以看到上面三幅圖的 SRP Batch 事件的 Draw Call 均為 6，也就意味著，繪制這六個 Cube 仍然需要 6 個 Draw Call，這和 SRP Batcher 原理是一致的，SRP Batcher 不降低 Draw Call 數量，而致力于降低每個 Draw Call 之前的設定作業的代價，

而如果不開啟 SRP Batcher，這六種材質（原本的材質手賤刪了，這里仍然是六個不同材質）所帶來的效果如下圖：

SRP Batcher 的適用場景及優劣勢

SRP Batcher 最主要的適用場景是，當場景中有非常多的 Material，但這些大量的 Material 只采用了少數幾種 Shader，或者說 Shader 變體比較少，

如果一個 Shader 即支持 SRP Batcher，又支持 GPU Instancing，那么會優先使用 SRP Batcher，也就是說，SRP Batcher 和 GPU Instancing 不兼容，

相較于 GPU Instancing，SRP 可以處理不同材質（但使用同一 Shader）的合批，這是它的巨大優勢，像是上圖中的六種材質如果交給 GPU Instancing 處理，那仍然會有六個獨立的 Draw Call （SRP Batcher 雖然也是六個 Draw Call，但每個 Draw Call 的代價要低非常多），但這不意味著無腦選擇 SRP Batcher，像是草和樹的 Shader 更建議只支持 GPU Instancing，因為此時 GPU Instancing 的效率更高，

更多 SRP Batcher 的使用效果可以參考： SRP Batcher: Speed up your rendering! | Unity Blog

此外，SRP Batcher 只支持 Mesh，更多資訊參考下圖：

為了獲得更好的性能表現，開發者應當要使每個 SRP Batch 盡量的大，也就是說需要更多的考慮同一 Shader 不同 Material，

參考：

1. Unity Blog: SRP Batcher: Speed up your rendering! https://blog.unity.com/technology/srp-batcher-speed-up-your-rendering
2. Unity Documentation: Manual: Scriptable Render Pipeline (SRP) Batcher https://docs.unity3d.com/2019.4/Documentation/Manual/SRPBatcher.html
3. 知乎: SRP Batcher & GPU Instancing 湯姆貓Xhttps://zhuanlan.zhihu.com/p/265153591
4. Catlike Coding Custom RPhttps://catlikecoding.com/unity/tutorials/custom-srp/draw-calls/

另外，CSDN 代碼段什么 Shader Language 都不支持，GLSL 沒有，HLSL 沒有，CG 也沒有~