無法使用VBA打開文本檔案

這是我的 excel vba 宏。我想將文本檔案串列轉換為特定檔案夾的 pdf。為此，我撰寫了從 word 檔案中打開單個文本檔案以保存為 pdf 格式的邏輯。但它不會保存為 pdf 檔案。誰能指導我的邏輯

Dim file As Variant
inp_dir = "C:\Users\HP\OneDrive\Desktop\vbatest\pdfconv\"
inp_file_name = Dir(inp_dir & "*.txt") 'txt path
inp_file = inp_dir & inp_file_name

Dim wdApp As New Word.Application, wdDoc As Word.Document


MsgBox (inp_file)

    ' Set wdDoc = Documents.Open(inp_file)
     Set wdDoc = Documents.Open(Filename:=inp_file, ReadOnly:=True, _
    AddToRecentFiles:=False, Format:=wdOpenFormatAuto, Visible:=False)
  
  wdDoc.SaveAs2 Filename:="inp_file" & Replace(inp_file, ".txt", ".pdf"), _
    FileFormat:=wdFormatPDF, AddToRecentFiles:=False
  wdDoc.Close False
  

uj5u.com熱心網友回復：

我猜你很接近 - 你的目標檔案名只有一個小錯誤：你寫Filename:="inp_file" & Replace(inp_file, ".txt", ".pdf")了 ，但是固定的字串"inp_file"沒有意義并且使檔案名無效。

我總是建議使用中間變數，這樣除錯和查找錯誤會容易得多。

還有一些小事：

• 您應該使用Option Explicit并宣告所有變數。
• file您宣告了一個從未使用過的變數。
• 將您的路徑宣告為常量

您的代碼可能如下所示：

Const inp_dir = "C:\Users\HP\OneDrive\Desktop\vbatest\pdfconv\"

Dim inp_file_name As String, inp_full_name As String

inp_file_name = Dir(inp_dir & "*.txt") 'txt path
inp_full_name = inp_dir & inp_file_name

Dim wdApp As New Word.Application, wdDoc As Word.Document
Set wdDoc = wdApp.Documents.Open(Filename:=inp_full_name, ReadOnly:=True, _
    AddToRecentFiles:=False, Format:=wdOpenFormatAuto, Visible:=False)
  
Dim pdf_Filename As String
pdf_Filename = Replace(inp_full_name, ".txt", ".pdf")
Debug.Print pdf_Filename 
wdDoc.SaveAs2 Filename:=pdf_Filename, FileFormat:=wdFormatPDF, AddToRecentFiles:=False
wdDoc.Close False

wdApp.Quit

uj5u.com熱心網友回復：

您的代碼非常接近運行。基本上，您需要使用您的wdApp物件打開 Word。這個例子展示了如何...

Option Explicit

Sub TxtToPDF()
    Dim inp_dir As String
    Dim inp_file_name As String
    Dim inp_file As String
    inp_dir = "C:\Temp\"
    inp_file_name = Dir(inp_dir & "*.txt")       'txt path
    
    Dim wordWasRunning As Boolean
    wordWasRunning = IsMSWordRunning
    
    Dim wdApp As Word.Application
    Set wdApp = AttachToMSWordApplication
    
    Do While Len(inp_file_name) > 0
        inp_file = inp_dir & inp_file_name
        Debug.Print "currently opening " & inp_file

        Dim wdDoc As Word.Document
        Set wdDoc = wdApp.Documents.Open(Filename:=inp_file, _
                                         ReadOnly:=True, _
                                         AddToRecentFiles:=False, _
                                         Format:=wdOpenFormatAuto, _
                                         Visible:=False)
        Dim out_file As String
        out_file = Replace(inp_file, ".txt", ".pdf")
        Debug.Print "saving as " & out_file
        wdDoc.SaveAs2 Filename:=out_file, _
                      FileFormat:=wdFormatPDF, AddToRecentFiles:=False
        wdDoc.Close False
        
        '--- get the next txt file
        inp_file_name = Dir
    Loop
    
    If Not wordWasRunning Then
        wdApp.Quit
    End If
End Sub

將此代碼放在另一個模塊中使用（來自我的個人庫）。

Option Explicit

Public Function IsMSWordRunning() As Boolean
    '--- quick check to see if an instance of MS Word is running
    Dim msApp As Object
    On Error Resume Next
    Set msApp = GetObject(, "Word.Application")
    If Err > 0 Then
        '--- not running
        IsMSWordRunning = False
    Else
        '--- running
        IsMSWordRunning = True
    End If
End Function

Public Function AttachToMSWordApplication() As Word.Application
    '--- finds an existing and running instance of MS Word, or starts
    '    the application if one is not already running
    Dim msApp As Word.Application
    On Error Resume Next
    Set msApp = GetObject(, "Word.Application")
    If Err > 0 Then
        '--- we have to start one
        '    an exception will be raised if the application is not installed
        Set msApp = CreateObject("Word.Application")
    End If
    Set AttachToMSWordApplication = msApp
End Function

標籤：vba ms-word

上一篇：使用VBA將Excel資料寫入字典

下一篇：MSProject-使用VBA添加“后繼者”列