問題：如何使用指定的計算填充 [score [TXT]] 列？有時計算將基于多行，具體取決于 [game] 列中的值。
我有一張包含 Metascores 和游戲名稱的表格，并且想要應用某種公式來自動計算條目的 AVG、MAX 和 MIN。上表有我想要的輸出。我正在使用 Office 365 - Excel。
當前表
| 元評分 | 得分平均 | 得分 MAX | 最低分數 | 游戲 |
|---|---|---|---|---|
| 87 | 刺客信條奧德賽 | |||
| 86 | 刺客信條奧德賽 | |||
| 83 | 刺客信條奧德賽 | |||
| 66 | 出血邊緣 | |||
| 62 | 出血邊緣 |
期望的輸出
| 元評分 | 得分平均 | 得分 MAX | 最低分數 | 游戲 |
|---|---|---|---|---|
| 87 | 85.3 | 87 | 83 | 刺客信條奧德賽 |
| 86 | 85.3 | 87 | 83 | 刺客信條奧德賽 |
| 83 | 85.3 | 87 | 83 | 刺客信條奧德賽 |
| 66 | 64 | 66 | 62 | 出血邊緣 |
| 62 | 64 | 66 | 62 | 出血邊緣 |
有些標題只出現一次，有些則出現幾次。是否有我可以應用的公式或腳本回圈遍歷表格并應用計算，或者輸出的不同建議？
謝謝你的幫助！！
uj5u.com熱心網友回復：
=UNIQUE(E2:E6)例如E10
=AVERAGEIF($E$2:$E$6,$E$10#,A2:A6)inA10并復制到右側。
或一次性使用LET：
=LET(data,A2:E6,
game,INDEX(data,,5),
unique,UNIQUE(game),
CHOOSE({1,2,3,4,5},
AVERAGEIF(game, unique,INDEX(data,,1)),
AVERAGEIF(game, unique,INDEX(data,,2)),
AVERAGEIF(game, unique,INDEX(data,,3)),
AVERAGEIF(game, unique,INDEX(data,,4)),
unique))
編輯：
更改描述后，這就是您所需要的：
B2使用中：=AVERAGEIF(E2:E6,E2:E6,A2:A6)
C2使用中：=MAXIFS(A2:A6,E2:E6,E2:E6)
D2使用中：=MINIFS(A2:A6,E2:E6,E2:E6)
If you'd have your data in two columns (let's say A20:B20) and would want a summary elsewhere, you could use the following:
=LET(data,A2:B6,
game,INDEX(data,,2),
score,INDEX(data,,1),
unique,UNIQUE(game),
CHOOSE({1,2,3,4},
unique,
AVERAGEIF(game,unique,score),
MAXIFS(score,game,unique),
MINIFS(score,game,unique)))
轉載請註明出處，本文鏈接：https://www.uj5u.com/yidong/447208.html
上一篇：從VBA中的散點圖中洗掉標記