鴻蒙內核原始碼分析(例外接管篇) | 社會很單純 , 復雜的是人 | 中文注解HarmonyOS原始碼

百萬漢字注解 >> 精讀內核原始碼,中文注解分析, 深挖地基工程,大腦永久記憶,四大碼倉每日同步更新< gitee | github | csdn | coding >

百篇博客分析 >> 故事說內核,問答式導讀,生活式比喻,表格化說明,圖形化展示,多站點每日同步更新< oschina | csdn | weharmony >

系列篇ARM部分說明基于ARM720T.pdf檔案.

為何要有例外接管?

拿小孩成長打比方,大人總希望孩子能健康成長,但在成長程序中總會遇到各種各樣的問題,樹欲靜而風不止,成長路上有危險,有時是自己的問題有時是外在環境問題.就像抖音最近的流行口水歌一樣,社會很單純,復雜的是人啊,每次聽到都想站起來扭幾下.哎! 老衲到底做錯什么了?

比如:老被小朋友欺負怎么弄? 發現亂花錢怎么搞? 青春期發育怎么應對? 失戀要跳樓又怎么辦? 意思超過他的認知范圍,就是靠它自己解決不了了,就需要有更高權限,更高智慧的人介入進來,幫著解決,干擦屁股的事.

那么應用程式就是那個小孩,內核就是監護人,有更高的權限,更高的智慧.而且監護人還不止一個,而是六個,每個監護人對應解決一種情況,情況發生了就由它來接管這件事的處理,小朋友你就別管了,先把你關家里,處理好了外面安全了再把應用程式放出來玩去.

這六個人處理問題都自帶工具,有標準的解決方案,有自己獨立的辦公場所,辦公場所就是堆疊空間(獨立的),標準解決方案就是私有代碼段,放在固定的位置.而自帶的工具就是 SPSR_***,SP_***,LR_***暫存器組.詳見 系列篇之作業模式篇 ,這里再簡單回顧下有哪些作業模式,包括小孩自己(用戶模式)一共是七種模式.

七種作業模式

圖來源于 ARM720T.pdf第43頁,在ARM體系中,CPU作業在以下七種模式中:
在這里插入圖片描述

用戶模式（usr）：屬于正常的用戶模式，不能直接切換到其他模式,ARM處理器正常的程式執行狀態，
快速中斷模式（fiq）：支持高速資料傳輸及通道處理，FIQ例外回應時進入此模式
外部中斷模式（irq）：用于通用中斷處理，IRQ例外回應時進入此模式
管理模式（svc）：作業系統保護模式，系統復位和軟體中斷回應時進入此模式（由系統呼叫執行軟中斷SWI命令觸發）
資料訪問終止模式（abt）：當資料或指令預取終止時進入該模式，可用于處理存盤器故障、實作虛擬存盤器和存盤器保護，
系統模式（sys）：運行具有特權的作業系統任務,與用戶模式類似，但具有可以直接切換到其他模式等特權
未定義指令中止模式（und）：處理未定義的指令陷阱，當未定義的指令執行時進入該模式，可用于支持硬體協處理器的軟體仿真，

除用戶模式外，其余6種作業模式都屬于特權模式

特權模式中除了系統模式以外的其余5種模式稱為例外模式
大多數程式運行于用戶模式
進入特權模式是為了處理中斷、例外、或者訪問被保護的系統資源
硬體權限級別：系統模式 > 例外模式 > 用戶模式
快中斷(fiq)與慢中斷(irq)區別：快中斷處理時禁止中斷

每種模式都有自己獨立的入口和獨立的運行堆疊空間. 系列篇之CPU篇 已介紹過只要提供了入口函式和運行空間,CPU就可以干活了.入口函式解決了指令來源問題,運行空間解決了指令的運行場地問題.
而且在多核情況下,每個CPU核的每種特權模式都有自己獨立的堆疊空間.注意是特權模式下的堆疊空間,用戶模式的堆疊空間是由用戶(應用)程式提供的.

官方概念

例外接管是作業系統對運行期間發生的例外情況（芯片硬體例外）進行處理的一系列動作，例如列印例外發生時當前函式的呼叫堆疊資訊、CPU現場資訊、任務的堆疊情況等，
例外接管作為一種調測手段，可以在系統發生例外時給用戶提供有用的例外資訊，譬如例外型別、發生例外時的系統狀態等，方便用戶定位分析問題，

鴻蒙的例外接管，在系統發生例外時的處理動作為：顯示例外發生時正在運行的任務資訊（包括任務名、任務號、堆疊大小等），以及CPU現場等資訊，

進入和退出例外方式

例外接管切換需要處理好兩件事:

一個是代碼要切到哪個位置,也就是要重置PC暫存器,每種例外模式下的切換方式如圖:

在這里插入圖片描述

另一個是要恢復每種模式的狀態,即 CPSR(1個) 和 SPSR(共5個) 的關系,對M[4:0]的修改,如圖:

以下是M[4:0]在每種模式下具體操作方式:

在這里插入圖片描述

堆疊幀

每個函式都有自己的堆疊空間，稱為堆疊幀，呼叫函式時，會創建子函式的堆疊幀，同時將函式入參、區域變數、暫存器入堆疊，堆疊幀從高地址向低地址生長,也就是說堆疊底是高地址,堆疊頂是底地址. 詳見 系列篇之用堆疊方式篇

以ARM32 CPU架構為例，每個堆疊幀中都會保存PC、LR、SP和FP暫存器的歷史值，
堆疊分析原理如下圖所示，實際堆疊資訊根據不同CPU架構有所差異，此處僅做示意，
圖中不同顏色的暫存器表示不同的函式，可以看到函式呼叫程序中，暫存器的保存，通過FP暫存器，堆疊回溯到例外函式的父函式，繼續按照規律對堆疊進行決議，推出函式呼叫關系，方便用戶定位問題，
在這里插入圖片描述

解讀

LR暫存器（Link Register），鏈接暫存器，指向函式的回傳地址，
R11：可以用作通用暫存器，在開啟特定編譯選項時可以用作幀指標暫存器FP，用來實作堆疊回溯功能，
GNU編譯器（gcc）默認將R11作為存盤變數的通用暫存器，因而默認情況下無法使用FP的堆疊回溯功能，為支持呼叫堆疊決議功能，需要在編譯引數中添加-fno-omit-frame-pointer選項，提示編譯器將R11作為FP使用，
FP暫存器（Frame Point），幀指標暫存器，指向當前函式的父函式的堆疊幀起始地址，利用該暫存器可以得到父函式的堆疊幀，從堆疊幀中獲取父函式的FP，就可以得到祖父函式的堆疊幀，以此類推，可以追溯程式呼叫堆疊，得到函式間的呼叫關系，
當系統發生例外時，系統列印例外函式的堆疊幀中保存的暫存器內容，以及父函式、祖父函式的堆疊幀中的LR、FP暫存器內容，用戶就可以據此追溯函式間的呼叫關系，定位例外原因，

六種例外模式實作代碼

/* Define exception type ID */		//ARM處理器一共有7種作業模式，除了用戶和系統模式其余都叫例外作業模式
#define OS_EXCEPT_RESET          0x00	//重置功能，例如：開機就進入CPSR_SVC_MODE模式
#define OS_EXCEPT_UNDEF_INSTR    0x01	//未定義的例外，就是others
#define OS_EXCEPT_SWI            0x02	//軟中斷
#define OS_EXCEPT_PREFETCH_ABORT 0x03	//預取例外(取指例外), 指令三步驟: 取指,譯碼,執行, 
#define OS_EXCEPT_DATA_ABORT     0x04	//資料例外
#define OS_EXCEPT_FIQ            0x05	//快中斷例外
#define OS_EXCEPT_ADDR_ABORT     0x06	//地址例外
#define OS_EXCEPT_IRQ            0x07	//普通中斷例外

地址例外處理(Address abort)

@ Description: Address abort exception handler
_osExceptAddrAbortHdl: @地址例外處理
    SUB     LR, LR, #8                                       @ LR offset to return from this exception: -8.
    STMFD   SP, {R0-R7}                                      @ Push working registers, but don`t change SP.

    MOV     R0, #OS_EXCEPT_ADDR_ABORT                        @ Set exception ID to OS_EXCEPT_ADDR_ABORT.

    B       _osExceptDispatch                                @跳到例外分發統一處理

快中斷處理(fiq)

@ Description: Fast interrupt request exception handler
_osExceptFiqHdl: @快中斷例外處理
    SUB     LR, LR, #4                                       @ LR offset to return from this exception: -4.
    STMFD   SP, {R0-R7}                                      @ Push working registers.

    MOV     R0, #OS_EXCEPT_FIQ                               @ Set exception ID to OS_EXCEPT_FIQ.

    B       _osExceptDispatch                                @ Branch to global exception handler.

解讀

快中斷處理時需禁用普通中斷

取指例外(Prefectch abort)

@ Description: Prefectch abort exception handler
_osExceptPrefetchAbortHdl:
#ifdef LOSCFG_GDB
#if __LINUX_ARM_ARCH__ >= 7
    GDB_HANDLE OsPrefetchAbortExcHandleEntry
#endif
#else
    SUB     LR, LR, #4                                       @ LR offset to return from this exception: -4.
    STMFD   SP, {R0-R7}                                      @ Push working registers, but don`t change SP.
    MOV     R5, LR
    MRS     R1, SPSR

    MOV     R0, #OS_EXCEPT_PREFETCH_ABORT                    @ Set exception ID to OS_EXCEPT_PREFETCH_ABORT.

    AND     R4, R1, #CPSR_MASK_MODE                          @ Interrupted mode
    CMP     R4, #CPSR_USER_MODE                              @ User mode
    BEQ     _osExcPageFault                                   @ Branch if user mode

_osKernelExceptPrefetchAbortHdl:
    MOV     LR, R5
    B       _osExceptDispatch                                @ Branch to global exception handler.
#endif

資料訪問例外(Data abort)

@ Description: Data abort exception handler
_osExceptDataAbortHdl: @資料例外處理,缺頁就屬于資料例外
#ifdef LOSCFG_GDB
#if __LINUX_ARM_ARCH__ >= 7
    GDB_HANDLE OsDataAbortExcHandleEntry
#endif
#else
    SUB     LR, LR, #8                                       @ LR offset to return from this exception: -8.
    STMFD   SP, {R0-R7}                                      @ Push working registers, but don`t change SP.
    MOV     R5, LR
    MRS     R1, SPSR

    MOV     R0, #OS_EXCEPT_DATA_ABORT                        @ Set exception ID to OS_EXCEPT_DATA_ABORT.

    B     _osExcPageFault   @跳到缺頁例外處理
#endif

軟中斷處理(swi)

@ Description: Software interrupt exception handler
_osExceptSwiHdl: @軟中斷例外處理
    SUB     SP, SP, #(4 * 16)	@先申請16個堆疊空間用于處理本次軟中斷
    STMIA   SP, {R0-R12}		@保存R0-R12暫存器值
    MRS     R3, SPSR			@讀取本模式下的SPSR值
    MOV     R4, LR				@保存回跳暫存器LR

    AND     R1, R3, #CPSR_MASK_MODE                          @ Interrupted mode 獲取中斷模式
    CMP     R1, #CPSR_USER_MODE                              @ User mode	是否為用戶模式
    BNE     OsKernelSVCHandler                               @ Branch if not user mode 非用戶模式下跳轉
	@ 當為用戶模式時,獲取SP和LR寄出去值
    @ we enter from user mode, we need get the values of  USER mode r13(sp) and r14(lr).
    @ stmia with ^ will return the user mode registers (provided that r15 is not in the register list).
    MOV     R0, SP											 @獲取SP值,R0將作為OsArmA32SyscallHandle的引數
    STMFD   SP!, {R3}                                        @ Save the CPSR 入堆疊保存CPSR值
    ADD     R3, SP, #(4 * 17)                                @ Offset to pc/cpsr storage 跳到PC/CPSR存盤位置
    STMFD   R3!, {R4}                                        @ Save the CPSR and r15(pc) 保存LR暫存器
    STMFD   R3, {R13, R14}^                                  @ Save user mode r13(sp) and r14(lr) 保存用戶模式下的SP和LR暫存器
    SUB     SP, SP, #4
    PUSH_FPU_REGS R1	@保存中斷模式(用戶模式模式)											

    MOV     FP, #0                                           @ Init frame pointer
    CPSIE   I	@開中斷,表明在系統呼叫期間可回應中斷
    BLX     OsArmA32SyscallHandle	/*交給C語言處理系統呼叫*/
    CPSID   I	@執行后續指令前必須先關中斷

    POP_FPU_REGS R1											 @彈出FP值給R1
    ADD     SP, SP,#4										 @ 定位到保存舊SPSR值的位置
    LDMFD   SP!, {R3}                                        @ Fetch the return SPSR 彈出舊SPSR值
    MSR     SPSR_cxsf, R3                                    @ Set the return mode SPSR 恢復該模式下的SPSR值

    @ we are leaving to user mode, we need to restore the values of USER mode r13(sp) and r14(lr).
    @ ldmia with ^ will return the user mode registers (provided that r15 is not in the register list)

    LDMFD   SP!, {R0-R12}									 @恢復R0-R12暫存器
    LDMFD   SP, {R13, R14}^                                  @ Restore user mode R13/R14 恢復用戶模式的R13/R14暫存器
    ADD     SP, SP, #(2 * 4)								 @定位到保存舊PC值的位置
    LDMFD   SP!, {PC}^                                       @ Return to user 切回用戶模式運行

普通中斷處理(irq)

OsIrqHandler:	@硬中斷處理,此時已切換到硬中斷堆疊
    SUB     LR, LR, #4
    /* push r0-r3 to irq stack */
    STMFD   SP, {R0-R3}		@r0-r3暫存器入 irq 堆疊
    SUB     R0, SP, #(4 * 4)@r0 = sp - 16
    MRS     R1, SPSR		@獲取程式狀態控制暫存器
    MOV     R2, LR			@r2=lr

    /* disable irq, switch to svc mode */@超級用戶模式(SVC 模式)，主要用于 SWI(軟體中斷)和 OS(作業系統)，
    CPSID   i, #0x13				@切換到SVC模式,此處一切換,后續指令將入SVC的堆疊
									@CPSID i為關中斷指令,對應的是CPSIE
    /* push spsr and pc in svc stack */
    STMFD   SP!, {R1, R2} @實際是將 SPSR,和LR入堆疊,入堆疊順序為 R1,R2,SP自增
    STMFD   SP, {LR}	  @LR再入堆疊,SP不自增

    AND     R3, R1, #CPSR_MASK_MODE	@獲取CPU的運行模式
    CMP     R3, #CPSR_USER_MODE		@中斷是否發生在用戶模式
    BNE     OsIrqFromKernel			@中斷不發生在用戶模式下則跳轉到OsIrqFromKernel

    /* push user sp, lr in svc stack */
    STMFD   SP, {R13, R14}^ 		@sp和LR入svc堆疊

解讀

普通中斷處理時可以回應快中斷

未定義例外處理(undef)

@ Description: Undefined instruction exception handler
_osExceptUndefInstrHdl:@出現未定義的指令處理
#ifdef LOSCFG_GDB
    GDB_HANDLE OsUndefIncExcHandleEntry
#else
                                                              @ LR offset to return from this exception:  0.
    STMFD   SP, {R0-R7}                                       @ Push working registers, but don`t change SP.

    MOV     R0, #OS_EXCEPT_UNDEF_INSTR                        @ Set exception ID to OS_EXCEPT_UNDEF_INSTR.

    B       _osExceptDispatch                                 @ Branch to global exception handler.

#endif

例外分發統一處理

_osExceptDispatch: @例外模式統一分發處理
    MRS     R2, SPSR                                         @ Save CPSR before exception.
    MOV     R1, LR                                           @ Save PC before exception.
    SUB     R3, SP, #(8 * 4)                                 @ Save the start address of working registers.

    MSR     CPSR_c, #(CPSR_INT_DISABLE | CPSR_SVC_MODE)      @ Switch to SVC mode, and disable all interrupts
    MOV     R5, SP
    EXC_SP_SET __exc_stack_top, OS_EXC_STACK_SIZE, R6, R7

    STMFD   SP!, {R1}                                        @ Push Exception PC
    STMFD   SP!, {LR}                                        @ Push SVC LR
    STMFD   SP!, {R5}                                        @ Push SVC SP
    STMFD   SP!, {R8-R12}                                    @ Push original R12-R8,
    LDMFD   R3!, {R4-R11}                                    @ Move original R7-R0 from exception stack to original stack.
    STMFD   SP!, {R4-R11}
    STMFD   SP!, {R2}                                        @ Push task`s CPSR (i.e. exception SPSR).

    CMP     R0, #OS_EXCEPT_DATA_ABORT 		@是資料例外嗎?
    BNE     1f 								@不是跳到 錨點1處
    MRC     P15, 0, R8, C6, C0, 0 			@R8=C6(記憶體失效的地址) 0(訪問資料失效)
    MRC     P15, 0, R9, C5, C0, 0 			@R9=C5(記憶體失效的狀態) 0(無效整個指令cache)
    B       3f 								@跳到錨點3處執行
1:  CMP     R0, #OS_EXCEPT_PREFETCH_ABORT 	@是預取例外嗎?
    BNE     2f 								@不是跳到 錨點2處
    MRC     P15, 0, R8, C6, C0, 2 			@R8=C6(記憶體失效的地址) 2(訪問指令失效)
    MRC     P15, 0, R9, C5, C0, 1 			@R9=C5(記憶體失效的狀態) 1(虛擬地址)
    B       3f 								@跳到錨點3處執行
2:  MOV     R8, #0
    MOV     R9, #0

3:  AND     R2, R2, #CPSR_MASK_MODE 
    CMP     R2, #CPSR_USER_MODE                              @ User mode
    BNE     4f @不是用戶模式
    STMFD   SP, {R13, R14}^                                  @ save user mode sp and lr
4:
    SUB     SP, SP, #(4 * 2) @sp=sp-(4*2)

非常重要的ARM37個暫存器

在這里插入圖片描述

詳見 系列篇之暫存器篇

結尾

以上為例外接管對應的代碼處理,具體每種例外發生的場景和代碼細節處理,因內容太多,太復雜,系列篇后續將分篇一一分析.敬請關注!

參與貢獻

訪問注解倉庫地址
Fork 本倉庫 >> 新建 Feat_xxx 分支 >> 提交代碼注解 >> 新建 Pull Request
新建 Issue

喜歡請大方點贊+關注+收藏吧

各大站點搜 “鴻蒙內核原始碼分析” ,快速找到組織.

公眾號: 鴻蒙內核原始碼分析

歡迎轉載,請注明出處,公眾號轉載申請方式: 關注后直接回復您的公眾號名稱即可.

百萬漢字注解 >> 精讀內核原始碼,中文注解分析, 深挖地基工程,大腦永久記憶,四大碼倉每日同步更新< gitee | github | csdn | coding >

百篇博客分析 >> 故事說內核,問答式導讀,生活式比喻,表格化說明,圖形化展示,多站點每日同步更新< oschina | csdn | weharmony >

轉載請註明出處，本文鏈接：https://www.uj5u.com/ruanti/267065.html

標籤：其他

上一篇：k8s:基本概念與組件

下一篇：架構師必須掌握的重要微服務架構設計模式！

鴻蒙內核原始碼分析(例外接管篇) | 社會很單純 , 復雜的是人 | 中文注解HarmonyOS原始碼 | v39.02

為何要有例外接管?

七種作業模式

官方概念

進入和退出例外方式

堆疊幀

六種例外模式實作代碼

地址例外處理(Address abort)

快中斷處理(fiq)

取指例外(Prefectch abort)

資料訪問例外(Data abort)

軟中斷處理(swi)

普通中斷處理(irq)

未定義例外處理(undef)

例外分發統一處理

非常重要的ARM37個暫存器

結尾

參與貢獻

喜歡請大方 點贊+關注+收藏 吧

喜歡請大方點贊+關注+收藏吧