一基礎

// 這里指定 Shader 的名字,不要求跟檔案名保持一致
Shader "Tint/First"{ 
    // 屬性
    Properties{
        _Color("Color",Color)= (1,1,1,1)  // 顏色
        _Vertor("Vector",Vector)=(1,2,3,4) //一維向量
        _Int("Int",Int) = 1 // 整數
        _Float("Float",Float) = 2.3 //浮點數
        _Range("Range",Range(1,10))= 1 // 范圍
        _MainTex("Main Tex",2D) = "white"{} // 圖片紋理
        _Cube("Cube",Cube)= "white"{} // 天空盒 
        _3D("3D Tex",3D) ="white"{} // 3D 紋理
    }
    //SubShader 可以寫很多個 顯卡運行效果的時候,從第一個SubShader開始,如果第一個 SubShader里面的效果可以實作,
    //那么就使用第一個 SubShader ,如果顯卡這個 SubShader 里面的某些效果它實作不理,它會自動去實作第二個SubShader
    //如果所有的 SubShader 都無法運行,那么將運行  Fallback "" 
    SubShader{
        // 至少有一個Pass
        Pass{
            // 使用 CG 語言撰寫 Shader 代碼
            CGPROGRAM
            // 頂點函式,這里只是宣告了頂點函式的函式名
            // 基本作用是 完成頂點坐標從模型空間到剪裁空間的轉換(從游戲環境轉換到視野相機螢屏上)
            #pragma vertex vert
            // 片元函式,這里只是宣告了片元函式的片元名
            // 基本作用是回傳模型對應的螢屏的每一個像素的顏色值
            #pragma fragment frag

            // 從應用程式傳遞到 頂點函式的所有語意
            struct a2v{
                // 告訴Unity把模型空間下的頂點坐標填充給 vertex
                float4 vertex : POSITION; 

                // 告訴Unity把模型空間下的法線方向填充給 normal
                float4 normal : NORMAL;

                // 告訴Unity把模型空間下的切線方向填充給 tangent  (TANGENT 0~n)
                float4 tangent : TANGENT;

                // 告訴Unity把第一套紋理坐標填充給 texcoord   (TEXCOORD 0~n)
                float4 texcoord : TEXCOORD0;

                // 告訴Unity把模型空間下的頂點顏色填充給 color (COLOR 0~n)
                fixed3 color : COLOR0;
                
            };

            // 從頂點函式 傳遞給 片元函式的所有語意
            struct v2f{
                // 剪裁空間中的頂點坐標(一般是系統直接使用)
                float4 position:SV_POSITION;

                // 不一定傳遞顏色,可以傳遞一組4個的值
                fixed3 color :COLOR0;

                // 不一定傳遞顏色,可以傳遞一組4個的值 (TEXCOORD 0~7)
                float4 texcoord:TEXCOORD0;
            };

            // 通過語意告訴系統,我這個引數是干嘛的,比如 POSITION 是告訴系統我需要頂點坐標
            // SV_POSITION這個語意用來解釋說明回傳值,意思是回傳值是剪裁空間下的頂點坐標
            // v2f vert(a2v v : POSITION):SV_POSITION{}
            v2f vert(a2v v){
                v2f f;
                f.position = UnityObjectToClipPos(v.vertex);
                // 這里場景中可以建一個正方體,它的模型空間下 法線(1,0,0)為紅色 法線(0,1,0)為綠色 法線(0,0,1)為藍色 
                // 其他法線方向是負數所以為黑色 過渡系統會自動進行插值運算
                f.color = v.normal;
                return f;
            }
            // 片元函式傳遞給 系統的所有語意
            //SV_TARGET 這個語意用來解釋說明回傳值,意思是回傳值是模型對應的螢屏的每一個像素的顏色值
            fixed4 frag(v2f f):SV_TARGET{
                // 模型顯示法線顏色
                return fixed4(f.color,1.0);
            }
            ENDCG
        }
    }
    Fallback "VertexLit"
}

二光照

漫反射左為Unity2018.4 右為Unity2020.1.5 Urp 添加了 LightMode = ForwardBase之后, 為啥Urp中沒效果,有人知道可以評論區說一下嗎,謝謝

UnityCG.cginc常用函式:

 /* 
 UnityCG.cginc 中一些常用的函式
 //攝像機方向(視角方向)
 float3 WorldSpaceViewDir(float4 v) 根據模型空間中的頂點坐標 得到(世界空間)從這個點到攝像機的觀察方向
 float3 UnityWorldSpaceViewDir(float4 v) 世界空間中的頂點坐標 ==> 世界空間從這個點到攝像機的觀察方向
 float3 ObjSpaceViewDir(float4 v) 模型空間中的頂點坐標 ==> 模型空間從這個點到攝像機的觀察
 //光源方向
 float3 WorldSpaceLightDir(float4 v) 模型空間中的頂點坐標 ==> 世界空間中從這個點到光源的方向
 float3 UnityWorldSpaceLightDir(float4 v) 世界空間中的頂點坐標 ==> 世界空間中從這個點到光源的方向
 float3 ObjSpaceLightDir(float4 v) 模型空間中的頂點坐標 ==> 模型空間中從這個點到光源的
 // 方向轉換
 float3 UnityObjectToWorldNormal(float3 norm) 把法線方向從模型空間==> 世界空間
 float3 UnityObjectToWorldDir(float3 dir) 把方向從模型空間 ==> 世界空間
 float3 UnityWorldToObjectDir(float3 dir) 把方向從世界空間 ==> 模型空間
 */

1.漫反射普通

公式: **漫反射 Diffuse = 直射光顏色 * max(0,cos夾角(光和法線的夾角)) cos(θ) = 光方向·法線方向**

// 普通漫反射
fixed3 diffuse = _LightColor0.rgb * dot(worldNormalDir,worldLightDir) * _Color.rgb;

大于90度夾角就認為是黑的

2. 漫反射半蘭伯特光照模型

公式: 漫反射 Diffuse = 直射光顏色 * max(0,0.5*cos夾角(光和法線的夾角) + 0.5) cos(θ) = 光方向·法線方向

     // 半蘭伯特光照模型 漫反射
     fixed3  halfLambert = 0.5* dot(worldNormalDir,worldLightDir) + 0.5;
     fixed3 diffuse = _LightColor0.rgb * halfLambert * _Color.rgb;

0-180度漸變,只有跟光方向180度夾角才會黑,也是漸變過去的

 float halfLambert = dot(worldNormalDir,worldLightDir)*0.5 + 0.5;

這個公式怎么來的呢?請看下面3張圖

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

/*   什么是光照模型 
光照模型就是一個公式,使用這個公式來計算某個點的光照效果
標準光照模型
在標準光照模型里面,我們把進入攝像機的光分為下面四個部分:
1.自發光
2.高光反射 Specular
3.環境光

4.漫反射 Diffuse = 直射光顏色 * max(0,cos夾角(光和法線的夾角))
當光和法線方向為單位向量的時候,可得公式: cos(θ) = 光方向·法線方向

一些公式 a · b = |a| × |b| × cos(θ)
其中：
|a| 是 矢量 a 的量值
|b| 是 矢量 b 的量值
θ 是 a 和 b 之間的 角度

點積的值:
u的大小、v的大小、u,v夾角的余弦，在u,v非零的前提下，點積如果為負，則u,v形成的角大于90度；如果為零，那么u,v垂直；如果為正，那么u,v形成的角為銳角，
兩個單位向量的點積得到兩個向量的夾角的cos值，通過它可以知道兩個向量的相似性，利用點積可判斷一個多邊形是面向攝像機還是背向攝像機，
向量的點積與它們夾角的余弦成正比，因此在聚光燈的效果計算中，可以根據點積來得到光照效果，如果點積越大，說明夾角越小，則物體離光照的軸線越近，光照越強，

*/

Shader "Unlit/sLight"
{
    Properties
    {
        _Diffuse("Diffuse Color",Color)=(1,1,1,1)
    }
    SubShader
    {
        Pass
        {
            // 只有定義了正確的 LightMode, 才能得到一些 Untiy的內置光照變數
            // 添加這個 LightMode 會在 Unity2020.1.5 Urp專案中無法顯現效果
            // Tags{"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // 包含 Unity的內置檔案,才可以使用 unity內置的一些變數
            #include "Lighting.cginc"
            #include "UnityCG.cginc"
            
            fixed4 _Diffuse;


            struct a2v
            {
                float4 vertex : POSITION;
                float4 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                fixed3 color : COLOR0;
                fixed3 worldNormalDirFrag:TEXCOORD0;
            };

            v2f vert (a2v v)
            {
                v2f o;
                // 頂點轉到 剪裁空間
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldNormalDirFrag = normalize(UnityObjectToWorldNormal(v.normal));
                return o;
                /*   頂點運算漫反射     

                // 世界空間法線方向計算第一種方式 需引入  #include "UnityCG.cginc"
                float3 worldNormalDir = normalize(UnityObjectToWorldNormal(v.normal));
                //世界空間法線方向計算第二種方式
                //float3 worldNormalDir = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
                
                // 世界空間光的方向 對于每個頂點來說,光的位置就是光的方向,因為光是平行光
                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 環境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                // 漫反射 Diffuse = 直射光顏色 * max(0,cos夾角(光和法線的夾角))  cos(θ) = 光方向·法線方向
                fixed3 diffuse= _LightColor0.rgb * max(0,dot(worldNormalDir,worldLightDir))*_Diffuse.rgb;

                // 為啥 _Diffuse.rgb用乘, ambient用加法呢?
                // 因為 環境光是 4種光之一,漫反射光+環境光會增強,而 _Diffuse.rgb 只是漫反射的顏色,它屬于漫反射的一部分
                o.color = diffuse + ambient; 
                return o;*/
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // 世界空間法線方向計算第一種方式 需引入  #include "UnityCG.cginc"
                float3 worldNormalDir = normalize(i.worldNormalDirFrag);

                // 世界空間光的方向 對于每個頂點來說,光的位置就是光的方向,因為光是平行光
                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 環境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                // // 普通漫反射 Diffuse = 直射光顏色 * max(0,cos夾角(光和法線的夾角))  cos(θ) = 光方向·法線方向
                // fixed3 diffuse= _LightColor0.rgb * max(0,dot(worldNormalDir,worldLightDir))*_Diffuse.rgb;

                // 半蘭伯特光照模型 max() 函式不需要了 因為這個時候它的值已經不會小于0了
                float halfLambert = dot(worldNormalDir,worldLightDir)*0.5 + 0.5;
                fixed3 diffuse= _LightColor0.rgb * halfLambert *_Diffuse.rgb;

                fixed3 col = diffuse + ambient;
                return fixed4(col,1);
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}

3.高光反射

公式: 高光 Specular =直射光* pow(max(cosx,0),10)*反射光顏色 cosx=dot(反射光方向,視野方向)

  // 反射光方向 = reflect(入射光方向 , 法線方向) 
  //那么問題來了 ,下面這個worldLightDir為啥要加負號呢?
  // 因為worldLightDir 是點到頂光坐標的方向,而我們需要的事 光到頂點的入射光方向
  fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormalDir));
  // 高光
  fixed3 specular =  _LightColor0.rgb * pow(max(0,dot(reflectDir,worldViewDir)),_Gloss )* _SpeularColor.rgb;

這個網站完整公式沒法繪制尷尬我口述一下把

1圖,max(cos(x),0) 就不會有小于0的值,

2,3圖 pow(cos(x),10) 當 10這個值越大,線就越陡峭,高光區域也就越小, 只看x < (3.14/2),即Cos(x)小于等于90度的情況,后面的陡峭便是需要加max()函式的理由, pow(max(cosx,0),10),當大于90度時,max(cos(x),0)都為0,所以pow(max(cosx,0),10)大于90度的值肯定也是0

/* 
高光 Specular =直射光* pow(max(cosx,0),10)*反射光顏色   x=dot(反射光方向,視野方向)

 */
Shader "Tint/Specular"{
    Properties {
        _Color("Color",Color)= (1,1,1,1)
        _SpeularColor("Specular Color",Color) = (1,0,0,1)
        _Gloss("Gloss",Range(1,200)) = 10

    }
    SubShader{
        Tags{"LightMode"="ForwardBase"}
        Pass{
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            fixed4 _Color;
            fixed4 _SpeularColor;
            half _Gloss;

            struct a2v{
                float4 vertex : POSITION;
                float3 normal: NORMAL;
            };
            struct v2f{
                float4 vertex : SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldView: TEXCOORD1;
            };

            v2f vert(a2v v){
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                // Mul(x,_World2Object) 物件空間轉世界空間
                // Mul(_World2Object,x) 世界空間轉物件空間
                // 攝像機世界坐標  _WordSpaceCameraPos.xyz
                //  為什么_WordSpaceCameraPos.xyz要加.xyz呢? 因為 v.vertex 是4階的 而我們只需要xyz即可
                o.worldView = _WorldSpaceCameraPos.xyz-mul(v.vertex,unity_WorldToObject).xyz;
                return o;
            }

            fixed4 frag(v2f f):SV_TARGET{
                // 世界法線單位向量
                fixed3 worldNormalDir = normalize(f.worldNormal);

                // 世界光方向單位向量
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                // 半蘭伯特
                fixed3  halfLambert = 0.5* dot(worldNormalDir,worldLightDir) + 0.5;
                fixed3 diffuse = _LightColor0.rgb * halfLambert * _Color.rgb;

                // 環境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                // 世界空間視野方向
                fixed3 worldViewDir = normalize(f.worldView );

                // 反射光方向 = reflect(入射光方向 , 法線方向) 
                //那么問題來了 ,下面這個worldLightDir為啥要加負號呢?
                // 因為worldLightDir 是點到頂光坐標的方向,而我們需要的事 光到頂點的入射光方向
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormalDir));

                // 高光
                fixed3 specular =  _LightColor0.rgb * pow(max(0,dot(reflectDir,worldViewDir)),_Gloss )* _SpeularColor.rgb;

                // 最后渲染顏色
                fixed3 finalCol = ambient + diffuse + specular;


                return fixed4(finalCol,1);
            }


            ENDCG
        }
    }
    Fallback "Diffuse"
}

4. Blinn-Phone 高光光照模型

公式: Blinn-Phone Specular =直射光* pow(max(cosx,0),10)*反射光顏色 x= cosx=dot(平行光方向和視野方向之間的平分線方向,法線方向)

 // 平行光方向 = 世界光方向 + 世界視野方向  兩個向量相加就是他們之間的平方線

 fixed3 halfDir = normalize(worldLightDir+worldViewDir);

fixed3 specular =  _LightColor0.rgb * pow(max(0,dot(worldNormalDir,halfDir)),_Gloss )* _SpeularColor.rgb;

/* 
Blinn-Phone高光 Specular =直射光* pow(max(cosx,0),10)*反射光顏色   x=平行光方向和視野方向的平分線
 */
Shader "Tint/sBlinnPhoneSpecular"{
    Properties {
        _Color("Color",Color)= (1,1,1,1)
        _SpeularColor("Specular Color",Color) = (1,0,0,1)
        _Gloss("Gloss",Range(1,200)) = 10

    }
    SubShader{
        Tags{"LightMode"="ForwardBase"}
        Pass{
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            fixed4 _Color;
            fixed4 _SpeularColor;
            half _Gloss;

            struct a2v{
                float4 vertex : POSITION;
                float3 normal: NORMAL;
            };
            struct v2f{
                float4 vertex : SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldView: TEXCOORD1;
            };

            v2f vert(a2v v){
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                // Mul(x,_World2Object) 物件空間轉世界空間
                // Mul(_World2Object,x) 世界空間轉物件空間
                // 攝像機世界坐標  _WordSpaceCameraPos.xyz
                //  為什么_WordSpaceCameraPos.xyz要加.xyz呢? 因為 v.vertex 是4階的 而我們只需要xyz即可
                o.worldView = _WorldSpaceCameraPos.xyz-mul(v.vertex,unity_WorldToObject).xyz;
                return o;
            }

            fixed4 frag(v2f f):SV_TARGET{
                // 世界法線單位向量
                fixed3 worldNormalDir = normalize(f.worldNormal);

                // 世界光方向單位向量
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

                // 半蘭伯特
                fixed3  halfLambert = 0.5* dot(worldNormalDir,worldLightDir) + 0.5;
                fixed3 diffuse = _LightColor0.rgb * halfLambert * _Color.rgb;

                // 環境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;

                // 世界空間視野方向
                fixed3 worldViewDir = normalize(f.worldView );

                // 平行光方向 = 世界光方向 + 世界視野方向  兩個向量相加就是他們之間的平方線
                fixed3 halfDir = normalize(worldLightDir+worldViewDir);
                // Blinn-Phone高光
                fixed3 specular =  _LightColor0.rgb * pow(max(0,dot(worldNormalDir,halfDir)),_Gloss )* _SpeularColor.rgb;

                // 最后渲染顏色
                fixed3 finalCol = ambient + diffuse + specular;


                return fixed4(finalCol,1);
            }


            ENDCG
        }
    }
    Fallback "Diffuse"
}

轉載請註明出處，本文鏈接：https://www.uj5u.com/ruanti/197110.html

標籤：其他

上一篇：用 JavaScript 實作一個 TicTacToe 游戲 —— 編程訓練

下一篇：狼人殺背后的秘密，實時語音你不知道的那些事

一篇博客入門Unity Shader

一 基礎

二 光照

1.漫反射 普通

公式: 漫反射 Diffuse = 直射光顏色 * max(0,cos夾角(光和法線的夾角)) cos(θ) = 光方向·法線方向

2. 漫反射 半蘭伯特光照模型