Terraformfor_each嵌套解決方案

我需要訪問嵌套映射的元素，但我做不到，并且出現錯誤無法訪問原始型別值（字串）的屬性。

# GLUE
locals {
  glue_catalog_resources = {
    uni = {
      name = "mst_business_units",
      description = "Unidades de negocios"
      columns = [
        {
          name = "codigouni"
          type = "int"
          comment = "Code"
        },{
          name = "descuni"
          type = "varchar(256)"
          comment = "Description"
        },{
          name = "estado"
          type = "varchar(256)"
          comment = "Current status"
        }
      ]
    }
  }
}

resource "aws_glue_catalog_table" "glue_catalogs_redshift" {
  for_each      = local.glue_catalog_resources
  name          = each.value.name
  database_name = aws_glue_catalog_database.cl_sales.name
  description   = each.value.description
  retention     = 0
  table_type    = "EXTERNAL_TABLE"

  parameters = {
    EXTERNAL         = "TRUE"
    "classification" = "parquet"
  }

  storage_descriptor {
    location = ""
    input_format = "org.apache.hadoop.hive.ql.io.parquet.MapredParquetInputFormat"
    output_format = "org.apache.hadoop.hive.ql.io.parquet.MapredParquetOutputFormat"
    number_of_buckets = 0
    compressed = "false"
    stored_as_sub_directories = "false"

    ser_de_info {
      serialization_library = "org.apache.hadoop.hive.ql.io.parquet.serde.ParquetHiveSerDe"

      parameters = {
        "serialization.format" = 1
      }
    }

    parameters = {
      "typeOfData": "kinesis"
    }

    columns {
      name = [ for column in each.value.columns: [ for row in column: row.name ] ]
      type = [ for column in each.value.columns: [ for row in column: row.type ] ]
      comment = [ for column in each.value.columns: [ for row in column: row.comment ] ]
    }

  }
}

我需要在列標簽中包含從上面的地圖中讀取的名稱、型別和評論，但我做不到，正確的讀取方法是什么

columns {
      name = [ for column in each.column.value: [ for row in column: row.name ] [ for row in column: row.name ] [ for row in column: row.name ] [ for row in column: row.name
      type = [ for column in each.value.columns: [ for row in column: row.type ]
      comment = [ for column in each.value.columns: [ for row in column: row.comment ] ] ]
    }

uj5u.com熱心網友回復：

在這種情況下，columns是一個鍵值對串列，因此您需要for稍微調整第二個：

  name    = [for column in local.columns : [for k, v in column : v if k == "name"]]
  type    = [for column in local.columns : [for k, v in column : v if k == "type"]]
  comment = [for column in local.columns : [for k, v in column : v if k == "comment"]]

編輯：答案的第一部分解決了訪問串列元素的問題。但是，為了讓它按您的意愿作業，我建議進行一些更改。在區域變數中，您可以更改columns為物件映射：

locals {
  glue_catalog_resources = {
    uni = {
      name        = "mst_business_units",
      description = "Unidades de negocios"
      columns = {
        "codigouni" = {
          name    = "codigouni"
          type    = "int"
          comment = "Code"
        },
        "descuni" = {
          name    = "descuni"
          type    = "varchar(256)"
          comment = "Description"
        },
        "estado " = {
          name    = "estado"
          type    = "varchar(256)"
          comment = "Current status"
        }
      }
    }
  }
}

然后，在 columns 塊中，您將執行以下操作：

resource "aws_glue_catalog_table" "glue_catalogs_redshift" {
  for_each      = local.glue_catalog_resources
  name          = each.value.name
  database_name = aws_glue_catalog_database.cl_sales.name
  description   = each.value.description
  retention     = 0
  table_type    = "EXTERNAL_TABLE"

  parameters = {
    EXTERNAL         = "TRUE"
    "classification" = "parquet"
  }

  storage_descriptor {
    location                  = ""
    input_format              = "org.apache.hadoop.hive.ql.io.parquet.MapredParquetInputFormat"
    output_format             = "org.apache.hadoop.hive.ql.io.parquet.MapredParquetOutputFormat"
    number_of_buckets         = 0
    compressed                = "false"
    stored_as_sub_directories = "false"

    ser_de_info {
      serialization_library = "org.apache.hadoop.hive.ql.io.parquet.serde.ParquetHiveSerDe"

      parameters = {
        "serialization.format" = 1
      }
    }

    parameters = {
      "typeOfData" : "kinesis"
    }

    dynamic "columns" {
      for_each = each.value.columns
      content {
        name    = columns.value.name
        type    = columns.value.type
        comment = columns.value.comment
      }
    }
  }
}

這種方法使用dynamic[1] 和for_each[2] 遍歷所有列并將所需的值分配給引數。

[1] https://developer.hashicorp.com/terraform/language/expressions/dynamic-blocks

[2] https://developer.hashicorp.com/terraform/language/meta-arguments/for_each

標籤：亚马逊网络服务地形yamlterraform-provider-aws

上一篇：無法在僅AWSIPv6的EC2實體中pinggithub

下一篇：如何在AWS中提供自定義后端代碼，以便Lambda函式可以匯入它